Solidity – How to Convert Bytes to Hexadecimal String

bytessoliditystring

In a smart contract I have stored a bytes4 value: 0xa22cb465. I'd like to parse this value as a string:

string memory test = "0xa22cb465"

I've only stumbled upon explanations on how to convert bytes to string, not parse. Thanks in advance for the help!

Best Answer

If I understand correctly by "parsing" you mean going from an integer representation (i.e., bytes4 data = 0xa22cb465;) to a string representation in hexadecimal (i.e., string memory test = "0xa22cb465").

In that case, you'd need to write a function to actually do that conversion. Here is an example working with bytes input and base 16 string output with "0x" prefix.

// SPDX-License-Identifier: GPL-3.0
pragma solidity >=0.8.0;

contract Example {
    bytes4 public data = 0xa22cb465;

    function howToUseIt() public view returns (string memory) {
        return iToHex(abi.encodePacked(data));
    }

    function iToHex(bytes memory buffer) public pure returns (string memory) {

        // Fixed buffer size for hexadecimal convertion
        bytes memory converted = new bytes(buffer.length * 2);

        bytes memory _base = "0123456789abcdef";

        for (uint256 i = 0; i < buffer.length; i++) {
            converted[i * 2] = _base[uint8(buffer[i]) / _base.length];
            converted[i * 2 + 1] = _base[uint8(buffer[i]) % _base.length];
        }

        return string(abi.encodePacked("0x", converted));
    }
}

I hope that answers your question.

Related Solutions

[Ethereum] Solidity convert hex string to bytes

This are very inefficient but should work

// Convert an hexadecimal character to their value
function fromHexChar(uint8 c) public pure returns (uint8) {
    if (bytes1(c) >= bytes1('0') && bytes1(c) <= bytes1('9')) {
        return c - uint8(bytes1('0'));
    }
    if (bytes1(c) >= bytes1('a') && bytes1(c) <= bytes1('f')) {
        return 10 + c - uint8(bytes1('a'));
    }
    if (bytes1(c) >= bytes1('A') && bytes1(c) <= bytes1('F')) {
        return 10 + c - uint8(bytes1('A'));
    }
    revert("fail");
}

// Convert an hexadecimal string to raw bytes
function fromHex(string memory s) public pure returns (bytes memory) {
    bytes memory ss = bytes(s);
    require(ss.length%2 == 0); // length must be even
    bytes memory r = new bytes(ss.length/2);
    for (uint i=0; i<ss.length/2; ++i) {
        r[i] = bytes1(fromHexChar(uint8(ss[2*i])) * 16 +
                    fromHexChar(uint8(ss[2*i+1])));
    }
    return r;
}

In any case I'd recommend to try to convert your hexadecimal data outside solidity.

Solidity Strings – Convert Address to String After Solidity 0.5.x

Try this out.

pragma solidity > 0.5.1;

contract Test 
{
    
    function test() 
        public 
        view    
        returns (string memory) 
    {
        return addressToString(address(this));
    }

    function addressToString(address _addr) public pure returns(string memory) 
    {
        bytes32 value = bytes32(uint256(uint160(_addr)));
        bytes memory alphabet = "0123456789abcdef";
    
        bytes memory str = new bytes(51);
        str[0] = '0';
        str[1] = 'x';
        for (uint256 i = 0; i < 20; i++) {
            str[2+i*2] = alphabet[uint8(value[i + 12] >> 4)];
            str[3+i*2] = alphabet[uint8(value[i + 12] & 0x0f)];
        }
        return string(str);
    }
}

Best Answer

Related Solutions

[Ethereum] Solidity convert hex string to bytes

Solidity Strings – Convert Address to String After Solidity 0.5.x

Related Topic