Silence warnings in return variables when they are not used

contract-developmentdata-typeslocal-variablessoliditywarnings

I have the following function in solidity:

function validateAndPayForPaymasterTransaction(
    bytes32, 
    bytes32, 
    Transaction calldata _transaction
) external payable override onlyBootloader returns (bytes4 magic, bytes memory context) {
    require(
        _transaction.paymasterInput.length >= 4,
        "The standard paymaster input must be at least 4 bytes long"
    );

    bytes4 paymasterInputSelector = bytes4(
        _transaction.paymasterInput[0:4]
    );
    if (paymasterInputSelector == IPaymasterFlow.approvalBased.selector) {
        (address token, uint256 minAllowance, ) = abi
            .decode(
                _transaction.paymasterInput[4:],
                (address, uint256, bytes)
            );

        require(token == allowedToken, "Invalid token");
        require(minAllowance >= 1, "Min allowance too low");

        address userAddress = address(uint160(_transaction.from));
        address thisAddress = address(this);

        uint256 providedAllowance = IERC20(token).allowance(
            userAddress,
            thisAddress
        );
        require(
            providedAllowance >= PRICE_FOR_PAYING_FEES,
            "The user did not provide enough allowance"
        );

        // Note, that while the minimal amount of ETH needed is tx.gasPrice * tx.gasLimit,
        // neither paymaster nor account are allowed to access this context variable.
        uint256 requiredETH = _transaction.gasLimit *
            _transaction.maxFeePerGas;

        // Pulling all the tokens from the user
        IERC20(token).transferFrom(userAddress, thisAddress, 1);
        // The bootloader never returns any data, so it can safely be ignored here.
        (bool success, ) = payable(BOOTLOADER_FORMAL_ADDRESS).call{
            value: requiredETH
        }("");
        require(success, "Failed to transfer funds to the bootloader");
    } else {
        revert("Unsupported paymaster flow");
    }
}

I am getting these warnings in both variables that are being returned from the function (bytes4 magic, bytes memory context):

Unused function parameter. Remove or comment out the variable name to silence this warning.

How can I silence this warning? I cannot actually remove the variables since they are part of an override function. If I do that I would get the following:

Overriding function return types differ.

Best Answer

The solution to these warnings is:

Remove the name of the variables from the return statement, as suggested by shubhamskatel:

function validateAndPayForPaymasterTransaction(
    bytes32, 
    bytes32, 
    Transaction calldata _transaction
) external payable override onlyBootloader returns (bytes4, bytes memory)

And then make sure that you are actually returning the said value types in every return of your code (all non-reverting code paths):

return (paymasterInputSelector, bytesVariable);

In this example, paymasterInputSelector is of type bytes4 and bytesVariable is of type bytes.

Note - you declare a bytes variable like this:

        bytes memory bytesVariable = new bytes(0);
Related Topic