Minecraft Java Edition – Issues with Execute Command Following Run in 1.13

minecraft-commandsminecraft-java-edition

In 1.12, I had the command:

execute @a ~ ~ ~ teleport @s ~ ~ ~

In a 'repeat' command block. This would freeze all players until I chose to unfreeze them. In 1.13, I assumed the adjustment to this syntax would be:

execute at @a run tp @s ~ ~ ~

In a 'repeat' command block. However, this does not work. To attempt to debug, I tried:

execute at @a run give @s stone 1

Still to no avail. I also tried replacing the selector in the run part:

 execute at @a run give @p stone 1

And nothing. Could someone point me in the right direction?

Best Answer

You're not changing the executor (only the command position), so @s is targeting nobody. You can execute the command as the player like this:

execute as @a at @s run tp @s ~ ~ ~

In addition, relative teleports will no longer stop motion. Absolute teleports and teleports to entities still do though, so you could do:

execute as @a run tp @s @s

Note also that I've removed the at @s, since relative coordinates aren't being used anymore so it's no longer needed.

Related Solutions

Minecraft Java Edition – Teleport All Entities Relative to Themselves in 1.13

You're close, but the at @e[type=minecart,distance=..30] as @e[type=minecart,distance=..30] will execute at each minecart position, for each minecart. So each minecart is being teleported to each position in order (e.g: 8 minecarts would be 64 tp's total), all ending up at the last one.

Instead, you should use this:

execute as @e[type=minecart,distance=..30] at @s run tp @s ~ 64 ~

Which makes the minecarts all execute at themselves, to teleport themselves.

Minecraft 1.13 – How to Teleport an Arrow to Another Entity Within a Radius

Arrows seem to be a bit weird with their motion. In theory this should make homing arrows which chase down the nearest target:

execute as @e[type=arrow] at @s run teleport @s ^ ^ ^1 facing entity @e[type=!arrow,sort=nearest,limit=1]

But for some reason this doesn't quite work. Same with explicitly setting their motion:

execute as @e[type=arrow] store result score @s x run data get entity @s Pos[0] 10
execute as @e[type=arrow] store result score @s y run data get entity @s Pos[1] 10
execute as @e[type=arrow] store result score @s z run data get entity @s Pos[2] 10
execute at @e[type=arrow] as @e[type=!arrow,sort=nearest,limit=1] at @s store result score @s x run data get entity @s Pos[0] 10
execute at @e[type=arrow] as @e[type=!arrow,sort=nearest,limit=1] at @s store result score @s y run data get entity @s Pos[1] 10
execute at @e[type=arrow] as @e[type=!arrow,sort=nearest,limit=1] at @s store result score @s z run data get entity @s Pos[2] 10
execute as @e[type=arrow] at @s run scoreboard players operation @s x -= @e[type=!arrow,sort=nearest,limit=1] x
execute as @e[type=arrow] at @s run scoreboard players operation @s y -= @e[type=!arrow,sort=nearest,limit=1] y
execute as @e[type=arrow] at @s run scoreboard players operation @s z -= @e[type=!arrow,sort=nearest,limit=1] z
execute as @e[type=arrow] store result entity @s Motion[0] double -0.01 run scoreboard players get @s x
execute as @e[type=arrow] store result entity @s Motion[1] double -0.01 run scoreboard players get @s y
execute as @e[type=arrow] store result entity @s Motion[2] double -0.01 run scoreboard players get @s z

But for some reason these seem to work differently with arrows. I tested it with chickens and it works great. So these are two solutions that should work, but don't, I don't know why.

So here is the answer to your original question instead: Just teleporting arrows to other entities:

execute as @e[type=arrow] at @s run tp @s @e[type=!arrow,sort=nearest,limit=1]

To limit the radius, add ,distance=..<number> to the target selector.

Best Answer

Related Solutions

Minecraft Java Edition – Teleport All Entities Relative to Themselves in 1.13

Minecraft 1.13 – How to Teleport an Arrow to Another Entity Within a Radius

Related Topic