Get the field value from object. I am using deserializeUntyped

apexdeserializejson

I am trying to get the field value from the object. If I loop through the object it looks like

Map<String, Object> params = (Map<String, Object>)JSON.deserializeUntyped(RestContext.request.requestbody.toString());
for(Object obj: (List<Object>)params.get('records')){
   System.debug('obj=====>'+obj);
}

how to get the obj.Banking?

LOOP RESULT

obj=>{attributes={referenceId=ref1, type=Account}, industry=Banking, name=SampleAccount1, numberOfEmployees=100, phone=1111111111, website=www.salesforce1.com}
obj=>{attributes={referenceId=ref1, type=Account}, industry=Banking, name=SampleAccount1, numberOfEmployees=100, phone=1111111111, website=www.salesforce1.com}

I want to get the industry, name values. Although I was able to get it working using the wrapper when I used JSON.deserialize like below

WrapperData wrapRecords =  (WrapperData) System.JSON.deserialize(RestContext.request.requestbody.toString(), WrapperData.class);
for(Integer i=0; i<wrapRecords.records.size() ; i++){
    Account acc = new Account ();
    acc.Name = wrapRecords.records[i].name;
    acc.industry = wrapRecords.records[i].industry;
}

I was able to get the records using JSON.deserialize but would like to know if this possible with JSON.deserializeUntyped. I saw somewhere choosing deserializeUntyped over deserialize is better when it comes to performance. I don't know how to approach. Any advise would be appreciated. Thank you so much.

Best Answer

I saw somewhere choosing deserializeUntyped over deserialize is better when it comes to performance.

AFAIK, the performance between deserialize and deserializeUntyped is minimal. With a class + deserialize, its much easier to parse the JSON response.

Having said that, this can still be done with deserializeUntyped as:

// hardcoding the string as per one in question
String requestBodyString = '{"records": [{"attributes":{"referenceId":"ref1", "type":"Account"}, "industry":"Banking", "name":"SampleAccount1", "numberOfEmployees":100, "phone":1111111111, "website":"www.salesforce1.com"}]}';

Map<String, Object> params = (Map<String, Object>)JSON.deserializeUntyped(requestBodyString);
for(Object obj: (List<Object>)params.get('records')){
    // the result of obj is JSON, so convert it to map
    Map<String, Object> objMap = (Map<String, Object>) obj;
    String industry = (String) objMap.get('industry');
    System.debug(industry);
}

The key here is to convert a complex object or JSON property to a Map<String, Object>, then you can extract the appropriate value from JSON.

Related Solutions

[SalesForce] Deserialize JSON to Map – EchoSign REST API response help

As sfdcfox suggested in a comment, you can use json2apex to generate the necessary code from a JSON sample. The app is a little out of date in that test methods should now be in a different class, so I generated the code and separated out the test method:

UserAgreements Class

public class UserAgreements {
    public class DisplayUserInfo {
        public String company;
        public String fullNameOrEmail;
    }

    public List<UserAgreementList> userAgreementList;

    public class UserAgreementList {
        public String displayDate;
        public DisplayUserInfo displayUserInfo;
        public Boolean esign;
        public String agreementId;
        public String latestVersionId;
        public String name;
        public String status;
    }


    public static UserAgreements parse(String json) {
        return (UserAgreements) System.JSON.deserialize(json, UserAgreements.class);
    }   
}

UserAgreementsTest Class

@isTest
public class UserAgreementsTest {
    static testMethod void testParse() {
        String json = '{'+
        '  \"userAgreementList\": ['+
        '    {'+
        '      \"displayDate\": \"2015-04-02T09:32:23-07:00\",'+
        '      \"displayUserInfo\": {'+
        '        \"company\": \"TEST\",'+
        '        \"fullNameOrEmail\": \"Tim 1234\"'+
        '      },'+
        '      \"esign\": true,'+
        '      \"agreementId\": \"AGREEMENT ID\",'+
        '      \"latestVersionId\": \"VERSION ID\",'+
        '      \"name\": \"Agreement for APEX Test Account - 2015-04-02\",'+
        '      \"status\": \"OUT_FOR_SIGNATURE\"'+
        '    },'+
        '    {'+
        '      \"displayDate\": \"2015-04-02T03:32:57-07:00\",'+
        '      \"displayUserInfo\": {'+
        '        \"company\": \"TEST\",'+
        '        \"fullNameOrEmail\": \"Tim 1234\"'+
        '      },'+
        '      \"esign\": true,'+
        '      \"agreementId\": \"AGREEMENT ID\",'+
        '      \"latestVersionId\": \"VERSION ID\",'+
        '      \"name\": \"Agreement for APEX Test Account - 2015-04-02\",'+
        '      \"status\": \"OUT_FOR_SIGNATURE\"'+
        '    },'+
        '    {'+
        '      \"displayDate\": \"2015-03-31T09:15:11-07:00\",'+
        '      \"displayUserInfo\": {'+
        '        \"company\": \"TEST\",'+
        '        \"fullNameOrEmail\": \"Tim 1234\"'+
        '      },'+
        '      \"esign\": true,'+
        '      \"agreementId\": \"AGREEMENT ID\",'+
        '      \"latestVersionId\": \"VERSION ID\",'+
        '      \"name\": \"Agreement for APEX Test Account - 2015-04-02\",'+
        '      \"status\": \"RECALLED\"'+
        '    }'+
        '  ]'+
        '}';
        UserAgreements obj = UserAgreements.parse(json);
        System.assert(obj != null);
    }
}

[SalesForce] Deserialize JSON Array With Integer Index

You are going to laugh at this, but it turns out that REENCODING as JSON at each step gets you your quoted values. Strange but true!! Try this:

String jsonData = '{"data": {"1500":{"id":"1500","last_name":"Test1"},"298":{"id":"298","last_name":"Test2"}},"status_code":200}';

//get top level map
Map<String,Object> jsonMap = (Map<String, Object>)JSON.deserializeUntyped(jsonData);

//extract data as JSON
String jsonSubset = JSON.serialize(jsonMap.get('data'));

//re-encode as a Map
Map<String,Object> jsonSubsetMap = (Map<String, Object>)JSON.deserializeUntyped(jsonSubset);

MyContact[] contacts = new MyContact[]{};
for (Object obj : jsonSubsetMap.values()){
    //re-encode as json, again!
    String jsonObj = JSON.serialize(obj);
    //deserialize that b@#$ard!!
    MyContact contact = (EBTestDeleteMe.MyContact)JSON.deserialize(jsonObj, MyContact.class);
    contacts.add(contact);
}

System.debug(contacts);

This outputs:

DEBUG|(MyContact:[id=298, last_name=Test2], MyContact:[id=1500, last_name=Test1])

This assumes you have a class called MyContact that looks like this:

public class MyContact {
    public String id;
    public String last_name;
}

Best Answer

Related Solutions

[SalesForce] Deserialize JSON to Map – EchoSign REST API response help

[SalesForce] Deserialize JSON Array With Integer Index

Related Topic