Is there any method to check the POSSIBILITY of converting a string to an Integer type

apex

Is there any way or method to check the POSSIBILITY of converting a string to an Integer type, or in other words: how do I know if an exception will be thrown when converting a string to an Integer? My idea is to use a try/catch block, and I want to know if there is a less cumbersome way. In Apex Salesforce!

Here is my code, are there any more accurate analogues:

public static boolean isConvertPoss(string str)
    {
            try
            {
                integer number=Integer.valueOf(str);
            }
            catch(Exception e)
            {
                return false;
            }
            return true;
}

Best Answer

If you want to avoid the possible expense of throwing an exception, you can use a Pattern (regular expression):

public static boolean isConvertPoss(string str)
  if(str != null) {
    Pattern p = Pattern.compile('[-+]?\\d{1,10}');
    try {
      return p.matcher(str).matches() && Integer.valueOf(str) != null;
    } catch(Exception e) {
      return false;
    }
  }
  return false;
}

We first check if str is not null, then we create a pattern that allows a optional leading positive/negative indicator followed by at least one digit.

Edit: based on comments, I realized we should probably do a sanity check that there are no more than ten digits, and afterwards try a conversion in case it's outside the binary range of -2³¹ to 2³¹-1.

Related Solutions

[SalesForce] How to avoid recursive trigger other than the classic ‘class w/ static variable’ pattern

Another good way to avoid recursion is highlighted in Chapter 6 of Dan Applemans's excellent book, Advanced Apex Programming. This particular example is around recursion when looking for a specific field change which is very common in many triggers.

As mentioned in @BarCotters answer, you generally run your trigger on very specific criteria. A change in a field can trigger certain logic in your trigger. If you look at the Order of Operations for triggers, you can see that any workflow rules and field updates based on those rules are run after the both before and after triggers have run. It runs however prior to the changes actually being committed to the DB, which is where this can cause problems when detecting field changes.

So lets say we are using a very simple example where we have a trigger on the Opportunity object that looks for opportunities that have been Won, and based on that it creates a new custom object record.

trigger OpportunityTrigger on Opportunity (after update) {
    map<Id,Opportunity> justWonOppsMap = new map<Id,Opportunity>();
    for (Opportunity o : Trigger.new) {
        if (o.isWon != Trigger.oldMap.get(o.Id).isWon) {
            justWonOppsMap.put(o.Id, o);
        }
    }
    List<Some_Custom_Object__c> objs = new list<Some_Custom_Object__c>();
    for(Opportunity o : justWonOppsMap.values()){
         objs.add(new Some_Custom_Object__c(
              Name = 'New object based off ' + o.Name, 
              Opportunity__c = o.Id
         ));
    }
    insert objs;
}

This trigger will work fine, and will create a new custom object when you close an Opportunity. It will work fine that is, assuming you have no WFR's that have field updates on the Opportunity Object.

Let's say now I had a workflow rule on the Opportunity that When an Opp is closed, it changes the CloseDate of the Opportunity to Today. (A fairly simple and common WFR that many admins may add).

That simple change now Breaks my trigger. This same trigger will now actually create 2 custom objects when my opportunity is closed. This is due to the fact that the WFR rule is now firing the triggers one final time.

This is how you would think the logic works

Trigger Run 1 (Old Value = Not Won, New Value = Won)
Workflow Trigger
Run 2 (Old Value = Won, New Value = Won)

This is not how it works though, even though the opp has been updated, it has not yet been committed to the Database, so in the second run of the trigger it still see's the opp and just being closed like below

This is actually how it works

Trigger Run 1 (Old Value = Not Won, New Value = Won)
Workflow
Trigger Run 2 (Old Value = Not Won, New Value = Won) Identical as first run

This is where Dan Appleman's solution comes in. He advises to use a mechanism that actually checks for the 'correct old value'. This would allow the second run of the trigger to detect the value that was set in the first run of the trigger.

trigger OpportunityTrigger on Opportunity (after update) {
    OpportunityTriggerHelper.OppAfterUpdate(trigger.ew, trigger.old, trigger.newMap, trigger.oldMap);
}

public class OpportunityTriggerHelper {

    Private static Map <Id,boolean> oldIsWonMap = null;

    public static void OppAfterUpdate(list<Opportunity> newOpps, list<Opportunity> oldOpps, map<Id,Opportunity> newMap, map<Id,Opportunity> oldMap) {

        if(oldIsWonMap == null) {
            oldIsWonMap = new map<Id,boolean >();
        }

        map<Id,Opportunity> justWonOppsMap = new map<Id,Opportunity>();
        for (Opportunity o : Trigger.new) {

            //This checks to see if there was a value set in a previous trigger run
            boolean oldIsWon = (oldIsWonMap.containsKey(o.id)) ? oldIsWonMap.get(o.id) : oldmap.get(o.id).isWon;

            //this checks the current opp value with the 'correct' old value
            if(o.isWon && !oldIsWon){
                justWonOppsMap.put(o.Id, o);
            }

            //this puts in the 'correct' old value in case the trigger is run again in the same context
            if(oldIsWon != o.isWon) {
                oldIsWonMap.put(o.id,o.isWon);
            }
        }
        List<Some_Custom_Object__c> objs = new list<Some_Custom_Object__c>();
        for(Opportunity o : justWonOppsMap.values()){
            objs.add(new Some_Custom_Object__c(
                Name = 'New object based off ' + o.Name, 
                Opportunity__c = o.Id
            ));
        }
        insert objs;
    }
}

With this change, now the WFR rule does not break our trigger. Only 1 custom object is created when the opp is closed.

I know this was longwinded, but I hope it helps. I would highly getting this book as this was only a few pages worth of goodness, and this book is jam packed with great knowledge that I think all SFDC developers should have.

Heres the link again.

http://advancedapex.com/

[SalesForce] Error: Compile Error: Illegal assignment from String to Boolean

Change

c.Volunteer__c = 'FALSE';
c.HOC__Minor_Wavier_on_File__c = 'FALSE';
c.HOC__Disabled_Person__c = 'FALSE';
c.HOC__Calculated_Birthdate__c = 'FALSE';
c.HOC__Confirmed_Organizer__c = 'FALSE';

c.Volunteer__c = false;
c.HOC__Minor_Wavier_on_File__c = false;
c.HOC__Disabled_Person__c = false;
c.HOC__Calculated_Birthdate__c = false;
c.HOC__Confirmed_Organizer__c = false;

Best Answer

Related Solutions

[SalesForce] How to avoid recursive trigger other than the classic ‘class w/ static variable’ pattern

[SalesForce] Error: Compile Error: Illegal assignment from String to Boolean

Related Topic