[SalesForce] Apex dynamically assign new records to users using trigger

Config solution would be to create a simple workflow rule with

• condition = "every time a new record is created" (+ anything you have to distinguish the records like LeadSource = 'API' maybe?)
• email alert to the owner (you'd have to prepare an email template first)

Apex version could be to set a Task for the Owner with optional Email notification. Insert your Leads first, then for each create a list of Tasks with ParentId = lead.id and OwnerId = lead.OwnerId. The important part would be to not go with straightforward

insert tasks;

but use the DML Options

Database.DMLOptions dlo = new Database.DMLOptions();
dlo.EmailHeader.triggerUserEmail = true;
Database.insert(tasks, dlo);

I think the config version is cleaner (easier to maintain in future if you need to change the criteria or temporarily disable it).

You might also want to look into the Chatter Actions and Lead assignment rules (but assignment rules let you specify the notification only if you change the owner in same rule so potentially you'll need to move more logic from Apex to config before you can use it. And you'd still need to make an email template).

I was able to solve this issue, and wanted to share the solution with you. When an "after update" trigger runs in the context of a Workflow, you must run reassignment rules after the whole workflow ended In order to allow the Lead Assignment rules to see the Lead after the transaction of the Workflow ended.

This is the code to achieve this (By Adding an async call to the reassignment rules):

trigger RunLeadAassignmentRules on Lead (after update) {

    Set<ID> ls = new Set<ID>();

    for (Lead l : trigger.new) {
        Lead old_lead = trigger.oldMap.get(l.Id);
        System.Debug(LoggingLevel.DEBUG,l.OwnerId);
        System.Debug(LoggingLevel.DEBUG,old_lead.OwnerId);

        System.Debug(LoggingLevel.DEBUG,l.Status);
        System.Debug(LoggingLevel.DEBUG,old_lead.Status);

        // Only run if the lead was assigned to a Queue and not
        // A person. We do not reassign.
        if ( old_lead.OwnerId.getSobjectType() == Group.SObjectType &&
             (
               old_lead.Number_of_Employees__c != l.Number_of_Employees__c ||
               old_lead.State != l.State ||
               old_lead.Country != l.Country
             )
            )
        {
            ls.add(l.Id);
        }
    }

    if (ls.size() > 0) {
        // This is the Fix
        ReassignLeads.futureLeadReassign(ls);
    }
}

And this is the Async Apex Class

 public with sharing class ReassignLeads {
    @future
    public static void futureLeadReassign(Set<ID> lIdReassignSet) {

      List<Lead> lUpdList = [SELECT Id FROM Lead WHERE Id IN: lIdReassignSet];
      for (Lead l:lUpdList){
        Database.DMLOptions dmo = new Database.DMLOptions();
        dmo.assignmentRuleHeader.useDefaultRule  = true;
        l.setOptions(dmo);
      }

      update(lUpdList);
    }
}

Remember that tests written for this trigger must use Test.startTest(); and Test.stopTest(); in order to wait for the async calls to finish before checking the results of the test.