[SalesForce] Apex equivalent to associative array

I have the following list definition in my Apex controller:

List<Object> mylist = new List<Object>();

And I would like to do something like:

mylist.add({
    key : objKey,
    label : objlabel,
    property1 : objproperty1
});

This code gives an error. Is there any way to achieve such a data structure in Apex?

Best Answer

You need to create a Wrapper class for this.

Example :

public class TestWrapper {

    public static void  pushValue(){
        list<fieldWrapper> n = new list<fieldWrapper>();

        fieldWrapper f = new fieldWrapper();
        f.key = 'a';
        f.label = 'b';
        f.property1 = 'c';
        n.add(f);
        system.debug('DD'+n);
    }

    public class fieldWrapper{
        public String key;
        public String label;
        public String property1;
    }

}

Related Solutions

[SalesForce] How to create schedule batch apex which returns list of object records

I rewrote your batch class to the way I write batch Apex - I hope this helps.

global class ScheduleContact implements Database.Batchable<SObject> {

global Database.queryLocator start(Database.BatchableContext ctx) {
    DateTime theDateTime = System.now().addDays(-60);
    String query = 'Select FirstName, LastName, AccountId, Contract_End_Date__c';
    query += ' FROM Contact WHERE Payment_Type__c = \'Paid In Full\'';
    query += ' AND Contract_End_Date__c >= :theDateTime';

    return Database.getQueryLocator(query);

}
global void execute(Database.BatchableContext BC, List<sObject> scope) {
    List<Contact> contactList = (List<Contact>)scope;

    //for creating new opportunity.
    List<Opportunity> newOpps = new List<Opportunity>();

    for (Contact c : contactList) {
        Opportunity opp = new Opportunity();
        opp.Name = c.FirstName + ' ' + c.LastName + ' Opportunity';
        opp.CloseDate = c.Contract_End_Date__c;
        opp.Type = 'Renewal';
        opp.StageName = 'Met';
        opp.AccountId = c.AccountId;
        newOpps.add(opp);
    }

    insert newOpps;
}
global void finish(Database.BatchableContext BC) {

}
}

I am using batchable, making a dynamic Apex query string, passing a list to the execute, casting it to a list and then working through that list to make new Opportunities.

(Edit: Thanks to @dphil for noticing my unused variable - removed it.)

[SalesForce] Collection of List keyed by sObject field

The special map constructor only handles the case of creating a map where the key is the ID and the value is the SObject.

To do what I think you want to do requires a loop:

Map<Id, List<Custom__c>> m = new  Map<Id, List<Custom__c>>();
for (Custom__c c : [
        SELECT Lookup_To_Custom__c, Id, Name
        FROM Custom__c
        WHERE Lookup_To_Custom__c != null
        ORDER BY Name
        ]) {
    List<Custom__c> l = m.get(c.Lookup_To_Custom__c);
    if (l == null) {
        l = new List<Custom__c>();
        m.put(c.Lookup_To_Custom__c, l);
    }
    l.add(c);
}

Note that using the foreign key field Lookup_To_Custom__c is a little more direct than going through the reference and taking the ID Lookup_To_Custom__r.Id.

Best Answer

Related Solutions

[SalesForce] How to create schedule batch apex which returns list of object records

[SalesForce] Collection of List keyed by sObject field

Related Topic