[SalesForce] Apex: Is there a way to Identify if history tracking is enabled on the field or not

Create an object called AccountHistoryTracking and fields like APIName__c,OldValue__c,NewValue__c then create a fieldset on Account called'HistoryTracking' with the fields you want to track on Account and then write below code to track history on account.This way you don't need to worry about history tracking limit per object.

trigger AccountHistoryTracker on Account (after update) {

    final List<Schema.FieldSetMember> trackedFields = 
        SObjectType.Account.FieldSets.HistoryTracking.getFields();

    if (trackedFields.isEmpty()) return;

    final List<AccountHistoryTracking__c> fieldChanges = 
        new List<AccountHistoryTracking__c>();

    if(!trigger.isUpdate)
        return;

    for (Account newAccount : trigger.new) {

        final Account oldAccount = trigger.oldmap.get(newAccount.Id);

        for (Schema.FieldSetMember fsm : trackedFields) {

            String fieldName  = fsm.getFieldPath();
            String fieldLabel = fsm.getLabel();

            if (newAccount.get(fieldName) == oldAccount.get(fieldName))
                continue;

            String oldValue = String.valueOf(oldAccount.get(fieldName));
            String newValue = String.valueOf(newAccount.get(fieldName));

            if (oldValue != null && oldValue.length()>255) 
                oldValue = oldValue.substring(0,255);

            if (newValue != null && newValue.length()>255) 
                newValue = newValue.substring(0,255); 

            final AccountHistoryTracking__c accountHistory = 
                new AccountHistoryTracking__c();

            accountHistory.name         = fieldLabel;
            accountHistory.apiName__c   = fieldName;
            accountHistory.User__c      = newAccount.Id;
            accountHistory.ChangedBy__c = UserInfo.getUserId();
            accountHistory.OldValue__c  = oldValue;
            accountHistory.NewValue__c  = newValue;

            fieldChanges.add(accountHistory);
        }
    }

    if (!fieldChanges.isEmpty()) {
        insert fieldChanges;
    }
}

I can't find this in Apex, but I can find it in the Tooling API and in the Metadata API.

For the Tooling API, check the CustomField object: https://developer.salesforce.com/docs/atlas.en-us.api_tooling.meta/api_tooling/tooling_api_objects_customfield.htm

For the Metadata API, there is, for each field on an object, a "trackHistory" attribute. https://developer.salesforce.com/docs/atlas.en-us.api_meta.meta/api_meta/customfield.htm

Andy Fawcett has written an Apex wrapper for the Metadata API. For more information, see https://andyinthecloud.com/category/metadata-api/ and https://github.com/financialforcedev/apex-mdapi.

(I'd go with the Metadata API and would use the wrapper. It's an easy deploy from the GitHub repository.