[SalesForce] apex test class to cover the method CompareTo :

i have below code in my apex class

global class Payment implements Comparable{
    public string id;
    public string YearQ;
    public string YearMo;
    public Date asOf;
    public decimal payment = 0;
    public decimal revenue = 0;
    public decimal attritionRate = 0;//DE420
    public decimal payOnRevenue = 0;//DE 420

    //only used by branch group sort (compareTo) to provide 0 values for missing payments
    public Payment() {
    }

    public Payment(PODA_Exhibit_Payment__c pmt) {
        this.id = pmt.id;
        this.YearQ = pmt.PODA_Contracted_Agency_Payment__r.YearQrt__c;
        this.YearMo = PODA_Util.getYearMoFromYearQ(this.YearQ);
        this.payment = pmt.Total_Payment__c;
        this.revenue = pmt.Total_Flown_Revenue__c;
        // DE 420 - Gain Calculator 9/9/14
        this.attritionRate = pmt.Attrition_Rate__c;
        this.payOnRevenue = pmt.Pay_On_Revenue__c;
    }

    public Payment(PODA_Branch_Payment_Summary__c pmt) {
        this.id = pmt.id;
        this.YearQ = pmt.YearQrt__c;
        this.YearMo = PODA_Util.getYearMoFromYearQ(this.YearQ);
        this.payment = pmt.Total_Payment__c;
        this.revenue = pmt.Total_Flown_Revenue__c;
    }

    public Payment(PODA_Branch_Exhibit_Payment__c pmt) {
        this.id = pmt.id;
        this.YearQ = pmt.YearQrt__c;
        this.YearMo = PODA_Util.getYearMoFromYearQ(this.YearQ);
        this.payment = pmt.Total_Payment__c;
        this.revenue = pmt.Total_Flown_Revenue__c;
    }

    public void addPayment(PODA_Branch_Payment_Summary__c pmt) {
      this.payment += pmt.Total_Payment__c;
      this.revenue += pmt.Total_Flown_Revenue__c;
    }

    public void addPayment(PODA_Branch_Exhibit_Payment__c pmt) {
        this.payment += pmt.Total_Payment__c;
        this.revenue += pmt.Total_Flown_Revenue__c;
    }

    public void addPayment(PODA_Exhibit_Payment__c pmt) {
        this.payment += pmt.Total_Payment__c;
        this.revenue += pmt.Total_Flown_Revenue__c;
        this.payOnRevenue += pmt.Pay_On_Revenue__c;
    }

    public Integer compareTo(Object compareTo) {
        Payment compareToHP = (Payment)compareTo;
        return this.YearQ.compareTo(compareToHP.YearQ);
    }

}

/// Payments is the inner class in the main apex class and i want to write test class for this.

I am facing issue while writing test for below method in the above code

 public Integer compareTo(Object compareTo) {
        Payment compareToHP = (Payment)compareTo;
        return this.YearQ.compareTo(compareToHP.YearQ);
    }

// i have created a class with name as Object1 in the test class and try to call the main class method as below

 PODA_Data.Payment objPODA = new PODA_Data.Payment();
 object1 obj = new object1();
  integer i = objPODA.compareTo(obj);

Facing error as below :

Error Message System.TypeException: Invalid conversion from runtime
type PODA_Data_Test.object1 to PODA_Data.Payment

// could you please help me how to write test class for the above method.

Best Answer

I would write a test method (or multiple methods) for the compareTo of this form:

@IsTest
static void compareTo() {

    PODA_Data.Payment p1 = new PODA_Data.Payment(new PODA_Branch_Payment_Summary__c(YearQrt__c = '1'));
    PODA_Data.Payment p2 = new PODA_Data.Payment(new PODA_Branch_Payment_Summary__c(YearQrt__c = '2'));

    PODA_Data.Payment p3 = new PODA_Data.Payment(new PODA_Branch_Exhibit_Payment__c(YearQrt__c = '3'));
    PODA_Data.Payment p4 = new PODA_Data.Payment(new PODA_Branch_Exhibit_Payment__c(YearQrt__c = '4'));

    PODA_Data.Payment p5 = new PODA_Data.Payment();

    // TODO Also create PODA_Exhibit_Payment__c ones; bit more awkward

    System.assert(p2.compareTo(p1) > 0);
    System.assert(p1.compareTo(p2) < 0);
    System.assert(p1.compareTo(p1) == 0);

    System.assert(p4.compareTo(p3) > 0);
    System.assert(p3.compareTo(p4) < 0);
    System.assert(p3.compareTo(p3) == 0);

    System.assert(p3.compareTo(p1) > 0);
    System.assert(p1.compareTo(p3) < 0);

    // Method compareTo will NPE with this so test will highlight missing guard code
    System.assert(p5.compareTo(p1) < 0);

    ...
}

The point of tests is to make sure that code works so always include asserts for the required behaviour and cover a reasonable number of permutations.

Related Solutions

[SalesForce] Apex Testing – Test Data Factory Quick Question

The createTestRecords method commits data to the database using insert.

The records that have been inserted can be retrieved using SOQL:

List<Account> accounts = [SELECT Name FROM Account]; // Will bring back the created accounts
List<Contact> contacts = [SELECT FirstName, LastName FROM Contact]; // Will bring back the created contacts

Personally I prefer to return the records I create in these types of methods as it means I have access to the inserted records (and their Id) without needing the query the database:

public static List<Account> createTestAccounts(Integer numAccts) 
{
    List<Account> accts = new List<Account>();

    for(Integer i = 0; i < numAccts; i++) 
    {
        Account a = new Account(Name = 'TestAccount' + i);
        accts.add(a);
    }

    insert accts;
    return accts;
}

[SalesForce] Simple Apex class to return a list of strings

You can't instantiate a List like that using an integer. You don't need to explicitly specify how much items are going into the list when it is created. Instead, just remove the integer:

//Instantiate the list
String[] myArray = new List<String>();

You're logic in your loop seems to be incorrect as well. Specifically, myArray's size will always be 0 when you instantiate it. Change your loop logic to:

for(Integer i=0;i<length;i++) {
   // code
}

You want to generate a List of strings based on the i variable. You will want to change your internal logic to:

//Populate the array
myArray.add('Test ' + i);

// Write value to the debug log
System.debug(myArray[i]);

Finally, you want to return that Array. You need to change your method so the return type is no longer void by changing its signature:

public static String[] generateStringArray(Integer length)

then it is just a matter of returning that array at the end of your method:

return myArray;

This would bring it all together as:

public class StringArrayTest {
    //Public Method
    public static String[] generateStringArray(Integer length) {
        //Instantiate the list
        String[] myArray = new List<String>();

        //Iterate throught the list
        for(Integer i=0;i<length;i++) {
            //Populate the array
            myArray.add('Test ' + i);

            // Write value to the debug log
            System.debug(myArray[i]);
        } //end loop

        return myArray;
    }//end method       
}// end class

Some more info on Arrays and Lists, Loops, and Class methods for future reference.

Best Answer

Related Solutions

[SalesForce] Apex Testing – Test Data Factory Quick Question

[SalesForce] Simple Apex class to return a list of strings

Related Topic