[SalesForce] ApexMocks from FFlib not getting verified at run time

Trying to test a simple overloaded service.

AccountsService.cls

public static List<Account> getAccounts(Set<Id> ids){
    /* This selector needs to be mocked */
    List<Account> accounts = AccountsSelector.newInstance().selectById( ids );

    if(accounts != null && accounts.size() > 0) {
        return accounts;
    } else {
        return NULL;
    }
}

    public static List<Account> getAccounts(Set<String> ids){
        return getAccounts( (Set<Id>)JSON.deserialize(JSON.serialize(ids), Set<Id>.class) );
    }

My thought here is that I simply need to unit test the Set<String> method which will reference the derived method, which then will call the AccountsSelector which should be stubbed per my test.

AccountsServiceTest.cls

@IsTest
private static void getAccounts() {
    /* Create mocks */
    fflib_ApexMocks MOCKS = new fflib_ApexMocks();
    AccountsSelector mockSelector = (AccountsSelector) MOCKS.mock(AccountsSelector.class);

    /* Generate a generic account id */
    Id aid = fflib_IDGenerator.generate(Account.SObjectType);

    //! Given
    MOCKS.startStubbing();
    List<Account> accountsList = new List<Account> {
        new Account(
            Id = aid,
            Name = 'Test Account'
        ) 
    };
    MOCKS.when(mockSelector.selectById(aid)).thenReturn(accountsList);
    MOCKS.stopStubbing();

    /* Configure the application to use mocks */
    Application.Selector.setMock(mockSelector);

    //! When
    AccountsService.getAccounts(new Set<Id>{aid});

    //! Then
    /* Verify services were called */
    ((AccountsSelector) MOCKS.verify(mockSelector)).newInstance().selectById(aid);

}

Unfortunately the test fails with the following response:

fflib_ApexMocks.ApexMocksException: Expected : 1, Actual: 0 -- Wanted but not invoked: AccountsSelector__sfdc_ApexStub.selectById(Id).

It seems the verify method is failing but I don't understand why, I feel like I'm missing something simple but after hours I'm not seeing it. I attempted to test against the method directly as well to make sure there wasn't an issue with the mocking and overloaded methods. I've also replaced the AccountsSelector with the interface IAccountsSelector but that doesn't seem to change anything either.

EDITED:

In addition when I remove the verify line the test passes without an issue and as you can see the AccountsSelector call was covered, so now I'm even more confused :/

Best Answer

This one is a common mistake; the fflib Selector layer requires that you stub the SObjectType() method as the setMock() method used by Application.Selector.setMock(mockSelector) calls SObjectType() to properly instantiate an internal map of selector instances by SObjectTypes (so some selectors can be mocked and others not).

I annotated your code below with the new line...

Now, some other things ...

You are testing getAccounts so you need to verify that it returns the accounts returned by the (mocked) selector. So, your verify is not what you want

You have:

((AccountsSelector) MOCKS.verify(mockSelector)).newInstance().selectById(aid);

You need to verify the return from this method ...I altered your code below. There's no real need to verify that the selector was called because if the code under test doesn't pass in a set of mocked accountIds exactly the same as in your mocks.when, the selector will not return any Accounts and the code under test will not return any Accounts (will return NULL per the way you coded it)

@IsTest
private static void getAccounts() {
    /* Create mocks */
    fflib_ApexMocks MOCKS = new fflib_ApexMocks();
    AccountsSelector mockSelector = (AccountsSelector) MOCKS.mock(AccountsSelector.class);

    /* Generate a generic account id */
    Id aid = fflib_IDGenerator.generate(Account.SObjectType);

    //! Given
    MOCKS.startStubbing();
    List<Account> accountsList = new List<Account> {
        new Account(
            Id = aid,
            Name = 'Test Account'
        ) 
    };
    MOCKS.when(mockSelector.SObjectType()).thenReturn(Account.SObjectType); // REQUIRED
    MOCKS.when(mockSelector.selectById(new Set<Id>{ aid }))).thenReturn(accountsList);
    MOCKS.stopStubbing();

    /* Configure the application to use mocks */
    Application.Selector.setMock(mockSelector);

    //! When
    Account[] results = AccountsService.getAccounts(new Set<Id>{ aid })); // CHG

    //! Then
    /* Verify result was as expected */
    System.assertEquals(1,results.size(),'sb return of mocked accounts');

}

Related Solutions

[SalesForce] Simple Apex class to return a list of strings

You can't instantiate a List like that using an integer. You don't need to explicitly specify how much items are going into the list when it is created. Instead, just remove the integer:

//Instantiate the list
String[] myArray = new List<String>();

You're logic in your loop seems to be incorrect as well. Specifically, myArray's size will always be 0 when you instantiate it. Change your loop logic to:

for(Integer i=0;i<length;i++) {
   // code
}

You want to generate a List of strings based on the i variable. You will want to change your internal logic to:

//Populate the array
myArray.add('Test ' + i);

// Write value to the debug log
System.debug(myArray[i]);

Finally, you want to return that Array. You need to change your method so the return type is no longer void by changing its signature:

public static String[] generateStringArray(Integer length)

then it is just a matter of returning that array at the end of your method:

return myArray;

This would bring it all together as:

public class StringArrayTest {
    //Public Method
    public static String[] generateStringArray(Integer length) {
        //Instantiate the list
        String[] myArray = new List<String>();

        //Iterate throught the list
        for(Integer i=0;i<length;i++) {
            //Populate the array
            myArray.add('Test ' + i);

            // Write value to the debug log
            System.debug(myArray[i]);
        } //end loop

        return myArray;
    }//end method       
}// end class

Some more info on Arrays and Lists, Loops, and Class methods for future reference.

[SalesForce] Filter and search is not working

I see that the code where you find actual accounts is not returned in wrapper format

    public pagereference Search()
    {
        String finalSearchValue = '%' + fullname + '%';
        Accounts = [Select Id, Name, Active__c FROM Account
                    where Name like :finalSearchValue];
        wraplist = new list<wrapData>();  
        for(Account a: Accounts)
        {
            wrapList.add(new wrapData(a));
        }
       return null;
   }

Same way apply for filter method as well.

Best Answer

Related Solutions

[SalesForce] Simple Apex class to return a list of strings

[SalesForce] Filter and search is not working

Related Topic