[SalesForce] Batch finish method getting null values

I'm implementing an apex batch process.

public class BatchName implements Database.Batchable<XYZClass.wrapper>,Database.Stateful{

I have declared an integer variable as public and assigning value to it in execute method.

Public Integer Counter=0;

When I try to access it in finish method, I am getting null value.

While declaration, when i set it to zero, I'm getting zero.
I'm unable to get the assigned integer value.

I'm using the database.stateful, as it allows you to maintain state.

Please help me. Am I overlooking anything here?

Best Answer

From the documentation:

Using State in Batch Apex

Each execution of a batch Apex job is considered a discrete transaction. For example, a batch Apex job that contains 1,000 records and is executed without the optional scope parameter is considered five transactions of 200 records each.

If you specify Database.Stateful in the class definition, you can maintain state across these transactions. When using Database.Stateful, only instance member variables retain their values between transactions. Static member variables don’t retain their values and are reset between transactions.

The following works for me...

public class Throwaway implements Database.Batchable<SObject>, Database.Stateful
{
    public Integer batches;
    public Throwaway() { batches = 0; }
    public Database.QueryLocator start(Database.BatchableContext bc)
    {
        return Database.getQueryLocator([SELECT Id FROM Account]);
    }
    public void execute(Database.BatchableContext bc, List<SObject> scope)
    {
        batches++;
    }
    public void finish(Database.BatchableContext bc)
    {
        system.assert(false, batches);
    }
}

Related Solutions

[SalesForce] Batch Apex stateful member variable behavior in test class

Yes, this is the expected behavior, but not for the reason you think. When you call Database.executeBatch, it serializes the class and keeps a copy of it. That means that the class instance you pass to Database.executeBatch is not the same instance that runs when the class is later executed (after Test.stopTest).

If you want to get the value back out (perhaps to verify the unit test behavior), you need to put the result in a static variable:

global  class SampleBatch implements      Database.Batchable<SObject>,Database.Stateful {

    global integer count;
    @TestVisible static Integer testCount;

    global SampleBatch (){count =0;} 
    //START
    global Database.QueryLocator start(Database.BatchableContext BC) {         
        return Database.getQueryLocator(queryString);                 
    }    

    //EXECUTE 
    global void execute (Database.BatchableContext BC,List<sObject> scope){
     count++;
    }
    //FINISH
    global void finish(Database.BatchableContext BC){
        testCount = count;
    }
}

You can then validate the result afterwards:

Test.startTest();
Database.executeBatch(new SampleBatch());
Test.stopTest();
System.assertEquals(1, SampleBatch.testCount);

If your batch class were doing something else, like modifying records, you could verify the results by using a query.

[SalesForce] Batch – Sending data from one batch to another

Should I implement Database.Stateful at this case? I know Database.Stateful used for passing data between executing method of the same batch. for example, counting or sum a field. Of course if the batch will be split to more than one execute I will need Database.Stateful for adding the values of the different executes to the Map, but do I need Database.Stateful for passing data through different batches?

YES - the finish() method executes in its own transaction so in order to pass the map to the next batch object, you need Database.Stateful

What it means: That Database.Stateful will drastically decrease its performance? How it manifests itself? Only the time of execution?

The biggest issue you will have is heap size as if the map is very large, you will exceed heap

Would be better to save the data in a custom object and in the second batch query the data and use it? (of course it individual, I'm talking when I need to pass a Map of Object with Set ).

This is clearly the most extensible and would allow for millions of rows. You would of course need a predictable query to find the values created by the first batch as passing millions of ids from batch 1 to batch 2 will not work

Assuming that the second Batch (Batch_B) that executed in the finish method is stuck in the queue. How the data (Map) is saved for this batch? where it saves the data? How can I know that the Data will not be deleted or override by other batch processes? How many Data can I send and Save?

The object for the second batch is serialized by SFDC with its constructor arguments. Nothing will be lost

Best Answer

Related Solutions

[SalesForce] Batch Apex stateful member variable behavior in test class

[SalesForce] Batch – Sending data from one batch to another

Related Topic