[SalesForce] BeforeInsert caused by: System.NullPointerException: Attempt to de-reference a null object

Error: There was an error creating Lead 1. Salesforce error:

dlrs_LeadTrigger: execution of BeforeInsert caused by: System.NullPointerException: Attempt to de-reference a null object Class.Helper.populateparnerId: line 23, column 1 Trigger.dlrs_LeadTrigger: line 9, column 1

So I am working on two object:

-Leads

-Partner object(Custom)

So I have a before insert Trigger on Leads, so when a new Lead is created and Partner Number Field is not blank it has to lookup for Partner_Number_Copy__c field on the Partner Object and return its Partner ID

Following Code works fine if I manually create a lead and provide a Partner Number it is populating a Partner__c field which is a lookup field to Partner object.

But when Leads are created through a Web Form I am receiving the above error.

FYI: Line 26 in the code is l.Partner__c=mapIdByPartner.get(l.Partner_Number__c).id;

public class Helper{      

         public static void populateparnerId(list<Lead> lstlead){

             set<decimal> setpartnerIds=new set<decimal>();

              for(Lead l:lstlead){
                 if(l.Partner_Number__c!=null){
                      setpartnerIds.add(l.Partner_Number__c);
                    }
             }

       //Query partner records

    map<decimal,Partner__c>  mapIdByPartner=new map<decimal,Partner__c>();

    for(Partner__c p:[Select Id,Partner_Number_Copy__c from Partner__c where Partner_Number_Copy__c  in:setpartnerIds]){
       mapIdByPartner.put(p.Partner_Number_Copy__c,p);
    }

     for(lead l:lstlead){
           if(l.Partner_Number__c!=null){
             l.Partner__c=mapIdByPartner.get(l.Partner_Number__c).id;
          }
      }
  }
}

Trigger used (also Line 9 from the error message),

if(trigger.isInsert && trigger.isBefore){ Helper.populateparnerId(trigger.new); }

Best Answer

Consider the following situation:

A Lead is coming with Partner_Number__c = '123' ('123' != null). If you do not have Partner__c record with such Partner_Number_Copy__c then mapIdByPartner.get(l.Partner_Number__c) will return null and it obviously has no Id. So you might want to modify your code as follows :

if(l.Partner_Number__c != null && mapIdByPartner.get(l.Partner_Number__c) != null){ l.Partner__c = mapIdByPartner.get(l.Partner_Number__c).id; }

This way you`ll be ready for situations when there will be no records with incoming Partner_Number__c in your system.

Related Solutions

[SalesForce] System.NullPointerException: Attempt to de-reference a null object

this is most probably happening when you try to execute this line:

update acc;

Most probably acc variable is still null at this point, which can happen because of 2 reasons:

Your Trigger.old is empty, so you never get inside the loop
staticFun.runMe is always false, so you never get inside this if-statement

Also, this line

acc = [select AccountNumberNew__c from Account where Id =: oldval.Id];

is a query inside the for-loop. The best practice is to move all queries outside the loops. Read about governor limits in Salesforce.

[SalesForce] System.NullPointerException: Attempt to de-reference a null object on After Insert trigger

Your trigger is wrong. It introduces an infinite loop, so your code will crash. Instead, use before insert/before update. Also, there's no need to copy the list. Your entire trigger can be written as:

trigger ProjectHoursTrigger on Project_Hours__c (before insert, before update) {
    UpdatePayrollPeriod.updatePayrollPeriod(Trigger.new); 
}

As for the actual error, you should be checking if the fields are null first:

public class UpdatePayrollPeriod {
    public static void updatePayrollPeriod(List<Project_Hours__c> projectHoursList) {
        for (Project_Hours__c ph : projectHoursList){
            if(ph.Year__c != null && ph.Date__c != null) {
                First_Pay_Period__c p = First_Pay_Period__c.getValues(string.valueOf(ph.Year__c));
                if(p != null && p.End_of_First_Pay_Period__c != null) {
                    ph.Payroll_Period2__c = ((p.End_of_First_Pay_Period__c.daysBetween(ph.Date__c))/14)+1;
                }
            }
        }
    }
}

For code coverage purposes, make sure your unit test is initializing the Date__c field, and the Year__c field, assuming it's not a formula.

Finally, it looks like you're using SeeAllData=false (the default test isolation mode), so you should also insert a new First_Pay_Period__c record before inserting the Project_Hours__c record.

Edit: The "p" variable in your class was not, not the field itself. This is because, as the last paragraph notes, you did not insert a First_Pay_Period__c record.

Edit 2: After a DML statement, you need to query the records back from the database to see what the final saved values are:

testHours = [SELECT PayRoll_Period2__c FROM Project_Hours__c WHERE Id = :testHours.Id];
System.assertEquals(testHours.Payroll_Period2__c, 2);

Best Answer

Related Solutions

[SalesForce] System.NullPointerException: Attempt to de-reference a null object

[SalesForce] System.NullPointerException: Attempt to de-reference a null object on After Insert trigger

Related Topic