[SalesForce] Can a schedule be executed from future method

Definitely you can use an HTTP callout as an escape mechanism. But this is pretty naughty. You'll need a Remote Site Setting and a Session ID and a global class etc etc etc (red flags, alarm bells).

May I humbly recommend the use of System.Queueable call instead of @Future. You can create a class that is constructed with any kind of argument that you want to hand in, like so:

public class DeferredHandler implements System.Queueable
{

    private Map<String,String> key2val;

    public DeferredHandler(Map<String,String> key2val) {
        this.key2val = key2val;
    }

    public void execute(System.QueueableContext objContext)
    {
        //do your @Future stuff here with this.key2val
    }

}

And invoke him from inside your batch like this:

//defer stuff
System.Queueable job = new DeferredHandler(key2val);
System.enqueueJob(job);

There is some literature about this in the docs and Josh Kaplan's awesome Queueable blog post.

Yes, Queueable can be called from Database.Batchable classes. You must go through enqueueJob for this to work:

public class BatchClass implements Database.Batchable<SObject> {
    public Database.QueryLocator start(Database.BatchableContext context) {
        return Database.getQueryLocator([SELECT Id FROM Account]);
    }
    public void execute(Database.BatchableContext context, Account[] records) {
        System.enqueueJob(new QueueClass(new Map<Id, Account>(records).keySet()));
    }
    public void finish(Database.BatchableContext context) {
    }
}

public class QueueClass implements Queueable {
    Set<Id> recordids;
    public QueueClass(Set<Id> recordIds) {
        this.recordIds = recordIds;
    }
    public void execute(QueueableContext context) {
         // Do something here
    }
}

Note that you're limited to just one enqueueJob call per execute in the Database.Batchable class. This is to prevent explosive execution (a so-called "Rabbit Virus" effect).