[SalesForce] Cannot deserialize instance of time from VALUE_STRING value

I'm trying to parse a Time field from my lightning component to my apex controller by using JSON and deserializing it in apex into an existing Object.

But unfortunately I'm always getting the error

Cannot deserialize instance of time from VALUE_STRING value 10:30:00.000Z

I already tried different Time formats and with/without quotes "" in my JSON

10:30
10:30:00
10:30:00.000
10:30:00.000Z
T10:00:00.000Z
2018-06-07T10:00:00.000Z

But nothing works.

My Org is on Spring 18 API Version 42
I have an SObject (Event__c) with a Time Field

The problem is reproducable in anonymous apex with following code

Event__c workingObject = new Event__c();
workingObject.Name = 'Lorem';
workingObject.Public_Start_Time__c = Time.newInstance(10,10,10,10);

String serializedObject = JSON.serialize(workingObject);
String mixedObject = '{"Public_Start_Time__c": "' + workingObject.Public_Start_Time__c + '", "name": "Ipsum"}';
String manualObject = '{"Public_Start_Time__c": "2018-06-07T10:00:00.000Z", "name": "Dolor"}';
try {
   Event__c banana = (Event__c)JSON.deserialize(serializedObject, Event__c.class);
}
catch(Exception ex) {
    System.debug(ex.getMessage());
}

try {
   Event__c banana = (Event__c)JSON.deserialize(mixedObject, Event__c.class);
}
catch(Exception ex) {
    System.debug(ex.getMessage());
}

try {
   Event__c banana = (Event__c)JSON.deserialize(manualObject, Event__c.class);
}
catch(Exception ex) {
    System.debug(ex.getMessage());
}

which results in the 3 following messages

Cannot deserialize instance of time from VALUE_STRING value 10:10:10.010Z or request may be missing a required field

Cannot deserialize instance of time from VALUE_STRING value 10:10:10.010Z or request may be missing a required field

Cannot deserialize instance of time from VALUE_STRING value 2018-06-07T10:00:00.000Z or request may be missing a required field

Everything I found so far was for dates or datetimes but not time only.

Best Answer

This is probably a bug, and I'd recommend contacting Salesforce Support (If you haven't already).

Heres a repo I wrote using a custom object (Test__c, with a single time field, Some_Time__c). It starts with the a demo using Time as the object, then runs the same code for Test__c. The raw Time object works, and has the same syntax as the JSON, but the JSON object fails with the same message.

Time t = DateTime.now().Time(); 
String s = JSON.serialize(t); 

System.debug(s); // "13:50:40.848Z"

Time t2 = (Time)JSON.deserialize(s, Time.class);

System.debug(t2); // 13:50:40.848Z

Test__c test = new Test__c(
    Some_Time__c = DateTime.now().Time()
);

String testString = JSON.serialize(test);

System.debug(testString);
// {"attributes":{"type":"Test__c"},"Some_Time__c":"13:50:40.850Z"}
// "13:50:40.850Z"

Test__c result = (Test__c)JSON.deserialize(testString, Test__c.class);

Some additional notes from my test runs:

Using Map<String, Object> record = (Map<String, Object>)JSON.deserializeUntyped(testString); returns a valid Time string in the map.
Trying to access this with System.debug((Time)record.get('Some_Time__c')); fails with a:

System.TypeException: Invalid conversion from runtime type String to Time
Since theres no Time.Parse method, I cant figure out a good way to get the string value back into a Time object

I spent some time writing an actual parser, which detects field types & behaves accordingly (using the fancy new switch statement). This should cover most use cases for people experiencing this issue until salesforce releases an actual fix.

Theres a few other improvements I could make, such as using the attributtes node to create the type, instead of using it as a parameter, and some extra null handling/error handling, but hey, it works!

public class GenericParser {

    public static sObject ParseSObject(String jsonString, Type typeOf) {
        JSONParser parser = JSON.createParser(jsonString); 

        sObject record = (sObject)typeOf.newInstance();

        Map<String, Schema.SObjectField> fields = record.getsObjectType().getDescribe().fields.getMap();

        while (parser.nextToken() != null) {
            if (parser.getCurrentToken() == JSONToken.FIELD_NAME) {

                if (fields.containsKey(parser.getText())) {

                    String label = parser.getText(); 

                    parser.nextValue();

                    Schema.SOAPType fieldType = fields.get(label).getDescribe().getSOAPType(); 

                    // Note that the enums type is not needed, just the value (TIME instead of Schema.SOAPType.TIME)
                    switch on fieldType {
                        when TIME {
                            record.put(label, ParseTime(parser.getText()));
                        } when BOOLEAN {
                            record.put(label, parser.getBooleanValue());
                        } when DOUBLE {
                            record.put(label, parser.getDoubleValue());
                        } when DATE {
                            record.put(label, parser.getDateValue());
                        } when DATETIME {
                            record.put(label, parser.getDateTimeValue());
                        } when INTEGER {
                            record.put(label, parser.getIntegerValue());
                        } when else {
                            record.put(label, parser.getText());
                        }
                    }
                }
            }
        }

        return record; 
    }

    public static Time ParseTime(String timeString) {
        // 14:26:41.276Z or "14:26:41.276Z"
        List<String> values = timeString.replace('Z', '').replace('"', '').split(':'); 

        // (14, 26, 41.276)         
        Integer hours = Integer.valueOf(values[0]); 
        Integer minutes = Integer.valueOf(values[1]);

        // 41.276 -> (41, 276) 
        Integer seconds = Integer.valueOf(values[2].split('\\.')[0]);
        Integer milliseconds = Integer.valueOf(values[2].split('\\.')[1]);

        return Time.newInstance(hours, minutes, seconds, milliseconds);
    }

}

As a bonus, it comes with a test class! I used a dummy object, with a ton of fields of just about every type, in order to ensure any field type works. Just about every Schema.SOAPType value is represented. Youll need to replace this with one of your own objects, but the idea is to have a generic parser, so it should work with any object & any number of fields.

@isTest
public class GenericParser_test {

    @isTest
    public static void Test_Time() {
        Time t = DateTime.now().Time(); 

        String j = JSON.serialize(t);

        Time r = GenericParser.ParseTime(j);

        System.assertEquals(t, r, 'Time values should be equal');
    }

    @isTest 
    public static void Test_Parser() {
        Test__c t = new Test__c(
            Account__c = '001c000001GWSaL', // Dummy Id to avoid DML 
            Opportunity__c = '006c000000GMQYv', 
            Some_Time__c = DateTime.now().Time(),
            Test_Checkbox__c = true,
            Test_Coord__latitude__s = 0,
            Test_Coord__longitude__s = 0,
            Test_Currency__c = 55.75, 
            Test_Date__c = Date.today(),
            Test_DateTime__c = DateTime.now(),
            Test_Email__c = 'example@example.com',
            Test_MultiPicklist__c = 'Test;Test 2',
            Test_Num__c = 77777755,
            Test_Percent__c = 80,
            Test_Picklist__c = 'Test',
            Test_Rich_Text__c = '<hr /><br /><b>Test</b><p>Text</p>',
            Test_TextArea__c = 'Text',
            Test_Url__c = 'example.org'
        );

        String j = JSON.serialize(t);

        sObject r = GenericParser.ParseSObject(j, Type.forName('Test__c')); 

        Test__c t2 = (Test__c)r; 

        Map<String, Object> startingValues = t.getPopulatedFieldsAsMap();
        Map<String, Object> result = t2.getPopulatedFieldsAsMap();

        System.assertEquals(startingValues.keySet(), result.keySet());

        for (String key:startingValues.keySet()) {
            System.assertEquals(startingValues.get(key), result.get(key));
        }
    }

}

Related Solutions

[SalesForce] Storing json as a String field is giving wrong value

The reason I asked to see all of the code is because sometimes when working with large sets of code, passing variables in and out of methods can have unexpected side effects. Is it possible you are having an issue with passing variables into and back out of methods? Apex uses pass by value for primitive data types (such as a Map or String). If at any point you set jsonAsMap = <something> you could be running into this issue. Here is a perfect example from the reference:

We’ll illustrate this with some code samples. But first, let’s step back and define these terms.

“Pass by value” means when a method is called, a second copy of the parameter variable is made in memory, and this copy is passed to the method as a parameter. This copy can be modified in the method, but the original variable in the caller is unchanged, and the changes to the copy are lost upon return.

“Pass by reference” means when a method is called, that actual variable is passed to the method.

As described in the new developer’s guide text, Apex is not passing anything by reference. It is passing the reference (i.e., the memory address) by value, which allows the developer to change fields on the object and call methods (like list.add()) on the object.

Let’s illustrate with some code. First, an example where we get apparent pass-by-reference behavior:
List fillMe = new List();
PassByWhatNow.reference(fillMe);
System.assertEquals(fillMe.size(),5);   //five items, as expected

/*  calls this method
public static void reference(List m) {
    List la = [select id, name from Account limit 5];
    for (Account a : la) m.add(a);
}
*/
In this example, the parameter passed to the function, behind the scenes, is a pointer to the fillMe collection, passed by value. That is to say, we took the memory address and copied it – but it is the same memory address number in both places. When the add() function is called on the copy, that same memory location is modified by adding the specified items to the list. So when we return to the calling program, the modifications made in the static function are visible. So far, so good.

Now let’s look at an example where things break down.
List createMe = new List();
PassByWhatNow.referenceNew(createMe);
System.assertEquals(createMe.size(),0);   //nothing in the list

/* calls this method
public static void referenceNew(List m) {
    m = new List([select id, name from Account limit 5]);
}
*/
Again, we pass a copy of the list’s memory address to the function. However, this time, the function is initializing the variable anew. When the “new” function is called, new memory is allocated. This is the big difference.

The copy of the memory address passed as a parameter is overwritten with the address of the newly allocated memory. The original, however, is not overwritten. That change in address is not known to the caller!

Any subsequent actions done in the method are on that new memory address rather than the original object address. These changes, including the addition of the Accounts to the list, can not be available to the caller, since it only knows of the original address. No actions were done on this address; the list on the caller is therefore unchanged, still empty as it was when the call was made.

While Apex usually does behave as if we’re passing variables by reference, we’re not truly passing by reference. There are a few situations where the distinction is important, as detailed here. Now you know more, and you are a stronger developer.

[SalesForce] JSON: Cannot deserialize instance of date from VALUE_STRING

Three problems here:

(a) Date receiving DateTime value.

The value should be "YYYY-MM-DD" only.

(b) Decimal receiving String value.

The value should not be in quotes.

JSON-compliant strings are more strict than normal JavaScript.

[{
  "name":"OpportunityABC",
  "CloseDate":"2017-06-03",
  "StageName":"Pre-Engagement",
  "Amount":4810308.0
}]

Best Answer

Related Solutions

[SalesForce] Storing json as a String field is giving wrong value

[SalesForce] JSON: Cannot deserialize instance of date from VALUE_STRING

Related Topic