[SalesForce] Cannot populate field value on new record with trigger

I am trying to write a simple trigger that will populate field values on a newly created record.

I'm using standard objects: Account and Opportunity

I have two custom fields on the Account object called ChiefTechOwner__c and ComputerLocation__c. I've also added these fields on the Opportunity object.

What I need is when a new Opportunity record is created (and an Account Name for that opportunity is selected), I need a trigger to get the corresponding values for the ChiefTechOwner__c and ComputerLocation__c fields associated with that given Account, and populate it on the Opportunity record.

I've written the code below.
The "Before Insert" returns null because it is querying for ID's that are not yet created. I changed it to "After Insert", but then I get a "read-only" error.

If feel like it is a common scenario; can someone help me understand how to solve this problem?

trigger UpdOppty on Opportunity (before insert) {

Map<Id,Account> relatedAccounts = new Map<Id,Account>(
    [Select Id, ComputerLocation__c, ChiefTechOwner__c
        FROM Account
        WHERE Id 
        IN (Select AccountId 
                FROM Opportunity
                WHERE Id = :Trigger.new)
     ]
     );

for (Opportunity o : Trigger.new) {

 for (Account a : relatedAccounts.values()) {

   if (a.Id == o.AccountId) {

     o.ChiefTechOwner__c = a.ChiefTechOwner__c;
     o.ComputerLocation__c = a.ComputerLocation__c; 
   }
 }

}
}

Best Answer

Your close, use a Map with the account ID from the Opportunity Records

trigger UpdOppty on Opportunity (before insert) {


    Map<Id,Account> relatedAccounts = new Map<Id,Account>();

    for (Opportunity o : Trigger.new) {
        relatedAccounts.put(o.AccountId,null);
    }

    relatedAccounts = New Map<ID,Account>([Select Id, ComputerLocation__c, ChiefTechOwner__c From Account Where Id In :relatedAccounts.keySet()]);

    for (Opportunity o : trigger.new) {
        Account a = relatedAccounts.get(o.AccountId);
        o.ChiefTechOwner__c = a.ChiefTechOwner__c;
        o.ComputerLocation__c = a.ComputerLocation__c; 

    }
}

Related Solutions

[SalesForce] Unit Test is Providing 0% Coverage for Apex Trigger

The trigger code is having lot of redundancy, So I modified it. before posting the modified code few lines of explanation what I changed. you collected account Ids twice and did the condition check twice where once is more enough. I am also made changes to the test class, where Task data is provided which is not required because the trigger has to create it once the necessary conditions are met. I am expecting this trigger should work for you, if there is any errors feel free to post as a comment.

trigger OpportunityAfter on Opportunity (after update){

    Set AccountIDs = new Set();

    for(Opportunity o : trigger.new){
        if(opp.StageName == 'Closed - Lost' && opp.Business_Line__c == 'Workforce' && 
            opp.Survey_Type__c != 'APulse' && trigger.oldMap.get(opp.Id).StageName != opp.StageName){

                AccountIDs.add(o.AccountId);
         }
    }

    Task[] tasksToInsert = new Task[]{};

    for (Account acc : [Select Id, Name, OwnerId from Account where Id IN :AccountIds]){
        for (Opportunity opp : trigger.new){
            if(opp.AccountId == acc.Id){
                Task tas = new Task();
                tas.WhatId=acc.Id;
                tas.OwnerId=opp.OwnerId;
                tas.Subject='Follow-up: ' + opp.name + ' - ' + acc.name;
                tas.ActivityDate=(opp.CloseDate + 180);
                tas.Description='Follow up to see how engagement initiatives are going and if Avatar can help. Refer to lost opportunity: ' + opp.name;
                tasksToInsert.add(tas);                                                         
            }
        }
    }
    if(tasksToInsert != null && !tasksToInsert.isEmpty())
    Database.insert(tasksToInsert);

}

@isTest
public class TestClass {

    static testMethod void myUnitTest() {

    //Set up user
    User u1 = [SELECT Id FROM User WHERE Email='abc@sampleemail.com'];
    test.startTest();  
    //Run As U1
    System.RunAs(u1){

    System.debug('Testing trigger... (single record validation)');

    //NEW Account record
    Account acc = new account();
    acc.Name = 'Test Account';
    acc.Industry = 'Healthcare';

    insert acc;

    //NEW Opportunity record
    Opportunity opp = new Opportunity();
    opp.Name = 'Test Opportunity'; 
    opp.CloseDate = System.today();
    opp.StageName = 'S1 - Investigative';
    opp.Type = 'Repeat Business - Wrkforce HC';
    opp.AccountId = acc.Id;
    opp.Survey_Type__c = 'Product Name';

    insert opp;

    opp.StageName = 'Closed - Lost';
    opp.Reason_Won_Lost__c = 'Relationship';
    opp.Business_Line__c = 'Workforce'  //added this line to meet the if condition while collecting the set of id in the trigger.

    update opp;
   test.stopTest();
    // Here I am expecting the task has been inserted and doing a query for it         and check it in the assert statement.
   Task  testTask=[Select Id, WhatId from Task where WhatId=:acc.Id];
    //Validate single insert
    System.assertEquals(acc.Id, testTask.WhatId);

    }
    }
}

[SalesForce] Updating a field with a value from parent during insert trigger

Actually you don't need to do that first insert to get the object's id. You need the id of the parent to do the query, and you should have that since it should be populated in the look-up field. I would do something like this:

// use a before insert trigger
// loop through trigger new, putting parent ids into a set<Id>
// query for parent objects, then use that list as argument in map constructor
// loop through trigger new again, get parent object from map, set field value

Update

I wanted to add a working example here to better illustrate my answer above. Note that if you are working with a look-up relationship, you should check to make sure that there actually is a parent record before trying to get a value from it.

trigger Contact on Contact (before insert){

    if (trigger.isBefore){
        if (trigger.isInsert){
            SetContactField.setAccountName(trigger.new);
        }
    }

}

public class SetContactField{

    public static void setAccountName(list<Contact> TriggerNew){

        list<Id> AccountIds = new list<Id>();

        for (Contact c : TriggerNew){
            AccountIds.add(c.AccountId);
        }

        map<Id,Account> RelatedAccounts = new map<Id,Account>([SELECT Id, Name FROM Account WHERE Id IN :AccountIds]);

        for (Contact c : TriggerNew){
            Account RelatedAccount = RelatedAccounts.get(c.AccountId);
            if (RelatedAccount == NULL){  // In a master detail relationship, this record is guaranteed to exist. 
                c.AccountName__c = NULL;
            } else {
                c.AccountName__c = RelatedAccount.Name;
            }
        }

    }

}

Best Answer

Related Solutions

[SalesForce] Unit Test is Providing 0% Coverage for Apex Trigger

[SalesForce] Updating a field with a value from parent during insert trigger

Related Topic