[SalesForce] Can’t set toAddresses on email when templateId defined

Question

Did something change recently with the SingleEmail methods that prevents using setToAddresses() when a template is used?

Background

I need to send an email to a user based and pass in the related record. However, you can't set targetObjectId to a user id if whatId has been set.

There used to be two known workarounds. First, to create a contact with the desired email address and use that for targetObjectId. Second, don't set targetObjectId and instead set toAddresses to the target user's email (see this answer). However, the docs seem to state this is no longer possible.

setToAddresses(String[]) Optional. A list of email addresses to which
you are sending the email. The maximum number of email addresses
allowed is 100. This argument is allowed only when a template is not
used.
via apex docs

I'm really hoping to avoid creating a dummy contact for this since we have a lot of triggers on that object. Am I taking crazy pills and it was never actually possible to use toAddresses with templateId or is this a recent change? If it's a recent change is there any other workaround?

Desired Usage

public static void send(Id recordId, Id templateId, String toAddress) {
    Messaging.SingleEmailMessage email = new Messaging.SingleEmailMessage();
    email.setWhatId(recordId);
    email.setTemplateId(templateId);
    email.setToAddresses(new String[] { toAddress });
    Messaging.sendEmail(new Messaging.SingleEmailMessage[] { email });
}

Resulting Error Message

System.EmailException: SendEmail failed. First exception on row 0;
first error: REQUIRED_FIELD_MISSING, Missing targetObjectId with
template: []

Best Answer

Using Newly introduced method setTreatTargetObjectAsRecipient() in Winter 16, you can send email message to any email address.

    Messaging.SingleEmailMessage email = new Messaging.SingleEmailMessage();
    email.setWhatId(recordId);
    email.setTemplateId(templateId);
    email.setToAddresses(new String[] { toAddress });   

    //Set current user as target object 
    email.settargetObjectId(UserInfo.getUserId()); 
    email.setsaveAsActivity(false);

    //This method would make sure email will not be sent to user
    email.setTreatTargetObjectAsRecipient(false); 
    Messaging.sendEmail(new Messaging.SingleEmailMessage[] { email });

Related Solutions

[SalesForce] SingleEmailMessage SetWhatId with Quote Id

So I finally got around to fixing the issue.

Just as @crop1645 said, if I simply INSERT the Task via a DML statement, I will be able to create a Task with a Quote's Id as the WhatId.

So before, as a recap, I tried something like this:

Messaging.SingleEmailMessage newEmail = new Messaging.SingleEmailMessage();
newEmail.setToAddresses(new List<String> { emailAddress });
newEmail.setTargetObjectId(quoteBeingUsed.ContactId);
newEmail.setWhatId(quotesId);
newEmail.setTemplateId(TemplateId);
newEmail.setFileAttachments(new List<Messaging.EmailFileAttachment> { newAttachment });
Messaging.sendEmail(new List<Messaging.SingleEmailMessage> { newEmail });

This resulted in throwing the following exception:

System.EmailException: SendEmail failed. First exception on row 0; first error: INVALID_ID_FIELD, Only accounts, assets, campaigns, cases, contracts, opportunities, orders, products, solutions and custom objects are allowed as whatId.: []

Now how I solved it was simple. However, I wanted to make sure I got the Task information exactly like it was done by the Email Quote button. I changed the WhatId for the SingleEmailMessage to the related OpportunityId and after the sendEmail method I followed it with:

Task newQuoteEmailTask = new Task(Subject = 'Email: ' + newEmail.getSubject(), 
     OwnerId = UserInfo.getUserId(), WhatId = quotesId, WhoId = quoteBeingUsed.ContactId,
     Status = 'Completed', ActivityDate = Date.today(), Priority = 'Normal', 
     Description = GenerateTaskComment(newEmail));
INSERT newQuoteEmailTask;

The Description's method is the following:

private static String GenerateTaskComment(Messaging.SingleEmailMessage newEmail)
{
    List<String> listOfFileNames = new List<String>();

    for(Messaging.EmailFileAttachment singleAttachment : newEmail.getFileAttachments())
        listOfFileNames.add(singleAttachment.getFileName());

    String endOfDescription = '_____________________________________________________________________'
    + '\nPowered by salesforce.com\nhttp://www.salesforce.com/';

    return 'Additional To: '+ String.join(newEmail.getToAddresses() != null ? newEmail.getToAddresses() : new List<String>(), ',')
        + '\nCC: ' + String.join(newEmail.getCcAddresses() != null ? newEmail.getCcAddresses() : new List<String>(), ',') 
        + '\nBCC: ' + String.join(newEmail.getBccAddresses() != null ? newEmail.getBccAddresses() : new List<String>(), ',') 
        + '\nAttachment'+ (listOfFileNames.size() > 1 ? 's' : '') + ': ' + String.join(listOfFileNames, ',')
        + '\n\nSubject: ' + newEmail.getSubject()
        + '\nBody:\n' + newEmail.getPlainTextBody()
        + '\n\n' + endOfDescription;
}

[SalesForce] Email not being send if whatID is set and setSaveAsActivity is true

From the Apex Code Developer's Guide:

setSaveAsActivity(saveAsActivity)

The default value is true, meaning the email is saved as an activity. This argument only applies if the recipient list is based on targetObjectId or targetObjectIds. If HTML email tracking is enabled for the organization, you will be able to track open rates.

The above method relies on you using setTargetObjectIds, to set the WhoID(s) for your email message. If you set the targetobjectIds as anything other than contacts or leads, then you'll have a problem because it creates a Task that's assigned on that Contact or Lead that can also be related to a WhatId.

setWhatId(whatId)

If you specify a contact for the targetObjectId field, you can specify an optional whatId as well. This helps to further ensure that merge fields in the template contain the correct data.

Usage:

The value must be one of the following types:

Account

Asset

Campaign

Case

Contract

Opportunity

Order

Product

Solution

Custom