[SalesForce] caseTrigger, therefore it cannot recursively update itself

Take a look at the related list on the case detail page, are they being created?

If your trigger is running when on the Case record, then no, you wont have access to the CaseHistory records at that point in time. You'll need to run the logic outside of your Case trigger, perhaps in a batch / scheduled class.

An alternative, is instead of keying off of CaseHistory, you can compare the old Case values with the new Case values in your trigger.

For example if you wanted to compare to see if the case was closed as part of this transaction, you could do the following in a trigger:

if(Trigger.oldMap == null || (Trigger.oldMap.get(currentCase.Id).Status != 'Closed' && currentCase.Status == 'Closed'))

//Edit: According to this post: How do I write test for a Histories Inner query? History records are not created as part of unit tests. Sounds like you might be out of luck. Your only options the way I see it are 1) Ignorning any CaseHistory logic in your assertions and/or 2) Implement special unit test handling for Case Histories using Test.isRunningTest()

Brian, here is a fleshed out version of your test class with some very basic asserts.

Basically, the pattern here is to do the work and then at the end query the data back out of the system and see if the results match the expectation.

@isTest
class TestCaseNeedsArchive {
    static testMethod void testCaseBeingClosedAtCreate(){
        Case caseRecord = TestUtils.createTestCase();

        // set the status as closed during insert
        caseRecord.Status = 'Closed';

        // reset governor limits for the actual test of the trigger
        Test.startTest();

        // insert the record which will be processed by the trigger
        insert caseRecord;

        // exit the testing context
        Test.stopTest();

        // check to ensure that the record that was just inserted
        // does have the Archive_Closed_Case_Needs_Update__c field set true
        List<Case> cases = [SELECT Id, Archive_Closed_Case_Needs_Update__c FROM Case WHERE Id = :caseRecord.Id];

        // there is only going to be one case in the list, but a loop does the job
        for (Case c : cases) {
            system.assertEquals(true, c.Archive_Closed_Case_Needs_Update__c, 'The value of Archive_Closed_Case_Needs_Update__c should be true.');
        }
    }

    static testMethod void testCaseBeingClosed(){
        Case caseRecord = TestUtils.createTestCase();

        // insert the record which will be processed by the trigger
        insert caseRecord;

        /* an assert can follow the insert similar to the one at the               */
        /* end of the testCaseNotClosedAtCreate() test, if you want to be thorough */

        // check to ensure that the record that was just inserted
        // does not have the Archive_Closed_Case_Needs_Update__c field set true
        List<Case> casesInserted = [SELECT Id, Archive_Closed_Case_Needs_Update__c FROM Case WHERE Id = :caseRecord.Id];

        // there is only going to be one case in the list, but a loop does the job
        for (Case c : casesInserted) {
            system.assertNotEquals(true, c.Archive_Closed_Case_Needs_Update__c, 'The value of Archive_Closed_Case_Needs_Update__c should not be true.');
        }

        // reset governor limits for the actual test of the update portion of the trigger
        Test.startTest();

        // change the status of the record and update it
        caseRecord.Status = 'Closed';
        update caseRecord;

        // exit the testing context
        Test.stopTest();

        // check to ensure that the record that was just updated
        // does have the Archive_Closed_Case_Needs_Update__c field set true
        List<Case> cases = [SELECT Id, Archive_Closed_Case_Needs_Update__c FROM Case WHERE Id = :caseRecord.Id];

        // there is only going to be one case in the list, but a loop does the job
        for (Case c : cases) {
            system.assertEquals(true, c.Archive_Closed_Case_Needs_Update__c, 'The value of Archive_Closed_Case_Needs_Update__c should be true.');
        }
    }

    // not sure what is being tested here from a logic perspective, but you can mimic the patterns of the other tests
    static testMethod void testClosedCaseEditedNeedsArchive(){
        Case caseRecord = TestUtils.createTestCase();
        caseRecord.Status = 'Closed';
        insert caseRecord;
        caseRecord.Archive_Closed_Case_Needs_Update__c = false;
        caseRecord.Subject = 'Test Subject';
        update caseRecord;
    }

    static testMethod void testCaseNotClosedAtCreate(){

        Case caseRecord = TestUtils.createTestCase();

        // reset governor limits for the actual test of the trigger
        Test.startTest();

        // insert the record which will be processed by the trigger
        insert caseRecord;

        // exit the testing context
        Test.stopTest();

        // check to ensure that the record that was just inserted
        // does not have the Archive_Closed_Case_Needs_Update__c field set true
        List<Case> cases = [SELECT Id, Archive_Closed_Case_Needs_Update__c FROM Case WHERE Id = :caseRecord.Id];

        // there is only going to be one case in the list, but a loop does the job
        for (Case c : cases) {
            system.assertNotEquals(true, c.Archive_Closed_Case_Needs_Update__c, 'The value of Archive_Closed_Case_Needs_Update__c should not be true.');
        }

    }
}