[SalesForce] Cloning Opportunities

I have a quick question that I hope you can help me with. I have built a trigger that seems to work theoretically. When we have a partner op go to a win, I need the op to be cloned with a new stage, new name and no amount (other than those fields everything else can be the same) This trigger does that – however, after cloning the first opp, all opps clone to the account associated with the first opp. When I try to remove the 'LIMIT 1' I get the error below – I appreciate any help.

Error:Apex trigger partnerOpClone caused an unexpected exception,
contact your administrator: partnerOpClone: execution of AfterUpdate
caused by: System.QueryException: List has more than 1 row for
assignment to SObject: Trigger.partnerOpClone: line 2, column 1

Here is the trigger:

trigger partnerOpClone on Opportunity (after update) {
Opportunity opp = [select Id, closedate, account.name, account.id from Opportunity where StageName = '09-Win' and type = 'Reseller / Partner Registration'  LIMIT 1];
Opportunity newOpp = opp.clone(false, true);
newOpp.StageName='Training';
newOpp.amount=null;
String oppname = opp.account.Name +' Partner'; 
newopp.Name = oppname;
newOpp.closedate=opp.closedate;
newOpp.account.id=opp.account.id;
insert newOpp;
}

Best Answer

merry you get the exception, because you run out of opportunities that meet the criteria StageName = '09-Win' and Type 'Reseller / Partner Registration'. That is because your code does not necessarily clones the opportunity the user updates, but the first opportunity that is returned by your query

Opportunity opp = [select Id, closedate, account.name, account.id from Opportunity where StageName = '09-Win' and type = 'Reseller / Partner Registration'  LIMIT 1];

I strongly recommend you read https://force.siddheshkabe.co.in/2012/01/basic-of-writing-apex-trigger.html

Below the code, that archives what you are looking for

trigger partnerOpClone on Opportunity (after update) {

// accounts ids to query
Set<Id> oppAccountIds = new Set<Id>();
// opportunities we have to clone
Opportunity[] oppsToClone = new Opportunity[]{};
// clones to save
Opportunity[] oppsToSave = new Opportunity[]{};

String STAGE_WON = '09-Win';
String TYPE_PARTNER = 'Reseller / Partner Registration';

// bulkified handling
for (Opportunity record:trigger.new)
{

    // make sure the opportunity stage has been changed to new
    if (record.StageName == STAGE_WON && trigger.oldMap.get(record.Id).StageName !=  STAGE_WON
    && record.Type == TYPE_PARTNER)

    // keep for query
    oppAccountIds.add(toCheck.Id);

    // keep opps that meet the criteria for further processing
    oppsToClone.add(record);
}


// make sure we only continue , if there are any opps we have to cline
if (oppsToClone.size() > 0)
{

    // query accounts and store by there name to lookup it up quickly
    Map<Id,Account> accountMap = new Map<Id,Account>([
        select Id
             , Name
          from Account
         where Id IN: oppAccountIds]);

    // clone the opps
    for (Opportunity record:oppsToClone)
    {
        Opportunity theClone = record.clone(false,true);
        theClone.Amount = null;
        theClone.Name = accountMap.get(record.AccountId).Name + ' Partner';
        oppsToSave.add(theClone);
    }

    insert oppsToSave;
}

}

Related Solutions

[SalesForce] Test Class fail

Here's a commented rewrite of that trigger which does not execute the aggregateResult query within the loop context of the Trigger.new collection.

Additionally, there's some code in both of your triggers which don't actually do anything as written.

trigger fulfillmentcontactcreatedopp on Opportunity (before insert, before update) {

    Map<Id, Opportunity> oppsToCheckMap = new Map<Id, Opportunity>();

    // collect the ID values of the opportunities with a stage calc value of 5 or more
    // if it is an update, the stage name must have changed
    for (Opportunity opp : trigger.new) {

        if (opp.Stage_Calc__c >= 5 ) { 

            if (trigger.isInsert || 
                trigger.isUpdate && trigger.oldMap.get(opp.Id).StageName != opp.StageName) {
                    oppsToCheckMap.put(opp.Id, opp);
            }
        }
    }

    // get an aggregate count of contact roles per opportunity in the fulfillment role
    List<AggregateResult> result = [SELECT OpportunityId
                                        , count(Id)
                                    FROM OpportunityContactRole
                                    WHERE (Role = 'Fulfillment')
                                        AND OpportunityId IN :oppsToCheckMap.keySet()
                                    GROUP BY OpportunityId];

    // iterate the results and set the number of fulfillment contacts on the opportunity
    for (AggregateResult aggCount : result) {

        /* this block of code isn't actually doing anything */
        if (aggCount.get('expr0') == 0) {

            Id oppId = (Id)aggCount.get('OpportunityId');
            Opportunity oppo = oppsToCheckMap.get(oppId);

        }
        /* this block of code isn't actually doing anything */

        // get the opportunity from the incoming map and update the value of the fulfillment contacts field
        Id oppId = (Id)aggCount.get('OpportunityId');
        Opportunity opp = Trigger.newMap.get(oppId);

        if (opp != null) {
            Integer fulcount = Integer.valueOf(aggCount.get('expr0'));
            opp.Number_of_Fulfillment_Contacts__c = fulcount;
        }
    }
}

Update

Here is the updated trigger code for the NetSuite_Sales_Order__c object with the Opportunity update statements removed from the loops. I also reformatted it for my own sanity and changed some of the odd checks for Trigger.new and Trigger.old in the if statements.

trigger celigoUpdateSalesOrder on NetSuite_Sales_Order__c (before insert, before update, before delete) {

    List<Opportunity> opportunitiesToUpdate = new List<Opportunity>();

    if (Trigger.isInsert || Trigger.isUpdate) {
        List<Id> opIds = new List<Id>();
        for (NetSuite_Sales_Order__c order : Trigger.new) {
            if (order.Opportunity__c == null) {
                continue;
            }
            opIds.add(order.Opportunity__c);
        }

        List<Opportunity> ops = [SELECT Id
                                        , StageName
                                        , StageNameState__c
                                    FROM Opportunity
                                    WHERE Id IN :opIds];

        celigo_connector__c cs = celigo_connector__c.getInstance('Opportunity Closed Stage');
        String closedStage = (cs!=null) ? cs.value__c : 'Closed Won';

        for (Opportunity o : ops) {
            if (Trigger.isInsert) {
                if (o.StageNameState__c == null) {
                    o.StageNameState__c = o.StageName;
                    o.StageName = closedStage;
                }
            }
            o.Celigo_Sync_Helper__c = true;

            // add to the list for update later
            opportunitiesToUpdate.add(o);

        }
    }

    if (Trigger.isDelete) {
        List<Id> opIds = new List<Id>();
        for (NetSuite_Sales_Order__c order : Trigger.old) {
            if (order.Opportunity__c == null) {
                continue;
            }
            opIds.add(order.Opportunity__c);
        }

        List<Opportunity> ops = [SELECT Id
                                        , StageName
                                        , StageNameState__c
                                    FROM Opportunity
                                    WHERE Id IN :opIds];

        List<NetSuite_Sales_Order__c> tOrders = [SELECT Id
                                                        , Opportunity__c
                                                    FROM NetSuite_Sales_Order__c
                                                    WHERE Opportunity__c IN :opIds];

        Map<Id, List<NetSuite_Sales_Order__c>> m = new Map<Id, List<NetSuite_Sales_Order__c>>();

        for (NetSuite_Sales_Order__c order : tOrders) {
            if (m.get(order.Opportunity__c) == null) {
                m.put(order.Opportunity__c, new NetSuite_Sales_Order__c[]{ order });
            }
            else {
                /* this code block doesn't do anything */
                List<NetSuite_Sales_Order__c> temp = m.get(order.Opportunity__c);
                temp.add(order);
                /* this code block doesn't do anything */
            }   
        }

        Set<Id> keys = m.keySet();

        for (Id i : keys) {
            List<NetSuite_Sales_Order__c> temp = m.get(i);
            Opportunity op;
            for (Opportunity tempOp : ops) {
                if (tempOp.Id == i) {
                    op = tempOp;
                    break;
                }
            }
            if (temp.size() > 1) {
                continue;
            }

            if (op.StageNameState__c == null) {
                continue;
            }

            op.StageName = op.StageNameState__c;
            op.StageNameState__c = null;

            // add to the list for update later
            opportunitiesToUpdate.add(op);
        }
    }

    // if we've got opportunities to update, do it
    if (!opportunitiesToUpdate.isEmpty()) {
        update opportunitiesToUpdate;
    }
}

[SalesForce] Cloning opportunities – identifying which deals are “clones”

You can do that using triggers. To Answer your second question, see the explanation below

First create a custom text field on Opportunity object, and let's call it RecordId.
Create a workflow rule that on create, populates RecordId with SFDC Id.
In our create trigger, you can check for the RecordId.
If RecordId == '', then the record is new.
If RecordId != ”, then the record is being cloned.

This is because trigger is executed before the workflow rule, and as a result whenever a new record is created this RecordId will not contain any value.

But when a record is being cloned this field RecordId will contain the SFDC record Id of the original object from where it is being cloned. You will be able to identify if this is new record or cloned record and take appropriate action

Actually both of your questions are related and can be answered with above solution.

Please let me know in case of any queries. If this answer helps you resolving your query, mark this as best answer.

Best Answer

Related Solutions

[SalesForce] Test Class fail

Update

[SalesForce] Cloning opportunities – identifying which deals are “clones”

Related Topic