[SalesForce] Compare two fields

I have 2 object A,B

A has 2 field id, name

B has 3 field id, name, ismatching(default 0)

Scenario is >> if I insert value in B , it should be compare B.name to A.name , if match is true then ismatching field update from 0 to 1,

I am using trigger for that but facing problem will you please suggest me .

here A is Whitelist__c and B is CrawleLink__c. and trigger is

trigger white_list_update on CrawleLink__c (before insert) 
{ 
    List <Whitelist__c> nam = [select name from Whitelist__c]; 
        for(CrawleLink__c cc : Trigger.new) { 
            for(Integer i= 0; i<nam.size(); i++) { 
                String aa= nam[i]; 
                if(aa==cc.Domain__c) { 
                cc.Whitelist__c = 1; 
            } 
        }    
    } 
}

Best Answer

Try this one.

trigger white_list_update on CrawleLink__c (before insert) 
{ 
    List <Whitelist__c> nam = [select name from Whitelist__c]; 

    Set<String> whiteListNames=new Set<String>();
    for(Whitelist__c w: nam){
        whiteListNames.add(w.name);
    } 
    for(CrawleLink__c cc : Trigger.new) { 
        if(whiteListNames.contains(cc.Domain__c)){
            cc.Whitelist__c = 1; 
        } 
    } 
}

Here i'm using SET to store names and checking if SET contain the name, set flag variable to 1.

Note: This logic should be on before update too because if name changes to a matching one the flag need to be updated.

For best practices use a separate class say White_list_updateHelper and create separate methods and call them from trigger.

Related Solutions

[SalesForce] get / compare children values on map

The children records will be contained within standard List collections under the parent object record.

Enhancing your much-too-genericized code sample:

Map<Id, Account> AcctOppCustomObjectMap = new Map<Id, Account>([SELECT Id
                                                                    ,(SELECT xxx 
                                                                        FROM xxx__r)
                                                                    ,(SELECT yyy 
                                                                        FROM yyy__r) 
                                                                FROM Account
                                                                WHERE Id IN :idSet]);

List<yyy__c> yThingsToUpdate = new List<yyy__c>();

for (Id accountId : AcctOppCustomObjectMap.keyset()) {
    Account acct = AcctOppCustomObjectMap.get(accountId);

    // the acct reference will have child lists for your subqueries
    // they will not be null, but they could be empty lists
    List<xxx__c> xxxList = acct.xxx__r;
    List<yyy__c> yyyList = acct.yyy__r;

    // iteration of the child records possible now using these two lists
    for (xxx__c xThing : xxxList) {
        for (yyy__c yThing : yyyList) {
            if (xThing.value == yThing.value) {
                // create your relationship and 
                // add to a list for bulk update / insert
                yThingsToUpdate.add(new yyy__c(Id = yThing.Id
                                                   , xxx__c = xThing.Id));

                break; // exit the for loop on the first match if desired
            }
        }
    }
}


if (!yThingsToUpdate.isEmpty()) {
    update yThingsToUpdate;
}

I would probably iterate each child list just once each to create maps of the contents by a desired key so that I could perform a Map.get() instead of repeatedly iterating lists to find the other child record to compare against. Your code sample needs more specific information in it.

Repeated iteration of the yyy list within the xxx list will limit your ability to process records since these will use script statements to iterate and match the records.

[SalesForce] Trigger to match field in another object and populate a relationship lookup

The expression trigger.newMap.keyset() contains ID's of the records and not names. Therefore your query should look like [Select Id From InForceEW_invoice_c Where Id IN :trigger.newMap.keyset()]; which SHOULD return the targeted invoices.

This will NOT return any records again, since your trigger is on the receivable object and you're querying invoices with ID of an receivable.

What you need to do to get all invoices that match a name of a receivable in your trigger, is to create a set of names (based on the receivables in your trigger) and then query all invoices which have the same name as the receivables in the trigger and work with them.

Something like this:

// build a set of receivable names
Set <String> receivableNames = new Set <String> ();

for(InForceEW_Receivable_c theReceivable : trigger.New)
{
    receivableNames.add(theReceivable.Name);
}

// Map the invoice names and the actual invoice records based on the receivable names
Map <String, InForceEW_invoice_c> matchingInvoicesMap = new Map <String, InForceEW_invoice_c> ();

for (InForceEW_invoice_c invoice : [Select Id, Name From InForceEW_invoice_c Where Name IN :receivableNames])
{
    matchingInvoicesMap.put(invoice.Name, invoice);
}

List <InForceEW_Receivable_c> receivablesToUpdate = new List <InForceEW_Receivable_c> ();

// go through the records in the trigger again and check whether we have found a matching receivable and invoic
for(InForceEW_Receivable_c theReceivable : trigger.New)
{
    if (matchingInvoicesMap.get(theReceivable.Name) != null)
    {
        // we found a mathing one
        theReceivable.Invoice__c = matchingInvoicesMap.get(theReceivable.Name).Id;

        // add it to a separate list and update it
        receivablesToUpdate.add(theReceivable);
    }
} 

update receivablesToUpdate;

Now the updating of the receivables will cause the trigger to fire again and again leading to recursive trigger and result with an error. You need to implement some sort of functionality that will prevent this. I will leave that part on you as an exercise...

Best Answer

Related Solutions

[SalesForce] get / compare children values on map

[SalesForce] Trigger to match field in another object and populate a relationship lookup

Related Topic