[SalesForce] Creating a Map with String, Object combination

I have a List of String. This list consist of accountNumbers from Account Object. List<String> accountNumList. I have a child object XYZ__c, which is child of Account Object. XYZ__c object has a custom field called status__c and flag__c

I am looking at an efficient way to build a Map of type Map<String,String>. where Key is the accountNumber and Value is the status__c field of the child object of the corresponding Account. There could be multiple children of a account. I need to get only the child whose flag__c field has 'Active' text in it and use it as the value.

What I think I should do to build this Map:

List<String> accountNumList; // has all the accountNumbers
List<Account> acc =[select id,accountNumber,(select id,status__c,flag__c from child_relation__r where flag__c=='Active') from Account where accountnumber in:accountNumList];

Map<String,String> accountMap = new Map<String,String>();
For(Account a : acc){
accountMap.put(a.accountNumber,a.child_relation__r.status__c);
}

Is this an efficient way to build the Map? Any Suggestions!

Best Answer

You need to index into your list. Before you do so, however, you have to check if the list is empty.

for (Account record : [/*query*/])
{
    if (!record.Children__r.isEmpty())
        accountMap.put(record.AccountNumber, record.Children__r[0].Status__c);
}

If you omit the empty check, than any iteration over a record without an active child would throw this error:

System.ListException: List index out of bounds: 0

Related Solutions

[SalesForce] get / compare children values on map

The children records will be contained within standard List collections under the parent object record.

Enhancing your much-too-genericized code sample:

Map<Id, Account> AcctOppCustomObjectMap = new Map<Id, Account>([SELECT Id
                                                                    ,(SELECT xxx 
                                                                        FROM xxx__r)
                                                                    ,(SELECT yyy 
                                                                        FROM yyy__r) 
                                                                FROM Account
                                                                WHERE Id IN :idSet]);

List<yyy__c> yThingsToUpdate = new List<yyy__c>();

for (Id accountId : AcctOppCustomObjectMap.keyset()) {
    Account acct = AcctOppCustomObjectMap.get(accountId);

    // the acct reference will have child lists for your subqueries
    // they will not be null, but they could be empty lists
    List<xxx__c> xxxList = acct.xxx__r;
    List<yyy__c> yyyList = acct.yyy__r;

    // iteration of the child records possible now using these two lists
    for (xxx__c xThing : xxxList) {
        for (yyy__c yThing : yyyList) {
            if (xThing.value == yThing.value) {
                // create your relationship and 
                // add to a list for bulk update / insert
                yThingsToUpdate.add(new yyy__c(Id = yThing.Id
                                                   , xxx__c = xThing.Id));

                break; // exit the for loop on the first match if desired
            }
        }
    }
}


if (!yThingsToUpdate.isEmpty()) {
    update yThingsToUpdate;
}

I would probably iterate each child list just once each to create maps of the contents by a desired key so that I could perform a Map.get() instead of repeatedly iterating lists to find the other child record to compare against. Your code sample needs more specific information in it.

Repeated iteration of the yyy list within the xxx list will limit your ability to process records since these will use script statements to iterate and match the records.

[SalesForce] Iterating inside a Map

To map them by Unique Id for later use:

Map<String, Account> existingAccounts = new Map<String, Account>();
for (Account existingAccount : [
    SELECT Unique__c FROM Account
    WHERE Unique__c IN :allUniqueIds
]){
    existingAccounts.put(existingAccount.Unique__c, existingAccount);
}

Then when iterating through you can retrieve them by that value.

String uniqueId = registration.account.Unique__c;
if (existingAccounts.containsKey(uniqueId))
    registration.account.Id = existingAccounts.get(uniqueId).Id;

Related Topic