[SalesForce] Declaring a map with String as keys and Integer as values

I'm getting two errors while compiling this snippet:

map <String,Integer> CharToNumber = new map<String,Integer>(); 

    CharToNumber.put('A', 0); 
    CharToNumber.put('B', 1);

Errors are: 1) expecting a right parentheses, found 'A'
2) UnexpectedSyntaxError(loc = RealLoc(startIndex = 42, endIndex = 43, line = 6, column = 19), message = mismatched input 'A' expecting RPAREN))

Now: I know it's not a common situation, but: can I declare a map of (having String as keys and Integer as values) ?

Best Answer

The code you have posted is valid Apex and reasonable. So the problem is either that some surrounding code is interfering - do you have something else called CharToNumber in any casing? - or that you are hitting a bug in the local compiler that is part of the Force.com IDE that you can ignore.

If you just need to initialize the map you can also use this more compact syntax for that:

map <String,Integer> CharToNumber = new map<String,Integer>{
        'A' => 0,
        'B' => 1
        };

that may work-around the problem.

Related Solutions

[SalesForce] Salesforce creating field values as map keys and results as values

Have I understood your question correctly?

1: i need to add field name like 'id,name,fld3,fld4 etc,.. as map keys

String fieldNames = String.join(new List<String>{
    SObjectType.Opportunity.Fields.Id.Name, //"Id"
    SObjectType.Opportunity.Fields.Name.Name //"Name"
}, ',');

List<Opportunity> opportunities = Database.query('SELECT ' + fieldNames + ' FROM Opportunity');

2: and results of the fields as map values

You are looking for data structure like this?

{
    "Id": [
        "006d0000008WaWzAAK",
        "006d0000008WaWpAAK",
        "006d0000008WaXHAA0"
    ],
    "Name": [
        "Pyramid Emergency Generators",
        "Dickenson Mobile Generators",
        "Grand Hotels Emergency Generators"
    ]
}

You can use a Map<String,List<Object>> data structure to hold all the field values. Then convert the SObject into a Map itself to loop over its fields easily. Here's a code sample that yields the above:

//select any fields you want
List<Opportunity> opportunities = [SELECT Id, Name FROM Opportunity]; //or from above

//prepare the data structure to hold the list of values
Map<String,List<Object>> field2values = new Map<String,List<Object>>();

//every opportunity
for (Opportunity opportunity : opportunities) {
    //we can convert any SObject into a Map
    Map<String,Object> mapOpp = (Map<String,Object>)Json.deserializeUntyped(Json.serialize(opportunity));

    //every field
    for (String key : mapOpp.keySet()) {

        //leave out the metadata
        if (key == 'attributes') continue;

        //list of values needs to be initialized the first time around
        if (field2values.get(key) == null) field2values.put(key, new List<Object>());

        //populate each value
        field2values.get(key).add(oppMap.get(key));
    }

}

System.debug(Json.serializePretty(field2values));

[SalesForce] Defining record type in Trigger

Compile Error: expecting a right parentheses, found 'Integer'

and

If(o.Campaign.RecordType == '012R00000004wJv'

Looks like your if statement is missing a right parentheses. Note that the full error message say that it found 'Integer' on the line after (line 5) the if statement - with no closing parentheses at the end of line 4, the parser kept going until it found something that didn't belong in an if statement. If you don't see the error on the line indicated, always look at the line(s) directly above.

Also, the field you need to check is RecordTypeId, not RecordType (see reference). Try this:

If(o.Campaign.RecordTypeId == '012R00000004wJv')

However, you shouldn't be hardcoding a record type id (or any id) into your code. Instead, look up the record type id by name. You could query the RecordType table, but there's a better way (reference):

trigger ObjectNameCheckProducts on Campaign (before insert, before update) {
  // Look up record type id
  String recordTypeName = 'Long-Term Strategic Products'; // <-- Change this to your record type name
  Map<String,Schema.RecordTypeInfo> rtMapByName = Schema.SObjectType.Campaign.getRecordTypeInfosByName();
  Schema.RecordTypeInfo rtInfo =  rtMapByName.get(recordTypeName);
  id recordTypeId = rtInfo.getRecordTypeId();

  for(Campaign o : Trigger.New){
    if(o.RecordTypeId == recordTypeId) {
      Integer counter = 0;

      if(o.Institutional_Products_A_G__c != null) 
        counter += o.Institutional_Products_A_G__c.split(';').size();
      if(o.Institutional_Products_G_Z__c != null)
        counter += o.Institutional_Products_G_Z__c.split(';').size();
      if(o.Intermediary_Products_A_F__c != null)
        counter += o.Intermediary_Products_A_F__c.split(';').size();
      if(o.Intermediary_Products_G_L__c != null)
        counter += o.Intermediary_Products_G_L__c.split(';').size();
      if(o.Intermediary_Products_M_Z__c != null)
        counter += o.Intermediary_Products_M_Z__c.split(';').size();

      if(counter > 5) o.addError('Max 5 values can be selected from Product lists');
    }
  }
}

Finally - Note the added braces after the initial if, wrapping the other if statements.

Best Answer

Related Solutions

[SalesForce] Salesforce creating field values as map keys and results as values

[SalesForce] Defining record type in Trigger

Related Topic