[SalesForce] Does SOSL allow the `-` dash character

Since you are using single quotes around your search term, I assume you are running this in apex inside of square brackets, like so:

list<list<sobject>> results = [find '*company\\?' in all fields returning contact (id, name)];

I also assume you are trying to search for a literal "?" in your result. It isn't intuitive, but it appears that Apex processes the string once, and then the SOSL engine processes it again. So you'll need to re-double your backslashes, like so:

list<list<string>> results = [find '*company\\\\?' in all fields returning contact (id, name)];

If you look at the apex log for my version, you'll see this:

SOSL_EXECUTE_BEGIN [1]|FIND '*company\\?' IN all FIELDS RETURNING contact(id,name)

Here it has changed each pair of backslashes into single backslash; I believe they are being converted to a single backslash by the SOSL engine.

I just had to work on this problem too. I took a slightly different approach and let regular expressions do the bulk of the effort via the Matcher.replaceAll( string ) method instead of looping and substringing myself.

The gist of my approach is below. For full comments, explanation, and unit tests please see my github repo.

public String escapeSosl( String text ) {

    // handle single quotes
    String escapedText = String.escapeSingleQuotes( text ) ;

    // remove reserved logical operators
    escapedText = escapedText.replaceAll( '(?i)( AND NOT | AND | OR )', ' ' );

    // match special characters to escape
    Pattern myPattern = Pattern.compile( '(\\?|\\&|\\||\\!|\\{|\\}|\\[|\\]|\\(|\\)|\\^|\\~|\\*|\\:|\\"|\\+|\\-)' );
    Matcher myMatcher = myPattern.matcher( escapedText );

    // escape special characters
    escapedText = myMatcher.replaceAll( '\\\\\\\\$1' );

    // collapse extra whitespace
    escapedText = escapedText.replaceAll( '( )+', ' ' ).trim();

    return escapedText;
}

I used the String.escapeSingleQuotes(text) method to handle the single quotes. I could not get it to work via regular expressions, I always ended up with too few or too many extra slashes \.

If the original input contains itself slashes \ then that may cause issues. Like the single quotes, I had issues getting the regular expression and replacement to yield the correct number of escaping slashes. As such, my code does not support trying to escape \ from the original input.