[SalesForce] Exact Target Ampscript Data Extension Key, what is it

I'm attempting to follow the first example shown on http://help.exacttarget.com/en-US/documentation/exacttarget/content/ampscript/ampscript_syntax_guide/data_extension_ampscript_functions/ and it says that variable 3 and 4 are related to the data extension key but it doesn't specify what it is.

S1 The name of the data extension for the claim or retrieve action

S2 The name of the column in the data extension that indicates whether the row is claimed or not

S3 The name of the data extension key column

S4 The value of the data extension key column

Based on their example code and database they show i'm going to assume that data extension key is not the Primary Key in the data table. It also doesn't appear to be the data extensions External Key. So what is it?

Here is my current Ampscript

%%[VAR @CouponRow
SET @CouponRow = ClaimRow("newsletter_coupon_20", "IsClaimed", "newsletter_coupon_20_key", newsletter_coupon_20_key )
IF EMPTY(@CouponRow) THEN ]%%
No Coupon Available
%%[ ELSE ]%%
Coupon Code = %%= FIELD(@CouponRow, "coupon_code") =%%
%%[ ENDIF ]%%

It returns this error when I try to validate it

Error 1: Script SET Statement Invalid
An error occurred when attempting to resolve a script expression. See inner exception for detail. Script Expression: ClaimRow("newsletter_coupon_20", "IsClaimed", "newsletter_coupon_20_key", newsletter_coupon_20_key ) MemberID: redacted JobID: 0 The specified attribute or custom object field name was not found for this client. Function Call: ClaimRow("newsletter_coupon_20", "IsClaimed", "newsletter_coupon_20_key", newsletter_coupon_20_key ) Attribute or Field Name: newsletter_coupon_20_key
Invalid Content:
SET @CouponRow = ClaimRow("newsletter_coupon_20", "IsClaimed", "newsletter_coupon_20_key", newsletter_coupon_20_key )

I've been digging around in the Exact Target Help and I can't locate a description of what the Data Extension Key is.

Best Answer

This is referring to a field in the coupon data extension, and the value you would like to populate it with. You can populate extra fields in the coupon data extension so that you can reference information about who claimed the coupon. The example on ET's help docs uses JobID, ListID, BatchID, SubscriberID, EmailAddress and ClaimedDate.

The reason you are getting an error because you are trying to insert the value of the attribute newsletter_coupon_20_key into the field newsletter_coupon_20_key in the data extension newsletter_coupon_20. This attribute either does not exist in your profile attributes, or in the Sendable DE you are attempting to deploy to, or the field "newsletter_coupon_20_key" does not exist in the coupon DE.

If you want the bare minimum for claiming a row, you could simply write:

SET @CouponRow = ClaimRow("newsletter_coupon_20", "IsClaimed")

However I do not recommend this approach because you are left with almost no information on who claimed the coupon or when that happened.

My suggestion is to set up the coupon DE using ET's example specification, which looks like this: Coupon Data Extension Example

Then, the code to claim a row would look like this:

set @CouponRow = ClaimRow("newsletter_coupon_20", "IsClaimed", "JobID", JobID, "ListID", ListID, "BatchID", _JobSubscriberBatchID, "SubscriberID", SubscriberID,"EmailAddress",EmailAddress)

(Notice the correlation between the DE fields, and the name/value pairs in the function)

You may also wish to add additional fields to the coupon DE. For instance you may want to add a "CampaignName" field, and populate it with the friendly name "Newsletter". Adding that would look something like this:

set @CouponRow = ClaimRow("newsletter_coupon_20", "IsClaimed", "CampaignName", "Newsletter")

Note that "Newsletter" is a string, not a variable, which is why it is in quotes.

Related Solutions

[SalesForce] Data extension field name is invalid, multiple errors

First, I'd suggest setting a primary key on your MatthewDataExtension Data Extension, since the ClaimRow() function is doing an update.

Also, every pair of ClaimRow() parameters after the 2nd needs to be the variable name and then the variable value -- in order to retrieve the proper row. So if you're going to update WebPromoCode and StoreCouponCode, your function would be this:

%%[

var @numberCustomer
var @WebPromoCode
var @StoreCouponCode
set @numberCustomer = AttributeValue("Customer_No")
set @WebPromoCode = AttributeValue("WebPromoCode")
set @StoreCouponCode = AttributeValue("StoreCouponCode")

set @couponDataExtensionRow = ClaimRow("MatthewDataExtension", "isClaimed", "WebPromoCode", @WebPromoCode, "StoreCouponCode", @StoreCouponCode , "Customer_No", @numberCustomer)

/* Snip */ 

]%%

If it helps, here's my go-to coupon claiming AMPScript:

%%[

var @couponRow, @couponCode, @rows, @row, @emailaddr

set @emailaddr = AttributeValue("emailaddr")

set @rows = LookupRows("couponCodes","EmailAddress",@emailaddr)

if rowcount(@rows) > 0 then
  set @row = Row(@rows,1)
  set @couponCode= field(@row,"couponCode")
else

    if _messagecontext == "PREVIEW" then
           set @couponCode = "XX TEST XX"
    else

      set @couponRow = ClaimRow("couponCodes","IsClaimed","EmailAddress",emailaddr) 

          if empty(@couponRow) then
             /* You can do other error handling here if you want.*/
             /* This aborts the send */
             raiseError("no more coupons available")
          else 
             set @couponCode= field(@couponRow,"couponCode") 
          endif

    endif 

endif

]%%

Here's your coupon code: %%=v(@couponCode)=%%

There are a few more details about the Data Extension on in my blog post on the subject.

[SalesForce] Amscript error in marketing cloud salesforce

This is not proper syntax:

%%[ if @orderCounter > 0 then do ]%%

Should be this:

%%[ if @orderCounter > 0 then ]%%

You're also missing a <tr> before the cell containing this code:

TOTAL: %%=FORMAT(@orderTotal, "C2")=%%

Not sure what else could be in play since you didn't post all of the email code. The first part of the error says you're missing some required personalization strings, which may be included in the part that's missing.

Best Answer

Related Solutions

[SalesForce] Data extension field name is invalid, multiple errors

[SalesForce] Amscript error in marketing cloud salesforce

Related Topic