[SalesForce] Generic SObject update pattern

Question

I know that it is possible to update a generic of List<SObject>, But what is the best approach to generate that list without knowing the SObjectType, only the ids ?

Sample:

 List<SObject> l = new List<SObject>();
 
 SObject o1 = new SObject(id='xxxxxx'); //this Id could be an Account
 o1.Name = 'Test';
 l.add(o1);


 SObject o2 = new SObject(id='xxxxxx'); //this Id could be a Custom
 o2.Name = 'Test' 
 l.add(o2); 
 
 //this is possible
 update l;

Unfortunately, SObject constructor doesn't allow id as parameter.

Backgound:

I'm trying to make a generic WS which will receive a list of objects to update( or upsert). The received object could by any type.

WS Request sample:

  [
   {id:'xxxxx',Name:'Test'},
   {id:'yyyyy',Name:'Test 2'},
   {id:'zzzzz',Name:'Test 3'}
  ]

The id attribute cloud be from any SObject.( I know the extra attr to update always exist).

Thanks in advance for your time.

Best Answer

Once you have the sObjectType you should be able to construct the sObject instance using the sObjectType.newSObject(ID Id) method. You can get the sObjectType from the Id using the Id.getSObjectType() method;

Map<Id, String> idsToUpdate = new Map<Id, String>();

// Put the Id's and associated name values in the map

List<SObject> sObjectsToUpdate = new List<SObject>();

for (Id idToUpdate : idsToUpdate.keySet()) {
    SObject o1 = idToUpdate.getSObjectType().newSObject(idToUpdate);
    // Set the Name field dynamically
    o1.put('Name', idsToUpdate.get(idToUpdate));
    sObjectsToUpdate.add(o1);
}

update sObjectsToUpdate;

Related Solutions

[SalesForce] Upsert Detail object without external Id

If I understand correctly, you have a list ? If this is the case, what happens if you cast the list to a map? This is going to be highly dependent on the context of execution but this might help.

Map<Id,bObj__c> mapOfAwesome = new Map<Id, bObj__c>(bObjectList);

Again, not knowing the context of execution this could be another red herring.

[SalesForce] Apex Cast sObject list dynamically to a specific sObject Type

I know this approach is strange because you are still working with a List<SObject>, but when you assign it you can make it more specific (e.g. List<Account>) by using Type.forName and Type.newInstance methods.

public static void dynamicUpsert(List<SObject> records)
{
    Schema.SObjectType sObjectType = records.getSObjectType();
    if (sObjectType != null)
    {
        String listType = 'List<' + sObjectType + '>';
        List<SObject> castRecords = (List<SObject>)Type.forName(listType).newInstance();
        castRecords.addAll(records);
        upsert castRecords;
    }
}

The getSObjectType call may not be completely reliable, especially since some of these records are being inserted and hence won't have ids. For that reason, it is probably better to accept sObjectType as an additional parameter instead of trying to determine it on the fly.

public static void dynamicUpsert(List<SObject> records, SObjectType sObjectType)
{
    String listType = 'List<' + sObjectType + '>';
    List<SObject> castRecords = (List<SObject>)Type.forName(listType).newInstance();
    castRecords.addAll(records);
    upsert castRecords;
}

Update

Some bad news, as discovered here (actually earlier than your post), the above methodology does not always work. Specifically, if I want to perform a partial upsert and also specify an external Id field, I get a compile fail.

Database.upsert(castRecords, externalIdField); // compiles, throws TypeException
Database.upsert(castRecords, /*allOrNone*/ false); // compiles, throws TypeException
Database.upsert(castRecords, externalIdField, /*allOrNone*/ false); // compile fail

Additional Update

I have a case open with support and it has been escalated to Tier 3. Currently the responses I'm getting are all along the lines of "will update you tomorrow," but I will post here if I get any resolution.