[SalesForce] How to compare one Map keyset with another Map’s field-value

I am trying to compare a map that contains Contact ids to the Map that holds ContactId as one of the fields that I have queried in each key-value pairs.

Map<Id, Contact> relatedContIdsMap = new Map<Id, Contact>(selectedContacts);
Map<Id, OpportunityContactRole> relatedOppConRoleMap = 
                    new Map<Id, OpportunityContactRole>([Select Id, ContactId 
                                                        From OpportunityContactRole
                                                        Where OpportunityId 
                                                        IN :relatedOppMap.keySet() ]);

How can I have a condition to compare the ContactIds of the map: relatedContIdsMap to the ContactIds that are retrieved in the map: relatedOppConRoleMap.

I have come across this: containsKey(key) from the developer docs, which seems to compare the actual key of a map, but not a particular field inside a map.

Best Answer

You can't, at least not without iterating over the values of your relatedOppConRoleMap (which, at first glance, kinda defeats the purpose of storing your OpportunityContactRoles in a map in the first place).

To get around this issue, you can simply iterate over your query results and build your map by yourself (instead of using the map constructor).

Map<Id, Contact> relatedContIdsMap = new Map<Id, Contact>(selectedContacts);
Map<Id, OpportunityContactRole> relatedOppConRoleMap = new Map<Id, OpportunityContactRole>();

for(OpportunityContactRole ocr :[Select Id, ContactId From OpportunityContactRole Where OpportunityId IN :relatedOppMap.keySet()]){
    relatedOppConRoleMap.put(ocr.ContactId, ocr);
}

// You can now access the OCR records based on the contactId
for(Contact cont :relatedContIdsMap.values()){
    OpportunityContactRole myOCR = relatedOppConRoleMap.get(cont.Id);
}

// ...or do other operations, like getting rid of all of the OCRs for 
//   Contacts that you didn't previously select
relatedOppConRoleMap.keySet().retainAll(relatedContIdsMap.keySet());

Related Solutions

[SalesForce] Compare Value of One Map with Key of Another Map to create new Map

Yes, there is.

You can use the containsKey() method of the map class.

if(groupDefinitionIds.size()>0){
    // Iterate over just one of your maps
    for(Id groupDefId: groupDefinitionIds.keyset()){
        // Assuming the keys in both maps are the same, you can simply use
        //   containsKey()
        // By "same keys", I mean that a key from one map can exist in the other.
        // This wouldn't work if, for example, one map held Account Ids, and the
        //   other held Opportunity Ids
        if(groupAssignmentIds.containsKey(groupDefId)){
            groupProgramIds.put(groupDefId, groupAssignmentIds.get(assignId));    
        }
    }
}

There's even a way that you can avoid having any explicit loop at all! (I say "explicit" loop, because the back-end implementation of at least some of the collection class methods probably involves a loop of its own)

// Step 1, clone the map you want to use the values from
Map<Id, MyClass> groupProgramIds = groupAssignmentIds.clone();

// Step 2, keeping/removing keys from a map removes the access to the associated values as well.
// map.keySet().removeAll()/retainAll() does just that
groupProgram.keySet().retainAll(groupDefinitionIds.keySet());

[SalesForce] How to check if a field value contains a value from map

Rather than loop through for loop, you should add that lstSubIssues in the query.

You don't need to create separate Map for this lists, Since for subIssue1, Subject_Details__c = 'Registration', similarly for subIssue2, twh.Subject_Details__c = 'Activation'.

After getting the list of Task, loop though the tasks and use subIssue1.contains(twh.SubIssue__c) to find the matching values and then update accordingly.

Note: Don't try to hardcode RecordtypeId, rather use from metadata.

Here is entire code:

List<String> subIssue1 = new List<String>{'Issue Uploading Docs (KTP)',
                                           'Issue Uploading Docs (KK)',
                                           'Issue Uploading Docs (NPWP)',
                                           'Issue Uploading Docs (All)',
                                           'Wrong Docs Request to re-submit (KTP)',
                                           'Wrong Docs Request to re-submit (NPWP)',
                                           'Wrong Docs Request to re-submit (KK)'};
List<String> subIssue2 = new List<String>{'Member Activation Request (Manager)',
                                          'Member Activation Request (VP)',
                                          'Member Activation Request (TL)'};
List<String> lstSubIssues = new List<String>();
lstSubIssues.addAll(subIssue1);
lstSubIssues.addAll(subIssue2);                   

List<Task> taskWithSub = [SELECT Id, SubIssue__c, CustomerHappiness__c, Subject_Details__c 
FROM Task 
WHERE RecordTypeId = '<recordTypeId>' 
AND SubIssue__c IN:lstSubIssues  
AND Subject_Details__c = 'It has been changed'  ];

if(!taskWithSub.isEmpty()){
    for(Task twh : taskWithSub){
        if(subIssue1.contains(twh.SubIssue__c)) {
            twh.Subject_Details__c = 'Registration';
        }
        if(subIssue2.contains(twh.SubIssue__c)) {
            twh.Subject_Details__c = 'Activation';
        }  
    } 

    update taskWithSub; //here update
}

Best Answer

Related Solutions

[SalesForce] Compare Value of One Map with Key of Another Map to create new Map

[SalesForce] How to check if a field value contains a value from map

Related Topic