[SalesForce] How to dynamically create JSON from many dot-separated strings (for example project.owner.name)

I have many strings in the custom setting with and without dot-separated field names. For example:

id
name
owner.name
owner.id
project.key
project.owner.name
project.owner.id
document.owner.parentPerson.name

I want to dynamically create JSON string with all these fields. My expected result is:

{  
    "id":"some value",
    "name":"some value",
    "owner":{  
        "name":"some value",
        "id":"some value"
    },
    "project":{  
        "key":"some value",
        "owner":{  
            "name":"some value",
            "id":"some value"
        }
    },
    "document":{
        "owner":{
            "parentPerson":{
                "name":"some value"
            }
        }    
    }
}

How can I do this? Thanks!

Best Answer

This (cursorily tested) code is the sort of thing I would write:

String[] names = new String[]{'k', 'k0.k1'};
String[] values = new String[]{'v', 'vv'};

Map<String, Object> root = new Map<String, Object>();
for (Integer j = 0; j < names.size(); j++) {
    String name = names[j];
    String value = values[j];
    Map<String, Object> m = root;
    String[] parts = name.split('\\.');
    for (Integer i = 0; i < parts.size(); i++) {
        String part = parts[i];
        if (i == parts.size() - 1) {
            // At last part so put value
            m.put(part, value);
        } else {
            // Before last part so put map
            Map<String, Object> mm = (Map<String, Object>) m.get(part);
            if (mm == null) {
                mm = new Map<String, Object>();
                m.put(part, mm);
            }
            m = mm;
        }
    }
}
String jsonString = JSON.serializePretty(root);
System.debug(jsonString);

Related Solutions

[SalesForce] How to efficiently compare two strings(values semi-colon separated) and find added or removed values in Apex

You can use Set methods here. As an example:

String newValue = 'A;D;B';
String oldValue = 'C;A';

Set<String> newValues = new Set<String>(newValue.split(';'));
Set<String> oldValues = new Set<String>(oldValue.split(';'));

Set<String> added = newValues.clone();
added.removeAll(oldValues);
Set<String> removed = oldValues.clone();
removed.removeAll(newValues);

system.debug(added); // yields {B,D}
system.debug(removed); // yields {C}

[SalesForce] How to create a recursive method in Apex which takes a dot notation string and convert it into Hierarchical Map/Json

I've done exactly this before. Here's working code for it:

public class JsonBoxer {

    public Map<String, Object> root {get; private set;}

    public JsonBoxer() {
        this.root = new Map<String, Object>();
    }

    public void put(String key, Object value) {
        doPut(root, key.split('\\.'), value);
    }

    private void doPut(Map<String, Object> currentRoot, List<String> keyChain, Object value) {
        if(keyChain.size() == 1) {
            currentRoot.put(keyChain[0], value);
        } else {
            String thisKey = keyChain.remove(0);
            Map<String, Object> child = (Map<String, Object>)currentRoot.get(thisKey);
            if(child == null) {
                child = new Map<String, Object>();
                currentRoot.put(thisKey, child);
            }

            doPut(child, keyChain, value);
        }
    }
}

Even with a test:

@IsTest
private class JsonBoxerTest {

    @IsTest static void noBoxing() {
        JsonBoxer boxer = new JsonBoxer();

        boxer.put('a', 'b');

        System.assertEquals('b', boxer.root.get('a'));
    }

    @IsTest static void boxing() {
        JsonBoxer boxer = new JsonBoxer();

        boxer.put('a.1', 'b');

        System.assertEquals('b', ((Map<String, Object>)boxer.root.get('a')).get('1'));
    }

    @IsTest static void twoSubKeyValues() {
        JsonBoxer boxer = new JsonBoxer();

        boxer.put('a.1', 'b');
        boxer.put('a.2', 'c');

        System.assertEquals('b', ((Map<String, Object>)boxer.root.get('a')).get('1'));
        System.assertEquals('c', ((Map<String, Object>)boxer.root.get('a')).get('2'));
    }

    @IsTest static void overwriteSubKey() {
        JsonBoxer boxer = new JsonBoxer();

        boxer.put('a.1', 'b');
        boxer.put('a.1', 'c');

        System.assertEquals('c', ((Map<String, Object>)boxer.root.get('a')).get('1'));
    }
}

Best Answer

Related Solutions

[SalesForce] How to efficiently compare two strings(values semi-colon separated) and find added or removed values in Apex

[SalesForce] How to create a recursive method in Apex which takes a dot notation string and convert it into Hierarchical Map/Json

Related Topic