[SalesForce] How to i create dynamic filtering report with the user input

You can bind apex:inputText to a variable on your controller. You can bind apex:inputField to an sObject field in your controller When you hit the commandButton the viewstate will be transmitted and the variable assignment will happen, you don't need to explicitly pass in the value as a parameter. Just access the variable in your controller as normal.

This Visualforce table can display a table of arbitrary fields from arbitrary SObjects by making use of map syntax:

<apex:page controller="MyController">
    <apex:pageBlock>
        <apex:pageBlockTable value="{!items}" var="item">
            <apex:repeat value="{!keys}" var="key">
                <apex:column value="{!item[key.sob][key.field]}"/>
            </apex:repeat>
        </apex:pageBlockTable>
    </apex:pageBlock>
</apex:page>

The corresponding controller - I've just used some random queries for this example - looks like this:

public with sharing class MyController {
    public class Key {
        public String sob {get; set;}
        public String field {get; set;}
        Key(String sob, String field) {
            this.sob = sob;
            this.field = field;
        }
    }
    public List<Map<String, SObject>> items {
        get {
            List<Map<String, SObject>> l = new List<Map<String, SObject>>();
            Account[] accounts = [select Name from Account limit 5];
            Contact[] contacts = [select FirstName, Birthdate from Contact limit 5];
            for (Integer i = 0; i < 5; i++) {
                Map<String, SObject> m = new Map<String, SObject>();
                m.put('Account', accounts[i]);
                m.put('Contact', contacts[i]);
                l.add(m);
            }
            return l;
        }
    }
    public Key[] keys {
        get {
            return new Key[] {
                    new Key('Contact', 'Birthdate'),
                    new Key('Account', 'Name'),
                    new Key('Contact', 'FirstName')
                    };
        }
    }
}

It is the keys array returned that determines the table columns displayed with one attribute choosing the SObject and the other attribute choosing the field in that SObject. By referencing the field directly the column heading and presentation formatting are automatically driven by the field's metadata.

Note that this is not a typical solution. In Salesforce, tables usually only contain fields from one object.