[SalesForce] How to set ParentID field on Account record related to contact in a Trigger

I have a trigger that is firing on before insert on the Contact object. I am trying to set the parent ID field on the Account record that the Contact is associated with.

I can't seem to access the related account through the contact in Trigger.New. My trigger calls method in a class which is shown below.

What code is needed to set the parentID field of the Account associated with each possible contact record that gets passed into this method?

 public static void setParentAccount(List<Contact> contacts) {

    Set<String> domains = new Set<String>();

    for(Contact record: contacts) {
      if(record.email != null) {
       domains.add(record.email.split('@')[1]);
      }
    }

   Map<String, Id> accountsByDomain = new Map<String, Id>();

   for(Account record: [select account_domain__c from account where account_domain__c = :domains]) {
     accountsByDomain.put(record.account_domain__c, record.Id);
   }
  }

  for(Contact record: contacts) {
    if(record.email != null) {
      // the ID of the parent account I want to set on the related Account of this contact
      Id accountId = accountsByDomain.get(record.email.split('@')[1]);

     //  **** Here I want to set the parentId field on the associated account equal to "accountId"
    }
  }

Best Answer

You are getting the AccountId from accountsByDomain map which you want to set on the Contact's Account ParentId. Please see below code to achieve this.

Take one list of Account which we will use to update the Contact's Account.

List<Account> lstAccount = new List<Account>();
for(Contact record: contacts) {
   if(record.email != null) {
      // the ID of the parent account I want to set on the related Account of this contact
      Id accountId = accountsByDomain.get(record.email.split('@')[1]);
      if(record.AccountId != null)
          lstAccount.add(new Account(Id = record.AccountId, ParentId = accountId));
    }
}
update lstAccount;

Related Solutions

[SalesForce] I have created a trigger ..i am updating contact address using account address

Please see code below and comments inside

trigger Account on Account (after insert, after update) {
    List<Contact> contactsForUpsert = New List<Contact>();

    // We want to avoid SOQL inside the for loop, because it might be a reason of troubles
    // and in order to follow best practices, thus we queried all needed information about Contacts
    // which are related with Accounts which are under insert/update
    // You have to think in 200 record's context when working with triggers
    // -->
    Map<Id, Contact> contactsByAccountId = new Map<Id, Contact>();
    List<Contact> contacts = [SELECT Id,
                                     AccountId,
                                     mailingstreet,
                                     mailingcity,
                                     mailingstate,
                                     mailingpostalcode
                            FROM Contact WHERE AccountId IN: Trigger.newMap.keySet()];
    for (Contact cont: contacts) {
        contactsByAccountId.put(cont.accountId, cont);
    }
    // <-- finished collecting information about Contacts. All contacts were placed in Map<AccountId, Contact>

    for (Account account: Trigger.new) {
        // old records are available only in update call
        Account old;
        if (Trigger.isUpdate) {
            old = Trigger.oldMap.get(account.Id);
        }
        // we want to perfoem the update of contact address fields in two cases:
        //  1. we insert new account, but there is a question: is that right business case for inserting Contact record here?
        //  2. we updated ShippingAddress in an exisitng account, I do believe that we do not want to update Contact record 
        //  each time when other fields were changed
        Boolean isShippingAddressChangedOrNew = Trigger.isInsert ? true :
                                                (   account.ShippingStreet != old.ShippingStreet
                                                 || account.ShippingCity != old.ShippingCity
                                                 || account.ShippingState != old.ShippingState
                                                 || account.ShippingPostalCode != old.ShippingPostalCode
                                                 || account.ShippingCountry != old.ShippingCountry) ? true : false;
        // check that field was changed
        if (isShippingAddressChangedOrNew) {
            // get existing Contact if exist
            Contact relatedContact = contactsByAccountId.get(account.Id);
            if (relatedContact == null) { // for insert call we create new Contact record
                relatedContact           = new Contact();
                relatedContact.AccountID = account.Id;
                relatedContact.LastName = 'test';
            }
            relatedContact.mailingstreet     = account.Shippingstreet;
            relatedContact.mailingcity       = account.Shippingcity;
            relatedContact.mailingstate      = account.Shippingstate;
            relatedContact.mailingpostalcode = account.shippingpostalcode;
            contactsForUpsert.add(relatedContact);
        }

    }

    try {
        upsert contactsForUpsert;
    } catch(Dmlexception e) {
        System.debug(LoggingLevel.ERROR, 'Contact insert from createopp.trigger has failed with message:' + e.getMessage());
    }
}

Read articles about trigger best practice:

[SalesForce] Create case with no accountId although contact has related account

Create an additional lookup relationship with Contact on the Case object
Use the newly created Contact field in your Pagelayout and hide the Original one.
Use a Workflowrule or process to update the original Contact lookup field with the Value in your newly created Contact field.

Related Topic