[SalesForce] How to use Type.forName to deserialize a generic list of SObjects

When the new Apex type methods were added in Summer '12, it was possible to do

Type t = Type.forName('MyClass');
MyClass newObj = (MyClass)t.newInstance();

What is the equivalent when I want to instantiate a List of such a class for which I only know the name at runtime?

I am also trying to create multiple records using JSON.deserialize. I think the answer to the earlier question may also help me with creating a List of such objects with JSON.deserialize(jsonStringOfSeveralObjects, appropriateListClass).

Note: I am able to use a Type method to create a record of a custom object like this:

Type oType = Type.forName(‘MySobjectName’);                                           
sObject rec = (sObject) JSON.deserialize(jsonString, oType);

But when the JSON string is an array of objects I am unable to use a method similar to the example shown below:

List<InvoiceStatement> deserializedInvoices = 
    (List<InvoiceStatement>)JSON.deserialize(JSONString, List<InvoiceStatement>.class);

Can you suggest the right format to use with List<> to create multiple records? I am specifically looking for corresponding substitutes for List<InvoiceStatement> and List<InvoiceStatement>.class that can be dynamically determined.

Best Answer

The trick is to deserialize into a List<SObject>. This works for me:

String jsonString = '[{"Name":"A1"},{"Name":"A2"}]';
Type t = Type.forName('List<Account>');
List<SObject> lo = (List<SObject>)JSON.deserialize(jsonString, t);
for (SObject o : lo) {
    System.debug(o.getSObjectType().getDescribe().getName() + ', Name: ' + o.get('Name'));
}

Output:

Account, Name: A1
Account, Name: A2

Related Solutions

[SalesForce] Can you use generics in Apex

NOTE: This answer is not useful for any code saved in v26.0 or later.

See Winter '13 Release Notes pg. 191 (193 of the PDF)

Take a look at the Parameterized Typing and Interfaces section in the Apex Developer's Guide. This is what you are looking for, I'm pretty sure.

The other way that Generics are commonly used in Apex are what you stated which is in the Collections and Batch Apex classes.

For example, without generics you'd have something like:

List contacts = new List();
contacts.add(new Contact());
contacts.add(new Account());  // uh oh.

With generics you have the compile time type safety:

List<Contact> contacts = new List<Contact>();
contacts.add(new Contact());
contacts.add(new Account()); // won't save/compile because the list knows it only has Contacts.

So, in theory there's some generic code somewhere in the Apex system that handles all of the List work such as:

public class List<T> {
    public void add(T element) { 
      // do the magic
    }
    public T get(Integer index) {
      // do the magic
    }
}

[SalesForce] the correct JSON to deserialize a map of sObjects

You need to use the typed deserialize method as follows...

String jsondata = '{ "Account" : { "attributes":{"type":"Account"},"BillingCity" : "testCity"}, "Opportunity" : { "attributes":{"type":"Opportunity"},"Name" : "testOpp"}}';
Map<String, SObject> mapJsonObjects = (Map<String, SObject>)
    JSON.deserialize(jsondata, Map<String, SObject>.class);
Account objAccount = (Account) mapJsonObjects.get('Account');
System.debug('Account BillingCity is ' + objAccount.BillingCity);
Opportunity objOpportunity = (Opportunity) mapJsonObjects.get('Opportunity');
System.debug('Opportunity Name is ' + objOpportunity.Name);

The trick is using the .class property to get the class type of the typed Map.

Map<String, SObject>.class

Results in

DEBUG|Account BillingCity is testCity

DEBUG|Opportunity Name is testOpp

Best Answer

Related Solutions

[SalesForce] Can you use generics in Apex

[SalesForce] the correct JSON to deserialize a map of sObjects

Related Topic