[SalesForce] How to use upsert in REST callout JSON

"Upsert" just inserts new records from JSON, but not updates existing.

It's my code:

public class myClass {

@future (callout = true)
public static void getCallout(){

    Http http = new Http();
    HttpRequest request = new HttpRequest();
    request.setEndpoint('https://api.myjson.com/bins/m56qw');
    request.setMethod('GET');
    HttpResponse response = http.send(request);

    if (response.getStatusCode() == 200){
        List<Object> jsonList = (List<Object>) JSON.deserializeUntyped(response.getBody());
        List<Product2> productList = new List<Product2>();

        for(Object o : jsonList){
            Map<String, Object> results = (Map<String, Object>) o;
            Product2 prod = new Product2();
            prod.Cost__c = Integer.valueOf(results.get('cost'));
            prod.Warehouse_Key__c = String.valueOf(results.get('sku'));  //My key to check a record
            productList.add(prod);  
        }
        if(productList != null){
            upsert productList;  //It just inserted, but not update existing records if I change them
        }
    }
  }
}

What am I doing wrong?

Best Answer

To make upsert update records you have to specify either record Id or External Id. When neither is specified, Salesforce treats the record as new and inserts it.

Example with record Id:

Product2 prod = new Product2();
prod.Id = '<salesforce id here>';

upsert prod;

Example with record External Id:

Product2 prod = new Product2();
prod.Warehouse_Key__c = '<extenral id here>';

upsert prod Warehouse_Key__c; // this is important since it specifies the field which Salesforce will use to match the record.

Upserting Records

To determine whether a record already exists, the upsert statement or Database method uses the record’s ID as the key to match records, a custom external ID field, or a standard field with the idLookup attribute set to true.

Related Solutions

[SalesForce] Split a single field into 2 columns for a VF page

This is untested so you may need to have play, however this should return a List of the RevenueWrapper classes which contains the 4 columns you are looking to use in your VF page:

public class RevenueController{

Map<String, RevenueWrapper> ResultList = new Map<String, RevenueWrapper>(); 

public RevenueController(){
    List<AggregateResult> result =  [
    SELECT FISCAL_YEAR(Date__c) Date, Type__c, sum(Amount__c) Amount
    FROM Revenue__c
    GROUP BY FISCAL_YEAR(Date__c), Type__c];

    for(AggregateResult ar : result){

        RevenueWrapper RW = new RevenueWrapper();

        //If the RevenueWrapper already exists grab it from the Map
        if(ResultList.containsKey(String.valueOf(ar.get('Date')))){
            RW = ResultList.get(String.valueOf(ar.get('Date')));
        }

        //Set the amount
        RW.setAmount(ar);

        //Save back to the Map
        ResultList.put(String.valueOf(ar.get('Date')), RW);
    }
}

public List<RevenueWrapper> getResults() {
    return ResultList.values();
}


public class RevenueWrapper{
    public String revenueDate { get; set; }
    public Integer budgetAmount { get; set; }
    public Integer actualAmount { get; set; }
    public Integer varianceFYPercent { set; }
    public Integer varianceFYAmount { set; }

    public RevenueWrapper(){

    }

    public void setAmount(AggregateResult ar){
        revenueDate = String.valueOf(ar.get('Date'));

            //Set the amount value based on type
        if(ar.get('Type__c') == 'Budget'){
            budgetAmount = Integer.valueOf(ar.get('Amount'));
        }else if(ar.get('Type__c') == 'Actual'){
            actualAmount = Integer.valueOf(ar.get('Amount'));
        }else{ //Catch all for a type that isn't recognised
            return;
        }

    }

    public Integer getVarianceFYAmount(){
        return actualAmount - budgetAmount;
    }

    public Decimal getVarianceFYPercent(){
        if(budgetAmount != 0){
            return Decimal.valueOf((Double.valueOf(actualAmount) / Double.valueOf(budgetAmount)) * 100).setscale(1);
        } else{
            return 0;
        }
    }
}

}

[SalesForce] How to create JSON string for REST callout from Wrapper class

You can do the following workaround to make this happen. First, generate the wrapper class from the JSON (it will have those __c). Then replace the __c to _c to Save the wrapper class (WorkRequest).

Now you can populate the data in the wrapper class, Serialize it, get the raw JSON String and replace all the _c to __c before sending to the request as below. By doing this you can send the JSON as required by your web service.

String rqString = System.JSON.serialize(wr);
System.debug(rqString);
rqString = rqString.replaceAll('_c', '__c');
System.debug(rqString);

Wrapper Class

//
// Generated by JSON2Apex http://json2apex.herokuapp.com/
//

public class WorkRequest {

    public Rqst rqst;

    public class WorkList {
        public String Name;
        public String Sprint_c;
        public String Description_c;
        public Integer isTest_c;
    }

    public class Rqst {
        public List<WorkList> workList;
    }


    public static WorkRequest parse(String json) {
        return (WorkRequest) System.JSON.deserialize(json, WorkRequest.class);
    }
}

Best Answer

Related Solutions

[SalesForce] Split a single field into 2 columns for a VF page

[SalesForce] How to create JSON string for REST callout from Wrapper class

Related Topic