[SalesForce] Process Builder calling Apex: “We can’t find an action with the name and action type that you specified.”

Do you actually need the InvocableVariableLead inner class with the @InvocableVariable annotated member? According to InvocableMethod Annotation a list of any sObject type (except the generic sObject itself) should be supported.

I modified the invocableMatchLead method to take a collection of Lead sObjects directly.

@InvocableMethod
public static void invocableMatchLead(List<Lead> leads) {
    List<Lead> theLeads = new List<Lead>();
    for (Lead l : leads) {
        // Do Something
        //l.Comments__c = 'changed';
    }
}

I was then able to configure calling this method from a scheduled action.

You can also create an @InvocableMethod that takes in a List of a custom class. By doing this, you can pass in parameters in the Process Builder

public with sharing class ActionForProcessBuilder {

    @InvocableMethod(label='Do Action')
    public static void doAction(Request[] requests) {
        // Process requests
        // Example: Query parents in bulk
        Map<Id, Parent__c> parents = new Map<Id, Parent__c>();

        for(Request request : requests) {
            parents.put(request.parentId, null);
        }

        parents = new Map<Id, Parent__c>([
            SELECT Id, Due_Date__c
            FROM Parent__c
            WHERE Id IN :parents.keySet()
        ]);

        for(Request request : requests) {
            final Parent__c parent = parents.get(request.parentId);
            if(request.adjustedDueDate != null && parent.Due_Date__c < request.adjustedDueDate) {
                // Do something
            }
        }
    }

    public with sharing class Request {
        @InvocableVariable(label='Record ID' required=true)
        public Id recordId;

        @InvocableVariable(label='Parent ID' required=true)
        public Id parentId;

        @InvocableVariable(label='Adjusted Due Date' required=false)
        public Date adjustedDueDate;
    }
}