[SalesForce] Sort with field of type String containing numbers and letters both

What is the best way to sort a List of String containing letters and numbers as values?

I have tried couple of ways to sort, but with nothing I could make it work.

Using a sort method of list
Using comparable interface

Small example what I am trying to achieve

List<String> strList = new List<String>{'1 test', '2 test', '10 test', '13 test'};

With every method I use for sorting i get the result like

{(1 test, 10 test, 13 test, 2 test)}

However I am trying to achieve {(1 test, 2 test, 10 test, 13 test)}

I know it is happening because salesforce do the sorting lexicographically. But is there a way to achieve what I am after ?

Best Answer

Given the pattern you have described, you could certainly try to parse out the starting number and sort on that.

public class NumericString implements Comparable
{
    final Integer numericValue;
    public final String value;
    public NumericString(String value)
    {
        this.value = value;
        this.numericValue = getStartingDigits(value);
    }
    public Integer compareTo(Object instance)
    {
        NumericString that = (NumericString)instance;
        if (this.numericValue == null) return 1;
        if (that.numericValue == null) return -1;
        return this.numericValue - that.numericValue;
    }

    public static Integer getStartingDigits(String value)
    {
        if (String.isNotBlank(value))
        {
            try
            {
                return Integer.valueOf(value.splitByCharacterType()[0]);
            }
            catch (TypeException tex) { /*NaN*/ }
        }
        return null;
    }
}

The above should be simpler with regular expressions, but I couldn't get them to work. I also put nulls last, but you could put them first by reversing this and that in your null checks.

Related Solutions

[SalesForce] Custom sObject sorting with ‘implements comparable’

public class gAlertWrapper implements Comparable{
   public Integer compareTo(Object compareTo) {
    gAlertWrapper gAlertWrapper = (gAlertWrapper) compareTo;
    if (gA.published__c == gAlertWrapper.gA.published__c) return 0;
    if (gA.published__c > gAlertWrapper.gA.published__c) return 1;
    return -1;        
  }
}

Following is the correct syntax

Corrected completed code

public static list<gAlert__c> getAlerts(string url){
    HttpRequest req = new HttpRequest();
    req.setEndpoint(url);
    req.setMethod('GET');

    Http http = new Http();
    HttpResponse res = http.send(req);
            Dom.Document doc = res.getBodyDocument();
            Dom.XMLNode address = doc.getRootElement();

            string title = '';
            integer count = 1;

    list<gAlert__c> results = new list<gAlert__c>();
    gAlert__c gAlert=new gAlert__c();
    gAlertWrapper entry = new gAlertWrapper(gAlert);      
    for(Dom.XMLNode child:address.getChildElements()){
        string childElement = child.getName();
        if(childElement == 'title'){
            title = child.getText();
        }
        else if(childElement == 'entry'){
            for(Dom.XmlNode grandChild : child.getChildElements()){
                    string grandChildElement = grandChild.getName();
                if(grandChildElement == 'title'){
                    entry.gA.title__c = grandChild.getText();
                }
                else if(grandChildElement == 'link'){
                    entry.gA.link__c = grandChild.getAttributeValue('href', null);
                }
                else if(grandChildElement == 'published'){
                    entry.gA.published__c = grandChild.getText().replace('Z','').replace('T',' ');
                }
                else if(grandChildElement == 'content'){
                    entry.gA.content__c = grandChild.getText();
                }
                else if(grandChildElement == 'author'){ //this is the last element in the tree
                    results.add(entry.gA.clone(false,false,false,false));
                    entry.gA.clear();
                }
            }
        }
    }
    return results;
}
public class gAlertWrapper implements Comparable{
    public gAlert__c gA;
    public gAlertWrapper(gAlert__c g) {
    gA = g;
    }
    public Integer compareTo(Object compareTo) {
        gAlertWrapper gAlertWrapper = (gAlertWrapper) compareTo;
        if (gA.published__c == gAlertWrapper.gA.published__c) return 0;
        if (gA.published__c > gAlertWrapper.gA.published__c) return 1;
        return -1; 
    }
}

[SalesForce] Apex equivalent of Java Comparator

While Comparator isn't available out of the box, it's not terribly hard to implement. However, your performance will be considerably worse than a native solution, so you'll need to test and see how many rows you can actually sort before it becomes intolerable.

public abstract class Comparator {
    public abstract Integer compare(Object o1, Object o2);
    public static void sort(Object[] values, Comparator comp) {
        //  Obtain the list type of values
        Object[] temp = values.clone();
        temp.clear();
        //  Helper class for sorting using Comparable
        Helper[] tempValues = new Helper[0];
        for(Object value: values) {
            tempValues.add(new Helper(comp, value));
        }
        //  Perform sort
        tempValues.sort();
        //  Extract values back into temp list
        for(Helper helper: tempValues) {
            temp.add(helper.value);
        }
        //  And set the list to the new, sorted order
        values.clear();
        values.addAll(temp);
    }
    //  Simply calls Comparator when asked.
    class Helper implements Comparable {
        Comparator method;
        Object value;
        Helper(Comparator comp, Object val) {
            method = comp;
            value = val;
        }
        public Integer compareTo(Object o) {
            return method.compare(value, ((Helper)o).value);
        }
    }
}

From here, you can create your own solutions:

public class AccountNameComparator extends Comparator {
    public override Integer compare(Object a, Object b) {
        return ((Account)a).name.compareTo(((Account)b).name);
    }
}

Which would let you sort as you like:

Account[] accounts = [SELECT Name FROM Account ORDER BY CreatedDate LIMIT 5];
Comparator.sort(accounts, new AccountNameComparator());

This should work with any sort of data type, even custom classes, as long as you can implement the "compare" method. This version also doesn't take into consideration null values specifically, so you may need to adjust your implementations accordingly.

Best Answer

Related Solutions

[SalesForce] Custom sObject sorting with ‘implements comparable’

[SalesForce] Apex equivalent of Java Comparator

Related Topic