[SalesForce] System.AsyncException: Database.executeBatch cannot be called from a batch start, batch execute, or future method

i write below trigger on that time this error is appear plz help me

trigger GK_betaObject_trg on GIRI2__betaObject__c(after insert,after delete,after update) { 
   List<Rollup_Config__c> sfRollup = [Select Id,Parent_Field_Name__c,Parent_Object_Name__c,
 Parent_Relation_Name__c,Child_Field_Name__c , 
          Child_Object_Name__c ,Operation_Type__c,Filter1__c,Filter2__c,
   Filter3__c,Filter4__c,Filter5__c from Rollup_Config__c where Child_Object_Name__c ='GIRI2__betaObject__c' ]; 
   if(sfRollup.size() > 0){ 
     for(Rollup_Config__c conf: sfRollup){ 
         List<Id> pIds = new List<Id>(); 
         List<sobject> dataList = Trigger.IsDelete ?  Trigger.old :Trigger.new; 
         for(sobject rec :  dataList){ 
            pIds.add(String.valueOf(rec.get(conf.Parent_Relation_Name__c))); 
         } 
         if(pIds!=null && pIds.size() > 0){ 
             System.Debug('pIds : '+pIds); 
             LookUpConfigBatch batchObj = new LookUpConfigBatch(conf); 
             batchObj.pIds = pIds; 
             String batchId = Database.executeBatch(batchObj); 
         } 
     } 
 } 
}

Best Answer

Some batch or future process is updating records which is causing this to attempt to execute another batch and you cannot do that.

To Stop the error:

if(pIds!=null && pIds.size() > 0 && !system.isFuture() && !system.isBatch()){ 
             System.Debug('pIds : '+pIds); 
             LookUpConfigBatch batchObj = new LookUpConfigBatch(conf); 
             batchObj.pIds = pIds; 
             String batchId = Database.executeBatch(batchObj); 
         }

Then rerun all your test methods to ensure it did not stop any business logic from happening. If you do not have good test methods you will need to inspect your code / logic to ensure that all updates are happening as expected.

Related Solutions

[SalesForce] System.AsyncException: Database.executeBatch cannot be called from a batch start, batch execute, or future method on batch within batch

You can chain batches only through the finish() method. The reason for this is that the execute() method will be called many times for a given batch start() and this can get out of hand with too many batches scheduled.

Have your batchable class implement Database.stateful and save any information you need as class member variables, available to the finish() method for starting the next batch

From the Apex doc:

Starting with Apex saved using Salesforce.com API version 26.0, you can call Database.executeBatch or System.scheduleBatch from the finish method. This enables you to start or schedule a new batch job when the current batch job finishes. For previous versions, you can’t call Database.executeBatch or System.scheduleBatch from any batch Apex method. Note that the version used is the version of the running batch class that starts or schedules another batch job. If the finish method in the running batch class calls a method in a helper class to start the batch job, the Salesforce.com API version of the helper class doesn’t matter.

[SalesForce] Can Queueable solve “Future method cannot be called from a future or batch method”

Yes, Queueable can be called from Database.Batchable classes. You must go through enqueueJob for this to work:

public class BatchClass implements Database.Batchable<SObject> {
    public Database.QueryLocator start(Database.BatchableContext context) {
        return Database.getQueryLocator([SELECT Id FROM Account]);
    }
    public void execute(Database.BatchableContext context, Account[] records) {
        System.enqueueJob(new QueueClass(new Map<Id, Account>(records).keySet()));
    }
    public void finish(Database.BatchableContext context) {
    }
}

public class QueueClass implements Queueable {
    Set<Id> recordids;
    public QueueClass(Set<Id> recordIds) {
        this.recordIds = recordIds;
    }
    public void execute(QueueableContext context) {
         // Do something here
    }
}

Note that you're limited to just one enqueueJob call per execute in the Database.Batchable class. This is to prevent explosive execution (a so-called "Rabbit Virus" effect).

Best Answer

Related Solutions

[SalesForce] System.AsyncException: Database.executeBatch cannot be called from a batch start, batch execute, or future method on batch within batch

[SalesForce] Can Queueable solve “Future method cannot be called from a future or batch method”

Related Topic