[SalesForce] System.DmlException: Delete failed. CANNOT_INSERT_UPDATE_ACTIVATE_ENTITY, execution of BeforeDelete

BACKGROUND

I have a simple trigger which is meant to block a record from being deleted based on the record type.

I am using a Trigger Handler by Kevin O'Hara

Trigger

trigger InvoiceTrigger on Invoice__c (before delete) {
    new InvoiceTriggerHandler().run();    
}

Trigger Handler

public class InvoiceTriggerHandler extends TriggerHandler {

    public InvoiceTriggerHandler() {}

    public override void beforeDelete(){

        for(Invoice__c invoice : (List<Invoice__c>) Trigger.new) {

            if (IsLocked(invoice)){
                invoice.addError('You cannot delete an Invoice record which is locked. Please contact your Salesforce Administrator.');
            }
        }   
    }

    private boolean IsLocked(Invoice__c invoice){
        return invoice.RecordTypeId == InvoiceUtils.getLockedRecordTypeId;
    }
}

Trigger Unit Test

@isTest
public class InvoiceTriggerTests {

    @isTest
    public static void InvoiceTrigger_Success(){

        // arrange
        Id invoiceId = TestDataFactory.createInvoice();

        // act
        Database.delete(invoiceId);

        // assert
        System.assert(true); // don't judge me :)
    }
}

But when I run the unit test I get this error message:

Error Message

System.DmlException: Delete failed. First exception on row 0; first
error: CANNOT_INSERT_UPDATE_ACTIVATE_ENTITY, InvoiceTrigger: execution
of BeforeDelete

caused by: System.NullPointerException: Attempt to de-reference a null
object

Class.InvoiceTriggerHandler.beforeDelete: line 7, column 1
Class.TriggerHandler.run: line 43, column 1 Trigger.InvoiceTrigger:
line 2, column 1: []

QUESTIONS

What is actually causing the problem?
How can I fix it?

Best Answer

In the delete context, your trigger.new will be null. Use trigger.old instead for delete events.

Related Solutions

[SalesForce] Test Class fail

Here's a commented rewrite of that trigger which does not execute the aggregateResult query within the loop context of the Trigger.new collection.

Additionally, there's some code in both of your triggers which don't actually do anything as written.

trigger fulfillmentcontactcreatedopp on Opportunity (before insert, before update) {

    Map<Id, Opportunity> oppsToCheckMap = new Map<Id, Opportunity>();

    // collect the ID values of the opportunities with a stage calc value of 5 or more
    // if it is an update, the stage name must have changed
    for (Opportunity opp : trigger.new) {

        if (opp.Stage_Calc__c >= 5 ) { 

            if (trigger.isInsert || 
                trigger.isUpdate && trigger.oldMap.get(opp.Id).StageName != opp.StageName) {
                    oppsToCheckMap.put(opp.Id, opp);
            }
        }
    }

    // get an aggregate count of contact roles per opportunity in the fulfillment role
    List<AggregateResult> result = [SELECT OpportunityId
                                        , count(Id)
                                    FROM OpportunityContactRole
                                    WHERE (Role = 'Fulfillment')
                                        AND OpportunityId IN :oppsToCheckMap.keySet()
                                    GROUP BY OpportunityId];

    // iterate the results and set the number of fulfillment contacts on the opportunity
    for (AggregateResult aggCount : result) {

        /* this block of code isn't actually doing anything */
        if (aggCount.get('expr0') == 0) {

            Id oppId = (Id)aggCount.get('OpportunityId');
            Opportunity oppo = oppsToCheckMap.get(oppId);

        }
        /* this block of code isn't actually doing anything */

        // get the opportunity from the incoming map and update the value of the fulfillment contacts field
        Id oppId = (Id)aggCount.get('OpportunityId');
        Opportunity opp = Trigger.newMap.get(oppId);

        if (opp != null) {
            Integer fulcount = Integer.valueOf(aggCount.get('expr0'));
            opp.Number_of_Fulfillment_Contacts__c = fulcount;
        }
    }
}

Update

Here is the updated trigger code for the NetSuite_Sales_Order__c object with the Opportunity update statements removed from the loops. I also reformatted it for my own sanity and changed some of the odd checks for Trigger.new and Trigger.old in the if statements.

trigger celigoUpdateSalesOrder on NetSuite_Sales_Order__c (before insert, before update, before delete) {

    List<Opportunity> opportunitiesToUpdate = new List<Opportunity>();

    if (Trigger.isInsert || Trigger.isUpdate) {
        List<Id> opIds = new List<Id>();
        for (NetSuite_Sales_Order__c order : Trigger.new) {
            if (order.Opportunity__c == null) {
                continue;
            }
            opIds.add(order.Opportunity__c);
        }

        List<Opportunity> ops = [SELECT Id
                                        , StageName
                                        , StageNameState__c
                                    FROM Opportunity
                                    WHERE Id IN :opIds];

        celigo_connector__c cs = celigo_connector__c.getInstance('Opportunity Closed Stage');
        String closedStage = (cs!=null) ? cs.value__c : 'Closed Won';

        for (Opportunity o : ops) {
            if (Trigger.isInsert) {
                if (o.StageNameState__c == null) {
                    o.StageNameState__c = o.StageName;
                    o.StageName = closedStage;
                }
            }
            o.Celigo_Sync_Helper__c = true;

            // add to the list for update later
            opportunitiesToUpdate.add(o);

        }
    }

    if (Trigger.isDelete) {
        List<Id> opIds = new List<Id>();
        for (NetSuite_Sales_Order__c order : Trigger.old) {
            if (order.Opportunity__c == null) {
                continue;
            }
            opIds.add(order.Opportunity__c);
        }

        List<Opportunity> ops = [SELECT Id
                                        , StageName
                                        , StageNameState__c
                                    FROM Opportunity
                                    WHERE Id IN :opIds];

        List<NetSuite_Sales_Order__c> tOrders = [SELECT Id
                                                        , Opportunity__c
                                                    FROM NetSuite_Sales_Order__c
                                                    WHERE Opportunity__c IN :opIds];

        Map<Id, List<NetSuite_Sales_Order__c>> m = new Map<Id, List<NetSuite_Sales_Order__c>>();

        for (NetSuite_Sales_Order__c order : tOrders) {
            if (m.get(order.Opportunity__c) == null) {
                m.put(order.Opportunity__c, new NetSuite_Sales_Order__c[]{ order });
            }
            else {
                /* this code block doesn't do anything */
                List<NetSuite_Sales_Order__c> temp = m.get(order.Opportunity__c);
                temp.add(order);
                /* this code block doesn't do anything */
            }   
        }

        Set<Id> keys = m.keySet();

        for (Id i : keys) {
            List<NetSuite_Sales_Order__c> temp = m.get(i);
            Opportunity op;
            for (Opportunity tempOp : ops) {
                if (tempOp.Id == i) {
                    op = tempOp;
                    break;
                }
            }
            if (temp.size() > 1) {
                continue;
            }

            if (op.StageNameState__c == null) {
                continue;
            }

            op.StageName = op.StageNameState__c;
            op.StageNameState__c = null;

            // add to the list for update later
            opportunitiesToUpdate.add(op);
        }
    }

    // if we've got opportunities to update, do it
    if (!opportunitiesToUpdate.isEmpty()) {
        update opportunitiesToUpdate;
    }
}

[SalesForce] Error on Trigger Before Delete[Trigger.old]

You can modify the values of the record before their final deletion in a Before Delete trigger event, but you need a separate DML statement for this. Example follows:

if(Trigger.isDelete) {
    Contact[] contacts = new Contact[0];
    for(Contact record: Trigger.old) {
        if(record.RecordTypeId == RecordType1 && record.Registered_on_ITV_Media__c) {
            contacts.add(new Contact(Id=record.Id, Status__c='Inactive'));
        }
    }
    update contacts;
}

Notice how I construct a new instance of the record using new Contact so it doesn't trigger the "record is read-only" error. Note that your before/after update logic will also be called, meaning the inactive status will be sent to your webservice automatically without handling this explicitly in your before delete trigger event (in other words, don't call the web service explicitly in your delete trigger event).

Best Answer

Related Solutions

[SalesForce] Test Class fail

Update

[SalesForce] Error on Trigger Before Delete[Trigger.old]

Related Topic