Apex ListException – Handling Before Insert or Upsert with Identically Equal Elements

I had the following exception thrown at me when trying to process more than one selected records via a custom button in the list view.

enter image description here

Class Code

global class MerchandiseInventoryClass {


   webservice static void ConverttoInventory(String[] merchandise_id)
   {
       //Convert Merchandise collection into Inventory Collection...

       Merchandise__c[] merchandise_collection = [SELECT ID,Author__c,Book_Title__c,Edition__c,Publisher__c,Total_Merchandise_QtyTotal_Qty__c,Status__c FROM Merchandise__c WHERE ID = :merchandise_id];


       Inventory__c i = new Inventory__c(); //Line 1
       List<Inventory__c> newInventory = new List<Inventory__c>();
       for(Merchandise__c m : merchandise_collection )
       {
           if(m.Status__c !='Fully Converted')
           {
           i.Author__c = m.Author__c ;
           i.Book_Title__c = m.Book_Title__c;
           i.Edition__c = m.Edition__c;
           i.Publisher__c = m.Publisher__c;
           i.Qty_Available__c = m.Total_Merchandise_QtyTotal_Qty__c;
           i.Merchandise__c = m.Id;
           m.Uninventoried_Qty__c = 0;
           m.Status__c = 'Fully Converted';
           newInventory.add(i);
           }
       }
       insert newInventory;
       update merchandise_collection;
   }

}

By moving the Line 1 to within the for loop solved the issue for me.

Thanks to this post (refer the Best Answer in that post)

https://developer.salesforce.com/forums/ForumsMain?id=906F00000008vFjIAI

What puzzles me is that WHY i have to instantiate "i" for every iteration within the loop.

Why the list collection ("newInventory") is complaining that are duplicate elements and why should it even confuse in the first place when I am performing an "insert" even ?

Best Answer

This line of your code:

Inventory__c i = new Inventory__c();

creates a block of memory that is big enough to hold all the fields of the inventory object and your variable i holds a reference to that memory (its address). As the loop runs, the code changes the values within that block of memory, then this line:

newInventory.add(i);

adds the same reference value to the list multiple times.

Salesforce made the design choice to flag this condition of multiple identical references by throwing an exception. If they had not, the code would have inserted multiple copies of the object with the fields set to the values of the last iteration round the loop which is not useful and is a harder to detect bug.

Moving the new inside the loop yields the correct code with a separate block of memory for each inventory object and so independent values for the fields.

Related Solutions

[SalesForce] System.ListException: Before Insert or Upsert list must not have two identically equal elements

I think i found the solution, Actually the above code is working fine as i swaped some lines in Original code(which was causing problem).

Original code :

Set<Property2__c> properties = new Set<Property2__c>();
List<Property2__c> upsertProperties = new List<Property2__c>();
for (Opportunity opp : opps) {
    Property2__c prop = new Property2__c();
    String propCheck = opp.Street_opp__c + '---' + opp.Postal_Code_ZIP_opp__c;
    if (szToProperty.containsKey(propCheck)) prop = szToProperty.get(propCheck); // check for property
    else szToProperty.put(propCheck,prop); // new property; add to the map in case multiple opps with existing records 
    System.debug('\n\n----Before adding --- : ' + prop);
    if (!properties.contains(prop)) { 
        properties.add(prop);
        prop.Name = opp.Street_opp__c;
        prop.Account__c = opp.AccountId;
        prop.Street__c = opp.Street_opp__c;
    }
}

if (properties.size() > 0) {
  upsertProperties.addAll(properties);
  System.debug('\n\n---Upsert Size---: ' +upsertProperties.size());
  upsert upsertProperties;
}

But it gave me error

System.ListException: Before Insert or Upsert list must not have two identically equal elements

Reason : The code checks for the set.contains When the fields are not initialised, hence there is a risk of adding duplicate record

if (!properties.contains(prop))

I have done some reordering in the code(included in the Question itself) and it worked for me.

Thanks for the help guys:)

[SalesForce] Before Insert or Upsert list must not have two identical equal elements

The existing code isn't too easy to follow. And with all the nested loops it's easy to imagine that duplicate items are getting added to a list. Rather than eliminating duplicates by using maps, I suggest it would be better to stop the code duplicating the data in the first place.

It is worth naming variables after their content and limiting their scope i.e. declare them where you need them and don't re-use them. The sort of code I would write for what I think you are doing (you may be doing something other than this so just take it as an example) is this:

   global void execute(
           Database.BatchableContext bc,
           List<Product_Metrics_vod__c> scope
           ) {
       // Find all keys
       Set<String> keys = new Set<String();
       for(Product_Metrics_vod__c pm : scope) {
           keys.add(key(pm));
       }
       // Query the existing ARs
       Map<String, Account_Report__c> keyToAr = new Map<String, Account_Report__c>();
       for (Account_Report__c ar : [
               SELECT Id, Name
               FROM Account_Report__c
               where Name IN :keys
               ]) {
           keyToAr.put(ar.Name, ar);
       }
       // Will update if already exists or will insert
       for (Product_Metrics_vod__c pm : scope) {
            Account_Report__c ar = keyToAr.get(key(pm));
            if (ar == null) {
                ar = new Account_Report__c(Name = key(pm));
                keyToAr.put(key(pm), ar);
            }
            ar.Account_Name__c = pm.Account_vod__c;
            ar.Product_Name__c = pm.Products_vod__c;
            ar.Loyalty__c = Integer.ValueOf(pm.Segment_Loyalty_LBK_FI__c);
            ar.Potential__c = pm.Segment_Potential_LBK_FI__c;
       }
       // Guaranteed only one value per key in this map
       upsert keyToAr.value();
   }
   private String key(Product_Metrics_vod__c pm) {
       return pm.Account_vod__c + '_' + pm.Products_vod__c;
   }

The above avoids multiple levels of loop nesting by using maps: this allows a value to be grabbed in a single statement rather than a set of values having to be looped over. Less code and execution time grows linearly rather than exponentially.

Best Answer

Related Solutions

[SalesForce] System.ListException: Before Insert or Upsert list must not have two identically equal elements

[SalesForce] Before Insert or Upsert list must not have two identical equal elements

Related Topic