[SalesForce] Test Class for Apex rest services is not getting parameters

I am developing a Apex REST class for an external system. I have done with the development and everything is working good.

Now I am creating test classes for this Rest class.

Problem I want to set params in RestContext.request.params but it is not setting parameters.

Below is my Rest class

@RestResource(urlMapping='/ownerPortal')
global class Rest_Services_Owner_Portal {

    Private static String ACTION_PARAM =  'action';
    Private static String TEST_SERVICE =  'testService';
    Private static String GET_BANK_DETAILD =  'getBankDetails';
    Private static String EDIT_BANK_DETAILD =  'editBankDetails';
    Private static String CREATE_BANK_DETAILD =  'createBankDetails';
    public static Object result;
    public static String jsonString{get{
        return JSON.serialize(result);
    }set;}
    @HttpPost
    global static void  handleRequest() {
        RestResponse response = RestContext.response;
        try{
            response.addHeader('Content-Type','application/json');
            RestRequest req = RestContext.request;
            Map<String,String> headersMap = req.headers;
            if(!req.params.containsKey('action')){
                throw New CustomException('action parameter is required!');
            }
            if(String.isBlank(headersMap.get('CRS_Authorization'))){
                throw New CustomException('CRS authorization header missing!');
            }
            String action = req.params.get('action');
            if(TEST_SERVICE.equalsIgnoreCase(action)){
                result = Rest_Services_Owner_Portal_Handler.testService(req.requestBody.toString());
            }else{
                throw New CustomException('Invalid action!');
            }
        }catch(CustomException cx){
            response.statusCode = 403;
            result = New ResponseClass('error',null,cx.getMessage(),cx.getMessage());
        }catch(Exception ex){
            result = New ResponseClass('error',null,ex.getMessage(),ex.getMessage());
        }
        response.responseBody = Blob.valueOf(jsonString);
    }
}

And following is my ServiceHandler class

public  class Rest_Services_Owner_Portal_Handler {
    public Rest_Services_Owner_Portal_Handler() {

    }

    public static Object testService(String data){

        System.debug(data);
        return New ResponseClass('success',JSON.deserializeUntyped(data),'Services are working!','Services are working!');
    }
}

And following is my Response Class

public with sharing class ResponseClass {
    public String status{get;set;}
    public Object result{get;set;}
    public String message{get;set;}
    public String debugMessage{get;set;}
    public ResponseClass(){

    }
    public ResponseClass(String status,Object result,String message,String debugMessage) {
        this.status = status;
        this.result = result;
        this.message = message;
        this.debugMessage = debugMessage;
    }
}

Below is my Test class

@isTest
private class Test_Rest_Services_Owner_Portal {

    @testSetup static void setupTestData(){

    }


  static testMethod void testService() {

    RestRequest req = new RestRequest(); 
    req.requestURI = Constants.OWNER_PORTAL_ENDPOINTS.get('testService');  
    req.httpMethod = 'POST';
    req.addHeader('CRS_Authorization','00DO000000537j1!ARsAQHvz9MMOxZ24dez0hCYWl0_WpITR1kIoOv3wo67zV6a48Y0RYN9FEzPQf.73.7TZGrVEnq_9X5zLGryMAVVNnQO4jehD');
    Map<Object,Object> requestMap = New Map<Object,Object>{
        'test' => 'test'
    };
    req.addParameter('action','testService');
    req.requestBody = Blob.valueOf(JSON.serialize(requestMap));
    RestContext.request = req;
    System.debug(req);
    Rest_Services_Owner_Portal.handleRequest();
    RestResponse response = RestContext.response;
    System.debug(response.responseBody.toString());

  }

}

Anyone have any Idea, how to test Rest class written in above pattern.

Thanks

Best Answer

In unit tests neither RestContext.request or RestContext.response are automatically initialised whereas in the normal execution environment they are. So if your @RestResource class references these values you need to set both of them up in your test.

So add to your test before the call to the @HttpPost method:

RestContext.response = new RestResponse();

so that this line in your @HttpPost method:

response.addHeader('Content-Type','application/json');

does not cause an NPE that breaks your test because response is null.

Related Solutions

[SalesForce] Issues with calling 2 setTest methods in apex test class

As it turns out, I overlooked something very simple. When calling the setTest() methods you need to make sure that variables maintain their state once set and therefore, because I was not declaring my variables as static, they were not maintaining their state and thus the error was being thrown.

Here's the modified controller code:

public class CanNewsChatterFeedController {
    //declare necessary static variables
    static ConnectApi.ChatterGroupPage chatterGrpPg;
    static String theGroupId;

    //empty constructor
    public CanNewsChatterFeedController(){}

    // get first page of news feed
    public static ConnectApi.FeedItemPage getNewsFeed() {
        //get the proper Chatter Group Page
        chatterGrpPg = getCanNewsChatterGrpPg();
       //get the groupId
       theGroupId = chatterGrpPg.groups[0].id;
       //use the groupId to get the feedItems
       ConnectApi.FeedItemPage feedPage = ConnectApi.ChatterFeeds.getFeedItemsFromFeed(null, ConnectApi.FeedType.Record, theGroupId);
       return feedPage;
    }

    //The Id of the ChatterGroup we want to display will be different in the sandbox from what it is in production
    //(production id: 0F9D0000000UGqS in sandbox id:0F9c0000000Chu1), in order to get the feed items we want, 
    //we have to search for the ChatterGroup by name. Since Group Name must be unique,
    //the searchGroups method should only return one ChatterGroupPage with one ChatterGroup
    public static ConnectApi.ChatterGroupPage getCanNewsChatterGrpPg(){
        return ConnectApi.ChatterGroups.searchGroups(null, 'Canada - Corby Scoreboard', null, 1);
    }    

    // build list of wrapped feed items for display in VisualForce
    public static List<FeedItemInfo> getNewsFeedForDisplay() {
        ConnectApi.FeedItemPage feed = getNewsFeed();      
        List<FeedItemInfo> result = new List<FeedItemInfo>();
        for (ConnectApi.FeedItem item : feed.items) {
            result.add(new FeedItemInfo(item));
        }

        return result;
    }


    public PageReference refreshFeed(){
        return null;
    }
}

I hope this helps someone else experiencing the same issue.

[SalesForce] Unit Test is Providing 0% Coverage for Apex Trigger

The trigger code is having lot of redundancy, So I modified it. before posting the modified code few lines of explanation what I changed. you collected account Ids twice and did the condition check twice where once is more enough. I am also made changes to the test class, where Task data is provided which is not required because the trigger has to create it once the necessary conditions are met. I am expecting this trigger should work for you, if there is any errors feel free to post as a comment.

trigger OpportunityAfter on Opportunity (after update){

    Set AccountIDs = new Set();

    for(Opportunity o : trigger.new){
        if(opp.StageName == 'Closed - Lost' && opp.Business_Line__c == 'Workforce' && 
            opp.Survey_Type__c != 'APulse' && trigger.oldMap.get(opp.Id).StageName != opp.StageName){

                AccountIDs.add(o.AccountId);
         }
    }

    Task[] tasksToInsert = new Task[]{};

    for (Account acc : [Select Id, Name, OwnerId from Account where Id IN :AccountIds]){
        for (Opportunity opp : trigger.new){
            if(opp.AccountId == acc.Id){
                Task tas = new Task();
                tas.WhatId=acc.Id;
                tas.OwnerId=opp.OwnerId;
                tas.Subject='Follow-up: ' + opp.name + ' - ' + acc.name;
                tas.ActivityDate=(opp.CloseDate + 180);
                tas.Description='Follow up to see how engagement initiatives are going and if Avatar can help. Refer to lost opportunity: ' + opp.name;
                tasksToInsert.add(tas);                                                         
            }
        }
    }
    if(tasksToInsert != null && !tasksToInsert.isEmpty())
    Database.insert(tasksToInsert);

}

@isTest
public class TestClass {

    static testMethod void myUnitTest() {

    //Set up user
    User u1 = [SELECT Id FROM User WHERE Email='abc@sampleemail.com'];
    test.startTest();  
    //Run As U1
    System.RunAs(u1){

    System.debug('Testing trigger... (single record validation)');

    //NEW Account record
    Account acc = new account();
    acc.Name = 'Test Account';
    acc.Industry = 'Healthcare';

    insert acc;

    //NEW Opportunity record
    Opportunity opp = new Opportunity();
    opp.Name = 'Test Opportunity'; 
    opp.CloseDate = System.today();
    opp.StageName = 'S1 - Investigative';
    opp.Type = 'Repeat Business - Wrkforce HC';
    opp.AccountId = acc.Id;
    opp.Survey_Type__c = 'Product Name';

    insert opp;

    opp.StageName = 'Closed - Lost';
    opp.Reason_Won_Lost__c = 'Relationship';
    opp.Business_Line__c = 'Workforce'  //added this line to meet the if condition while collecting the set of id in the trigger.

    update opp;
   test.stopTest();
    // Here I am expecting the task has been inserted and doing a query for it         and check it in the assert statement.
   Task  testTask=[Select Id, WhatId from Task where WhatId=:acc.Id];
    //Validate single insert
    System.assertEquals(acc.Id, testTask.WhatId);

    }
    }
}

Best Answer

Related Solutions

[SalesForce] Issues with calling 2 setTest methods in apex test class

[SalesForce] Unit Test is Providing 0% Coverage for Apex Trigger

Related Topic