[SalesForce] Trigger to update Account running total upon change to any child custom Invoice object

i have 3 objects: invoice,invoice line item & standard Account.

relationships:

invoice & invoice line item—>master-detail.
Account & invoice—>lookup.

On the invoice object i have one Rollup summary field called total price(sum of all prices on invoice line item).

On account i have 1 field called Account_balance

On the save event of a invoice line item i want to update Account_balance field with rollup summary value of invoice object.

Is this possible with a trigger ?

Best Answer

This is definitely possible with a trigger. To give you some pseudo code, I would write your trigger on the Invoice__c object. It will handle any updates of the Invoice_Line_Item__c object because of the rollup summary. You will want to have something like:

trigger InvoiceTrigger on Invoice__c (after insert, after update) {
    if(Trigger.isAfter && (Trigger.isInsert || Trigger.isUpdate)){
        InvoiceTriggerHandler.updateAccountBalance(Trigger.newMap);
    }
}

public class InvoiceTriggerHandler{
    public static void updateAccountBalance(Map<Id, Invoice__c> invoices){
        AggregateResult[] results = [
            SELECT 
                Account__c, SUM(Total_Price__c)
            FROM
                Invoice__c 
            WHERE 
                Id IN :invoices.keySet 
            GROUP BY 
                Account__c
        ];
        Set<Account> accountsToUpdate = new Set<Account>();
        for(AggregateResult result:results){
            accountsToUpdate.add(new Account(
                Id = result.get('Account__c'), 
                Account_Balance__c = result.get('expr0')
            );
        }
        update accountsToUpdate;
    }
}

You will have to clean that up and write your own tests, but that is the general idea. Every time an Invoice_Line_Item__c is updated and it changes the rollup summary field, this trigger will fire to update the account. There is some additional logic you may want to add, such as checking the old value of the Total_Price__c field with the new value and only running through Accounts who have had Invoice__c changes rather than all of them. There may be some other ways to tweak this as well, I just quickly wrote this up. Keep in mind this is not production ready by any means, but I hope this points you in the right direction.

The approach above utilizes aggregate functions and setting Id fields for update.

EDIT: I originally had the following code, which should still work, but the above is more optimal.

trigger InvoiceTrigger on Invoice__c (after insert, after update) {
    if(Trigger.isAfter && (Trigger.isInsert || Trigger.isUpdate)){
        InvoiceTriggerHandler.updateAccountBalance(Trigger.new);
    }
}

public class InvoiceTriggerHandler{
    public static void updateAccountBalance(List<Invoice__c> invoices){
        Set<Id> accountIds = new Set<Id>();
        for(Invoice__c invoice:invoices){
            accountIds.add(invoice.Account__c);
        }
        List<Account> accounts = [SELECT Id, Account_Balance__c, (SELECT Id, Total_Price__c FROM Invoices__r) FROM Account WHERE Id IN :accountIds];
        for(Account acc:accounts){
            acc.Account_Balance__c = 0;
            for(Invoice__c invoice:acc.Invoices__r){
                acc.Account_Balance__c += invoice.Total_Price__c;
            }
        }
        update accounts;
    }
}

Related Solutions

[SalesForce] Trigger to add Products to Opportunity Line Item from a custom object without Price Book

As the error states, you need to specify the opportunity id. Presumably, you'll find the opportunity attached to the order.

That probably looks like this:

trigger CreateOpportunityProduct on Order_Line_Item__c(after insert, after update){       
if(trigger.isUpdate)
{          
    map<id, order__c> orders = new map<id, order__c>();
List<ID> pricebookID=new List<ID>();       
List<ID> opportunityID=new List<ID>();           
List<OpportunityLineItem> newopportunitylineitemlist=new List< OpportunityLineItem>();        
    for(order_line_item__c record: trigger.new) {
        orders.put(record.order__c, null);
    }
    orders.putall([select id, opportunity__c from order__c where id in :orders.keyset()]);
for(Order_Line_Item__c orderlist: Trigger.new){    
OpportunityLineItem Oppitem=new OpportunityLineItem();
Oppitem.Quantity=orderlist.Quantity__c;
Oppitem.UnitPrice=orderlist.UnitPrice__c;
oppitem.opportunityid = orders.get(orderlist.order__c).opportunity__c;
pricebookID.add(Oppitem.PriceBookEntryId);
opportunityID.add(Oppitem.OpportunityId);
newopportunitylineitemlist.add(Oppitem);
}    
List<Order__c> orderlist= new List<Order__c>([Select Id,Opportunities__c From Order__c Where Opportunities__c IN:opportunityID]);            
List<PricebookEntry> pricebookentrylist = new List<PricebookEntry>([Select Id,Product2Id From PricebookEntry Where Id IN:pricebookID]);         
if(newopportunitylineitemlist.size()>0)
insert(newopportunitylineitemlist);    
}    
}

Adjust field names as necessary.

[SalesForce] Need to fire trigger on child objects when parent object is updated

On the rollup question only...

This is a case where it is probably worth factoring out the code that does the rollup into a separate class. That then allows the triggers to be fairly simple:

trigger ParentTrigger on Parent__c (before ...) {
    if (change detected) {
        // Trigger objects will be persisted so just copy result
        for (Parent p : ChildRollup.calculateParents(Trigger.newMap)) {
            Trigger.newMap.get(p.Id).Sum__c = p.Sum__c;
        }
    }
}

trigger ParentTrigger on Parent__c (after ...) {
    if (change detected) {
        update ChildRollup.calculateParents(Trigger.newMap);
    }
}

trigger ChildTrigger on Child__c (...) {
    update ChildRollup.calculateParents(Trigger.newMap);
}

and sharing most of the code:

public class ChildRollup {
    public static Parent__c[] calculateParents(Map<Id, Parent__c> parents) {
        return calculateParents(parents.keySet());
    }
    public static Parent__c[] calculateParents(Map<Id, Child__c> children) {
        Set<Id> parentIds = new Set<Id>();
        for (Child__c c : children.values()) {
            parentIds.add(c.Parent__c);
        }
        return calculateParents(parentIds);
    }
    private static Parent__c[] calculateParents(Set<Id> parentIds) {
        Map<Id, Parent__c> parents = new Map<Id, Parent__c>();
        for (Id parentId : parentIds) {
            parents.put(parentId, new Parent__c(Id = parentId, Sum__c = 0.00));
        }
        for (AggregateResult ar : [
                select Parent__c p, sum(Value__c) s
                from Child__c
                where Parent_c in :parentIds
                group by Parent__c
                ]) {
            parents.get((Id) ar.get('p')).Sum__c += (Decimal) ar.get('s');
        }
        return parents.values();
    }
}

Best Answer

Related Solutions

[SalesForce] Trigger to add Products to Opportunity Line Item from a custom object without Price Book

[SalesForce] Need to fire trigger on child objects when parent object is updated

Related Topic