[SalesForce] Update Multiple values for record in Apex Trigger

I have custom junction object between user and custom object. I need to update user record with junction object values for given user. Each user may have more than one record in junction object.

Example: User1 will have account1,account 2 in junction object and I need to update user record custom field with account1, account2.
I have written code like this but it will overwrite the previous value with new value in given batch when I issue single update list statement. How can I achieve it?

trigger UpdateUserGUL on GUL_Account_to_User_Junction__c (after insert) {
    String AccountName;
    String ChatterGrpName;
    List<User> userList = new List<User>();

    for (GUL_Account_to_User_Junction__c j: Trigger.New) {
        User userRecord = new User();
        userRecord.Id = j.UserId__c;
        //check to see if it is having any value
        AccountName = userRecord.GUL_Account_Default__c;
        if(AccountName == null) {
            userRecord.GUL_Account_Default__c = j.GUL_Account_Name__c;
        } else { 
            userRecord.GUL_Account_Default__c = AccountName + ',' + j.GUL_Account_Name__c;
        }   

        userList.add(userRecord);
    }
    update userList;
}

Best Answer

If I were you, I would implement this with dlrs.

Parent Object: User
Relationship Field: UserId__c
Child Object: GUL_Account_to_User_Junction__c
Field To Aggregate: GUL_Account_Name__c
Aggregate Operation: Concatenate Distinct
Aggregate Result Field: GUL_Account_Default__c
Concatenate Delimiter: ,

If you want to roll your own solution, you are going to have to query the sibling records, and don't forget you need to worry about the delete case.

Map<Id, Set<String>> userIdToAccountNames = new Map<Id, Set<String>>();
for (Junction__c junction : trigger.new)
{
    if (!userIdToAccountNames.containsKey(junction.UserId__c))
        userIdToAccountNames.put(junction.UserId__c, new Set<String>());
    userIdToAccountNames.get(junction.UserId__c).add(junction.GUL_Account_Name__c);
}
for (Junction__c existing : [
    SELECT UserId__c, GUL_Account_Name__c FROM Junction__c
    WHERE UserId__c IN :userIdtoAccountNames.keySet()
]) userIdToAccountNamees.get(existing.UserId__c).add(existing.GUL_Account_Name__c);

List<User> users = new List<User>();
for (Id userId : userIdToAccountNames.keySet())
{
    String concat = String.join(new List<String>(userIdToAccountNames.get(userId)), ',');
    users.add(new User(Id=userId, GUL_Account_Default__c=concat));
}
update users;

You should really consider adding error handling to the update operation. You may also need to put this functionality in a without sharing class, since most users won't be able to update other User records.

Related Solutions

[SalesForce] Trigger old and new for update operation

This code is something of a guess because you have not responded to highfive's comment and your question is not entirely clear. This code assumes that there is a lookup relationship between Time_Off__c and User via an id field called User__c.

It illustrates that the Trigger context variable holds references to the values of the objects before they were changed (the old fields) and after they have been changed (the new fields) and this allows you to look at the difference between old and new values:

trigger TimeOffTrigger on Time_Off__c (before update) {

    // Get the current Credit values
    Set<Id> userIds = new Set<Id>();
    for (Time_Off__c newTimeOff : Trigger.new) {
        userIds.add(newTimeOff.User__c);
    }
    Map<Id, User> users = new Map<Id, User>([
            select Id, Credit__c
            from User
            where Id in :userIds;
            ]);

    // Update Credit values with the changed days
    for (Time_Off__c newTimeOff : Trigger.new) {
        Time_Off__c oldTimeOff = Trigger.oldMap.get(newTimeOff.Id);
        User u = users.get(newTimeOff.User__c);
        u.Credit__c += (oldTimeOff.Days__c - newTimeOff.Days__c);
    }
    update users.value();
}

This is only handling the update case, so you may also need to code for the insert case and perhaps the delete case too. And if fields allow nulls you will need more defensive code.

If none of this makes any sense, I recommend you Google and watch some YouTube presentations and generally read more on the subject. It is particularly important to get comfortable with using sets and maps.

The recent comments on the question suggest that this is what is required (though at first sight it looks quite unusual):

trigger TimeOffTrigger on Time_Off__c (before update) {
    User u = [
            select Id, Credit__c
            from User
            where Id in :UserInfo.getUserId()
            ];
    for (Time_Off__c newTimeOff : Trigger.new) {
        Time_Off__c oldTimeOff = Trigger.oldMap.get(newTimeOff.Id);
        u.Credit__c += (oldTimeOff.Days__c - newTimeOff.Days__c);
    }
    update u;
}

[SalesForce] Apex Trigger : Insert record on another object on “afterInsert” event

There are a couple of things wrong with your above snippet and example, but they are easy to fix.

First you need to initialise your List.

List<CaseLogger__c> l = new List<CaseLogger__c>();

The add() method on a List<CaseLogger__c> will take a CaseLogger__c as its parameter:

l.add(new CaseLogger__c(Name = c.Id + c.Origin));

I'd also advise that you give l a more descriptive name.

Putting that all together you get:

trigger CaseTrigger on Case ( after insert)
{
    List<CaseLogger__c> loggers = new List<CaseLogger__c>();

    for(Case c : Trigger.new)
    {
        loggers.add(new CaseLogger__c(Name = c.Id + c.Origin));
    }

    insert loggers;
}

Best Answer

Related Solutions

[SalesForce] Trigger old and new for update operation

[SalesForce] Apex Trigger : Insert record on another object on “afterInsert” event

Related Topic