[SalesForce] Visualforce: apex:repeat and Map

In my controller I have a map of integers and strings which I want to display as checkboxes.

The controller:

public Map<Integer, String> xmlCatalogsMap {get;set;}
public Set<Integer> xmlCatalogsKeys {get;set;}

public void getXMLCatalogs() {
    String sql = 'SELECT BOID__c, Name FROM ZXMLCatalogs__c ORDER BY Name';
    List<ZXMLCatalogs__c> result = Database.query(sql);
    Map<Integer, String> xmlCatalogsMap = new Map<Integer, String>();

    for (ZXMLCatalogs__c c : result) {
        xmlCatalogsMap.put(Integer.valueOf(c.BOID__c), c.Name);
    }

    Set<Integer> xmlCatalogsKeys = xmlCatalogsMap.keySet();
}

getXMLCatalogs() is called from constructor.

Now I want to display a checkbox for each integer/string pair. Integer/key should be the checkbox value and the string should be the label:

<apex:repeat value="{!xmlCatalogsKeys}" var="i">
    <apex:pageBlockSectionItem>
        <apex:inputCheckbox label="{!xmlCatalogsMap[i]}" value="{!i}" html-name="CatalogId" />
    </apex:pageBlockSectionItem>
</apex:repeat>

I read
how to display map on vf page in salesforce
and
How to reference a map's keySet() and individual map elements within Visualforce? Get 'Unknown function' error

When I compile with Sublime/Maven I always get the below error without line number:

Unknown property 'i'

Why can't I use i (or any other variable name) as a variable?

Best Answer

In the line:

<apex:inputCheckbox label="{!xmlCatalogsMap[i]}" value="{!i}" html-name="CatalogId" />

value attribute should be Boolean. So that checkbox can be marked as check or uncheck.

Currently it's Integer. That's why it is showing error.

To fix this problem, set up a map of Integer to Boolean, then bind the checkbox to that instead.

public Map<Integer, Boolean> xmlCatalogsChecked { get; set; }

public void getXMLCatalogs() {
    // Query omitted
    xmlCatalogsChecked = new Map<Integer, Boolean>();
    for (ZXMLCatalogs__c c : result) {
        xmlCatalogsMap.put(Integer.valueOf(c.BOID__c), c.Name);
        // Assign default state
        xmlCatalogsChecked.put(Integer.valueOf(c.BOID__c), false);
    }
}

<apex:inputCheckbox label="{!xmlCatalogsMap[i]}" value="{!xmlCatalogsChecked[i]}" 
    html-name="CatalogId" />

Update based on Comments

Main issue in your code is this line at getXMLCatalogs() method which is initializes the map and makes that empty.

Map<Integer, String> xmlCatalogsMap = new Map<Integer, String>();

I have create apex class and pages just like you and it is working correctly.

Apex class

public class DealerController
{
    public Map<Integer, String> xmlCatalogsMap {get;set;}
    public Map<Integer, Boolean> xmlCatalogsChecked { get; set; }

    public Set<Integer> xmlCatalogsKeys {get;set;}

    public DealerController()
    {
        getXMLCatalogs();
    }

    public void getXMLCatalogs() {
        xmlCatalogsKeys = new Set<Integer>();

        String sql = 'SELECT Dealer_Number__c, Name FROM Dealer__c ORDER BY Name';
        List<Dealer__c> result = Database.query(sql);

        xmlCatalogsMap = new Map<Integer, String>();
        xmlCatalogsChecked = new Map<Integer, Boolean>();

        for (Dealer__c c : result) {
            xmlCatalogsMap.put(Integer.valueOf(c.Dealer_Number__c), c.Name);
            // Assign default state
            xmlCatalogsChecked.put(Integer.valueOf(c.Dealer_Number__c), false);
        }
         xmlCatalogsKeys = new Set<Integer>(xmlCatalogsMap.keySet());


    }

}

Visualforce

<apex:page id="dealerPage" controller="DealerController" action="{!getXMLCatalogs}">
    <apex:form >
    <apex:pageBlock >
    <apex:pageBlockSection >
    <apex:repeat value="{!xmlCatalogsKeys}" var="i">


            <apex:inputCheckbox label="{!xmlCatalogsMap[i]}" value="{!xmlCatalogsChecked[i]}" 
            html-name="CatalogId" />


    </apex:repeat>
    </apex:pageBlockSection>
    </apex:pageBlock>
    </apex:form>
</apex:page>

Result

Related Solutions

[SalesForce] Split a single field into 2 columns for a VF page

This is untested so you may need to have play, however this should return a List of the RevenueWrapper classes which contains the 4 columns you are looking to use in your VF page:

public class RevenueController{

Map<String, RevenueWrapper> ResultList = new Map<String, RevenueWrapper>(); 

public RevenueController(){
    List<AggregateResult> result =  [
    SELECT FISCAL_YEAR(Date__c) Date, Type__c, sum(Amount__c) Amount
    FROM Revenue__c
    GROUP BY FISCAL_YEAR(Date__c), Type__c];

    for(AggregateResult ar : result){

        RevenueWrapper RW = new RevenueWrapper();

        //If the RevenueWrapper already exists grab it from the Map
        if(ResultList.containsKey(String.valueOf(ar.get('Date')))){
            RW = ResultList.get(String.valueOf(ar.get('Date')));
        }

        //Set the amount
        RW.setAmount(ar);

        //Save back to the Map
        ResultList.put(String.valueOf(ar.get('Date')), RW);
    }
}

public List<RevenueWrapper> getResults() {
    return ResultList.values();
}


public class RevenueWrapper{
    public String revenueDate { get; set; }
    public Integer budgetAmount { get; set; }
    public Integer actualAmount { get; set; }
    public Integer varianceFYPercent { set; }
    public Integer varianceFYAmount { set; }

    public RevenueWrapper(){

    }

    public void setAmount(AggregateResult ar){
        revenueDate = String.valueOf(ar.get('Date'));

            //Set the amount value based on type
        if(ar.get('Type__c') == 'Budget'){
            budgetAmount = Integer.valueOf(ar.get('Amount'));
        }else if(ar.get('Type__c') == 'Actual'){
            actualAmount = Integer.valueOf(ar.get('Amount'));
        }else{ //Catch all for a type that isn't recognised
            return;
        }

    }

    public Integer getVarianceFYAmount(){
        return actualAmount - budgetAmount;
    }

    public Decimal getVarianceFYPercent(){
        if(budgetAmount != 0){
            return Decimal.valueOf((Double.valueOf(actualAmount) / Double.valueOf(budgetAmount)) * 100).setscale(1);
        } else{
            return 0;
        }
    }
}

}

[SalesForce] Reason behind element value must resolve to a String type!

This looks to be a bug in Visualforce - its been around since 2008 by the look of this post on the Developerforce Discussion Boards:

https://developer.salesforce.com/forums/ForumsMain?id=906F0000000951yIAA

The best I've been able to do with this is to have the underlying property still stored as an Integer, but have a string based getter/setter for it that converts to/from a string. That way I can use the property as an Integer within my code and I just have to convert it once.

You'll need an answer from Salesforce as to why it works this way - given that people have been complaining about this behaviour for nearly 6 years, it feels like they might think its working correctly. Although Doug Chasman does suggest its a bug in the developerforce post above.

Best Answer

Related Solutions

[SalesForce] Split a single field into 2 columns for a VF page

[SalesForce] Reason behind element value must resolve to a String type!

Related Topic