[SalesForce] Active User and their related Tasks SOQL

What you need is a Wrapper for each data row you want to display. the wrapper will take care of the SelectOptions.

Below is an example, that displays a list of Opportunities for which you can select a Contact based on the Opportunity's AccountId

To avoid to run into Governor Limits #getItems() is responsible for setting up the selectOptions in bulk initially.

public class SelectListController {

    ItemWrapper[] items;

    // account select options for the opportunities
    public List<SelectOption> getParentOptions() {

        List<SelectOption> options = new List<SelectOption>();

        for (Account record : [select Id, Name from Account LIMIT 100])
        {
            options.add(new SelectOption(record.Id,record.Name));
        }
        return options;
    }


    // returns list of ItemWrappers, each holding an opportuity record as well
    // as a list of contact selectOptions for the opportunity account id
    public ItemWrapper[] getItems(){

        if (items == null)
        {

            items = new ITemWrapper[]{};

            Opportunity[] records = [
                select Id
                     , Name
                     , AccountId
                  from Opportunity
                 where AccountID != null
                 LIMIT 10];

            Id[] accountIds = new Id[]{};
            for (Opportunity record:records)
            {
                accountIds.add(record.AccountId);
            }

            // query accounts with contacts to bulk setup select options
            Map<Id,Account> accountMap = new Map<Id,Account>([
                select Id
                     , (
                select Id
                     , Name
                  from Contacts)
                  from Account
                 where Id IN: accountIds]);

            // setup one ItemWrapper per Opportunity and generate the selectOptions using the Account Map
            for (Opportunity record:records)
            {
                ItemWrapper item = new ItemWrapper(record);
                items.add(item);

                // could by null if AccountId is null
                if (accountMap.containsKey(record.AccountId))
                {
                    for (Contact contact:accountMap.get(record.AccountId).Contacts)
                    {
                        item.contactOptions.add(new SelectOption(contact.Id,contact.Name));
                    }                
                }
            }
        }

        return items;
    }


    // Wrapper with Opportunity and Contact SelectOptions for the Opp's AccountId
    public class ItemWrapper {

        public Opportunity record {get;set;}

        public String contactValue {get;set;}

        public SelectOption[] contactOptions {get;set;}

        public ItemWrapper(Opportunity record){
            this.record = record;
            this.contactOptions = new SelectOption[]{};
        }


        public Id getParentValue(){
            return record.AccountId;
        }


        // changing the parent value, will replace the current contact options with
        // contacts from the for the new account
        public void setParentValue(Id value){

            if (value != record.AccountId)
            {
                contactOptions = new SelectOption[]{};

                for (Contact contact:[select Id, Name from Contact where AccountId =: value ORDER BY NAME])
                {
                    contactOptions.add(new SelectOption(contact.Id,contact.Name));
                }
            }
            record.AccountId = value;
        }
    }
}

Here's the VF Page

<apex:page controller="SelectListController">

<apex:form>
    <apex:pageBlock>

        <apex:pageBlockTable value="{!items}" var="i">

            <apex:column value="{!i.record.Name}"/>

            <apex:column>
                <apex:selectList value="{!i.ParentValue}" size="1">
                    <apex:selectOptions value="{!parentOptions}"/>
                    <apex:actionSupport event="onchange" reRender="contacts"/>
                </apex:selectList>
            </apex:column>

            <apex:column>
                <apex:selectList value="{!i.contactValue}" size="1" id="contacts">
                    <apex:selectOptions value="{!i.contactOptions}"/>
                </apex:selectList>
            </apex:column>


        </apex:pageBlockTable>

    </apex:pageBlock>
</apex:form>
</apex:page>

On keypress/keydown/change of your inputFields (whichever you prefer) you should call an action function to sync values. The idea is to pass along which field you're updating, and which record to sync from, and loop through your records to identify selected records and update the proper field. This may be a bit clunky but I hope I'm conveying the idea appropriately.

<apex:actionFunction name="sync" action="{!sync}">
    <apex:param name="field" assignTo="fieldToUpdate" value="" />
    <apex:param name="value" assignTo="selectedId" value="" />
</apex:actionFunction>

<!-- using i as an example for your table values -->
<apex:inputField value="{i.Phone}" onChange="sync('phone', '{i.Id}')" />



List<WrapperObject> WrappedObjectList = (however you fill your list);

public string fieldToUpdate {get;set;}
public string selectedId {get; set;}
public string fieldValue{
    get{
        //grab the value from the selected object
        for(WrappedObject o : WrappedObjectList){
            if(o.Id == selectedId){
                if(fieldToUpdate == "phone"){
                    return o.Phone;;
                }
            }
        }
        return "";
    }
}

public PageReference sync(){
    for(WrappedObject o : WrapperObjectList){
        //update all selected objects with that value
        if(o.Selected){
            if(fieldToUpdate == "phone"){
                o.Phone = fieldValue;
            }
        }
    }
    return null;
}

Hope this helps! c: