[SalesForce] CANNOT_INSERT_UPDATE_ACTIVATE_ENTITY, execution of AfterInsert

Since your trigger code isn't commented, it is unclear exactly what your intent is but I'll take a shot at correcting and commenting it.

trigger quotepotential on Quote_Line_Item__c (after insert, after update) {

    // the IDs of quotes which we are going to populate the potential amount on
    Set<Id> quoteIds = new Set<Id>();

    // the list of Quote__c records which will be updated with the amount
    List<Quote__c> quotesToUpdate = new List<Quote__c>();

    // collect the ID value of the related Quote
    for (Quote_Line_Item__c record: Trigger.new) {
        if (record.Quote1__c != null) {
            quoteIds.add(record.Quote1__c);
        }
    }

    // use the quoteIDs set to get the aggregate sum per Quote1__c
    for (AggregateResult ar : [SELECT Quote1__c
                                    , SUM(Max_Batch__c)sumMax 
                                FROM Quote_Line_Item__c
                                WHERE Quote1__c IN :quoteIds 
                                GROUP BY Quote1__c]) {

        // create an sObject to be used for the update operation
        Quote__c qu = new Quote__c(Id = (Id)ar.get('Quote1__c'));
        qu.Potential__c = (Decimal)ar.get('sumMax');

        // add this sObject to the updates list
        quotesToUpdate.add(qu);

        /* Not sure why this code is here - it appears to not belong */
        /* P.S. avoid DML operations in loops in all cases */
        // list<quote__c> quo = [select id,potential__c from quote__c where id IN :quotes limit 1 for update]; 
        // update quo;
    }

    // if there's work to be done, do it.
    if (!quotesToUpdate.isEmpty()) {
        update quotesToUpdate;
    }
}

You could resolve this by using a static Boolean variable in a class. Quoting from the success community

In order to avoid the situation of recursive call, make sure your trigger is getting executed only one time. To do so, you can create a class with a static boolean variable with default value true.

In the trigger, before executing your code keep a check that the variable is true or not.

Once you check make the variable false.

A detailed explanation with sample code is available on the link