[SalesForce] Display lists of strings as columns on VF page

So if I have lets say three string lists, how can I have each string appear as a column in a table on a VF page? Is it possible to have a PageBlockTable or would I have to build it another way?

List<String> firstName = new list<String> { 'John' , 'Amy' , 'Andrew'};
List<String> lastName = new list<String> { 'Smith' , 'Williams' , 'Jones'};
List<String> cityName = new list<String> { 'New York' , 'LA' , 'Miami'};

Best Answer

You can do this if you have a helper variable to access the indices. This example presumes that all lists are to be of equal length:

public class DemoController {
    public string[] firstName { get; set; }
    public string[] lastName { get; set; }
    public string[] cityName { get; set; }
    public Integer[] indexes { get; set; }
    public DemoController() {
        firstName = new string[] { 'John' , 'Amy' , 'Andrew'};
        lastName = new string[] { 'Smith' , 'Williams' , 'Jones'};
        cityName = new string[] { 'New York' , 'LA' , 'Miami'};
        indexes = new Integer[] { 0, 1, 2 };
    }
}

<apex:page controller="DemoController">
    <apex:pageBlock>
        <apex:pageBlockTable value="{!indexes}" var="index">
            <apex:column headerValue="First Name" value="{!firstName[index]}" />
            <apex:column headerValue="Last Name" value="{!lastName[index]}" />
            <apex:column headerValue="City" value="{!cityName[index]}" />
        </apex:pageBlockTable>
    </apex:pageBlock>
</apex:page>

There are other ways to arrange this behavior, such as with CSS or potentially messing around with an apex:variable, but this technique is the one I generally regard as the safest method, even if it does use a bit more view state.

Related Solutions

[SalesForce] Split a single field into 2 columns for a VF page

This is untested so you may need to have play, however this should return a List of the RevenueWrapper classes which contains the 4 columns you are looking to use in your VF page:

public class RevenueController{

Map<String, RevenueWrapper> ResultList = new Map<String, RevenueWrapper>(); 

public RevenueController(){
    List<AggregateResult> result =  [
    SELECT FISCAL_YEAR(Date__c) Date, Type__c, sum(Amount__c) Amount
    FROM Revenue__c
    GROUP BY FISCAL_YEAR(Date__c), Type__c];

    for(AggregateResult ar : result){

        RevenueWrapper RW = new RevenueWrapper();

        //If the RevenueWrapper already exists grab it from the Map
        if(ResultList.containsKey(String.valueOf(ar.get('Date')))){
            RW = ResultList.get(String.valueOf(ar.get('Date')));
        }

        //Set the amount
        RW.setAmount(ar);

        //Save back to the Map
        ResultList.put(String.valueOf(ar.get('Date')), RW);
    }
}

public List<RevenueWrapper> getResults() {
    return ResultList.values();
}


public class RevenueWrapper{
    public String revenueDate { get; set; }
    public Integer budgetAmount { get; set; }
    public Integer actualAmount { get; set; }
    public Integer varianceFYPercent { set; }
    public Integer varianceFYAmount { set; }

    public RevenueWrapper(){

    }

    public void setAmount(AggregateResult ar){
        revenueDate = String.valueOf(ar.get('Date'));

            //Set the amount value based on type
        if(ar.get('Type__c') == 'Budget'){
            budgetAmount = Integer.valueOf(ar.get('Amount'));
        }else if(ar.get('Type__c') == 'Actual'){
            actualAmount = Integer.valueOf(ar.get('Amount'));
        }else{ //Catch all for a type that isn't recognised
            return;
        }

    }

    public Integer getVarianceFYAmount(){
        return actualAmount - budgetAmount;
    }

    public Decimal getVarianceFYPercent(){
        if(budgetAmount != 0){
            return Decimal.valueOf((Double.valueOf(actualAmount) / Double.valueOf(budgetAmount)) * 100).setscale(1);
        } else{
            return 0;
        }
    }
}

}

[SalesForce] How to make a Cascading (Dependent) Select List (Drop Down) in a Data Table in VisualForce

What you need is a Wrapper for each data row you want to display. the wrapper will take care of the SelectOptions.

Below is an example, that displays a list of Opportunities for which you can select a Contact based on the Opportunity's AccountId

To avoid to run into Governor Limits #getItems() is responsible for setting up the selectOptions in bulk initially.

public class SelectListController {

    ItemWrapper[] items;

    // account select options for the opportunities
    public List<SelectOption> getParentOptions() {

        List<SelectOption> options = new List<SelectOption>();

        for (Account record : [select Id, Name from Account LIMIT 100])
        {
            options.add(new SelectOption(record.Id,record.Name));
        }
        return options;
    }


    // returns list of ItemWrappers, each holding an opportuity record as well
    // as a list of contact selectOptions for the opportunity account id
    public ItemWrapper[] getItems(){

        if (items == null)
        {

            items = new ITemWrapper[]{};

            Opportunity[] records = [
                select Id
                     , Name
                     , AccountId
                  from Opportunity
                 where AccountID != null
                 LIMIT 10];

            Id[] accountIds = new Id[]{};
            for (Opportunity record:records)
            {
                accountIds.add(record.AccountId);
            }

            // query accounts with contacts to bulk setup select options
            Map<Id,Account> accountMap = new Map<Id,Account>([
                select Id
                     , (
                select Id
                     , Name
                  from Contacts)
                  from Account
                 where Id IN: accountIds]);

            // setup one ItemWrapper per Opportunity and generate the selectOptions using the Account Map
            for (Opportunity record:records)
            {
                ItemWrapper item = new ItemWrapper(record);
                items.add(item);

                // could by null if AccountId is null
                if (accountMap.containsKey(record.AccountId))
                {
                    for (Contact contact:accountMap.get(record.AccountId).Contacts)
                    {
                        item.contactOptions.add(new SelectOption(contact.Id,contact.Name));
                    }                
                }
            }
        }

        return items;
    }


    // Wrapper with Opportunity and Contact SelectOptions for the Opp's AccountId
    public class ItemWrapper {

        public Opportunity record {get;set;}

        public String contactValue {get;set;}

        public SelectOption[] contactOptions {get;set;}

        public ItemWrapper(Opportunity record){
            this.record = record;
            this.contactOptions = new SelectOption[]{};
        }


        public Id getParentValue(){
            return record.AccountId;
        }


        // changing the parent value, will replace the current contact options with
        // contacts from the for the new account
        public void setParentValue(Id value){

            if (value != record.AccountId)
            {
                contactOptions = new SelectOption[]{};

                for (Contact contact:[select Id, Name from Contact where AccountId =: value ORDER BY NAME])
                {
                    contactOptions.add(new SelectOption(contact.Id,contact.Name));
                }
            }
            record.AccountId = value;
        }
    }
}

Here's the VF Page

<apex:page controller="SelectListController">

<apex:form>
    <apex:pageBlock>

        <apex:pageBlockTable value="{!items}" var="i">

            <apex:column value="{!i.record.Name}"/>

            <apex:column>
                <apex:selectList value="{!i.ParentValue}" size="1">
                    <apex:selectOptions value="{!parentOptions}"/>
                    <apex:actionSupport event="onchange" reRender="contacts"/>
                </apex:selectList>
            </apex:column>

            <apex:column>
                <apex:selectList value="{!i.contactValue}" size="1" id="contacts">
                    <apex:selectOptions value="{!i.contactOptions}"/>
                </apex:selectList>
            </apex:column>


        </apex:pageBlockTable>

    </apex:pageBlock>
</apex:form>
</apex:page>

Best Answer

Related Solutions

[SalesForce] Split a single field into 2 columns for a VF page

[SalesForce] How to make a Cascading (Dependent) Select List (Drop Down) in a Data Table in VisualForce

Related Topic